[art_rrc]

Доброго времени суток. Подскажите пожалуйста, если ли в VBA (AutoCAD 2015) методы, позволяющие "вытянуть" содержимое текста вместе с формулами? Т.к. простой .TextString возвращает уже преобразованный результат..
Пример:
На экране текст выглядит как "1-1" или "#-#", Но на самом деле, там забито такое выражение:
"%<\AcObjProp Object(%<\_ObjId 8796076505568>%).TextString>%-%<\AcObjProp Object(%<\_ObjId 8796076505568>%).TextString>%"
Так вот, можно как-нибудь его заполучить?
Спасибо.

[Кулик Алексей aka kpblc]

FieldCode ?

[art_rrc]

Сообщение от Кулик Алексей aka kpblc FieldCode ?

Attr = DynBlockObj.GetAttributes
"AttrTextStr = Attr(i).FieldCode"
Выдает ошибку.
Не знает такого метода по всей видимости..(

Код:

[Выделить все]

Sub art_FieldBase()
Dim dynBlObj As AcadBlockReference
'On Error Resume Next
'Call ClearSelectionSets
Set SelSet1 = ThisDrawing.SelectionSets.Add("Set1_FieldBase")
SelSet1.SelectOnScreen
If SelSet1.Count = 0 Then GoTo DavayDoSvidaniya
'Обновление пространства модели
ThisDrawing.Regen acActiveViewport
For Each Item In SelSet1
    If Item.ObjectName = "AcDbBlockReference" Then
        Set dynBlObj = Item
        Call GetAttr(dynBlObj, "_1ПОЗИЦИЯ", strText)
        'Call SetLineUp(dynBlObj)
        MsgBox (strText)
        
    End If
    Next
DavayDoSvidaniya:
SelSet1.Delete
End Sub

Public Sub GetAttr(DynBlockObj As AcadBlockReference, AttrName As String, AttrTextStr)
Attr = DynBlockObj.GetAttributes
For i = 0 To UBound(Attr)
    If Attr(i).TagString = AttrName Then
    'AttrTextStr = Attr(i).TextString
    AttrTextStr = Attr(i).FieldCode
    End If
Next
End Sub

[Do$]

Сообщение от art_rrc GoTo DavayDoSvidaniya

[trir]

хм

[Кулик Алексей aka kpblc]

Н-да, с атрибутами не все так просто FieldCode в VBA существует только для текстов

[Theodor]

Коллеги, а определить наличие кода/поля именно в атрибутах - нашлось все таки какое-нибудь VBA решение?

[Boxa]

Theodor, я извиняюсь, а в чем сложность то? Ну да, надо написать не одну строчку, а пяток - десять, но все таки в чем сложность то?
ЗЫ.
Маленькое уточнение, Theodor ставит вопрос о проверке наличия поля в атрибуте, это VBA может, а вот прочитать значение кода этого поля - нет.

[Кулик Алексей aka kpblc]

Да ладно, не может! Может:

Код:

[Выделить все]

Public Sub test()
Dim sTextString As String
Dim sFldString As String
Dim oEnt As AcadEntity
Dim oMtext As AcadMText
  For Each oEnt In ThisDrawing.ModelSpace
    If oEnt.ObjectName = "AcDbMText" Then
      Set oMtext = oEnt
      sTextString = oMtext.TextString
      sFldString = oMtext.FieldCode
      MsgBox "TextString = " & sTextString & vbCr & "FieldCode = " & sFldString
    End If
  Next oEnt
End Sub

----- добавлено через 26 сек. -----
С атрибутами такой же метод, думаю.

[Boxa]

Кулик Алексей aka kpblc, вопрос про АТРИБУТЫ, у атрибута нет метода FieldCode

[Кулик Алексей aka kpblc]

У многострочного атрибута, кажется, есть.

[Boxa]

Сообщение от Кулик Алексей aka kpblc У многострочного атрибута, кажется, есть.

Очень может быть, т.к. по сути для атрибута будет установлена метка MTextAttribute и поле будет браться из вложенного объекта МТекст

там что то типа этого:

Код:

[Выделить все]

 
if (arAttr.IsMTextAttribute)
{
  MText mtx = arAttr.MTextAttribute;
  arAttr.MTextAttribute = mtx;
  arAttr.UpdateMTextAttribute();
  brRefBlock.RecordGraphicsModified(true);
}

[Theodor]

Сообщение от Boxa Маленькое уточнение, Theodor ставит вопрос о проверке наличия поля в атрибуте, это VBA может

И как это узнать, наличие поля? каким методом? если применительно к однострочному атрибуту? С мультитекстами понятно, попробовал, работает.
Хотя бы узнать о наличии, фиг с ним с кодом.

[Boxa]

Theodor, посмотреть содержимое ExtensionDictionary для атрибута.

Код:

[Выделить все]

Sub IsAttributesHasFIELD() 
   Dim HasFIELD As Boolean
   HasFIELD = False
   Dim blockRefObj As AcadObject
   Dim basePnt As Variant
   On Error Resume Next
   ThisDrawing.Utility.GetEntity blockRefObj, basePnt, "Select an object"

   Dim varAttributes As Variant
   varAttributes = blockRefObj.GetAttributes
  
   For Each I In varAttributes
    If I.HasExtensionDictionary Then
         Dim EDictionary As AcadDictionary
         Set EDictionary = I.GetExtensionDictionary
         If EDictionary.Count > 0 Then
             For Each f In EDictionary
                 If f.Name = "ACAD_FIELD" Then
                     HasFIELD = True
                     Exit For
                 End If
             Next
         End If
     End If
    Next
   
    MsgBox CStr(HasFIELD)
End Sub

[Theodor]

Сообщение от Boxa посмотреть содержимое ExtensionDictionary для атрибута.

Ого! Интересно! Спасибо, попробую. Давно задумывался об изучении расширенных словарей, думаю там много полезных тайн.

----- добавлено через ~20 мин. -----
Boxa, еще раз спасибо, все получилось!!!