| Правила | Регистрация | Пользователи | Поиск | Сообщения за день | Все разделы прочитаны |  Справка по форуму | Файлообменник |

Вернуться   Форум DWG.RU > Программное обеспечение > Расчетные программы > ANSYS > Несходимость. Расчет модели ж/б балки в ANSYS.

Несходимость. Расчет модели ж/б балки в ANSYS.

Ответ
Поиск в этой теме
Непрочитано 07.08.2011, 22:39 #1
Несходимость. Расчет модели ж/б балки в ANSYS.
websword
 
Регистрация: 07.08.2011
Сообщений: 10

Простая железобетонная балка.
Сравниваю с экспериментальными результатами.
Задача узкая, но времени на нормальный многомесячный последовательный разбор Ансиса к сожалению нет (
Плоды моих измышлений на базе Wolanski(2004), Saifullah(2011) и справки, прилагаются ниже.
Бетон канонически моделируется SOLID65, арматура - LINK8.
Увы, не удается добиться сходимости балки, количество итераций не играет.
Да и прогибы получаются мягко говоря, маленькими.
Почему- ума не приложу.
Был бы очень благодарен, если б указали куда копать.

Код:
[Выделить все]
/COM,Neutov Alexander
/PREP7
/TITLE, Balka_27
ANTYPE,STATIC! тип анализа – статический
/UNITS,SI

!Параметры балки
l=1				! Длина балки
h=0.22				! Высота балки
b=0.05				! Ширина балки
c=0.35				! Пролет среза
sh_f_v=h+0.04			! Высота балки+толщина силы/пластинки
a_s1=0.04			! Толщина защитного слоя снизу/сверху
a_sb=0.02			! Толщина защитного слоя сбоку
A_s=1.54E-4			! Площадь нижней рабочей арматуры в м2
A_s_str=0.785E-4		! Площадь верхней арматуры в м2
A_sw=0.2827E-4		! Площадь поперечной арматуры в м2

! Секция элементов и констант
ET,1,SOLID65			! тип элемента – солид65(бетон)
R,1                 			! реал константы под него
ET,2,LINK8                  		! тип элемента – линк8 (арматура)
R,2,A_s                     		! площадь арматуры продольной нижней
R,3,A_s_str			! площадь арматуры продольной верхней
R,4,A_sw			! площадь арматуры поперечной 
ET,3,SOLID45			  ! тип элемента – солид45(стальная опора/сила)
R,5

!Секция свойств материалов
E_x_s=2E11			! Модуль упругости стали продольной арматуры
E_x_sw=2E11			! Модуль упругости стали поперчной арматуры
E_x_b=3.94722222E10			! Модуль упругости бетона(начальный)

MP,EX,1,E_x_b          		! материал, линейный, 1(бетон), модуль упругости
MP,NUXY,1,0.2	     	! малый ?модуль пуассона 
TB,MISO,1
TBPT,DEFI,3.6E-4,1.421E7
TBPT,DEFI,6E-4,2.233E7
TBPT,DEFI,13E-4,3.991E7
TBPT,DEFI,19E-4,4.656E7
TBPT,DEFI,24.3E-4,4.8E7



TB,CONCR,1			! создает таблицу для нелинейных свойств бетона(1)
TBDATA,1,0.3,0.8,4.99E6,44.22E6           ! определяет константы модели начиная с номера(первого после команды)
! TB,CREEP,1 ! создает таблицу для ползучести свойств материала бетон(1)

MP,EX,2,E_x_s              	! материал, линейный, 2(сталь), модуль упругости
MP,NUXY,2,0.3	     	!модуль пуассона 
TB,BISO,2			! Билинейная диаграмма деформирования стали
TBDATA,1,2.5E08		! Предел текучести в Па
TBDATA,2,1.45E09		! Секущий модуль в Па

MP,EX,3,E_x_s                 	! Все тоже самое для стали поперечной арматуры
MP,NUXY,2,0.3
TB,BISO,2
TBDATA,1,2.5E08
TBDATA,2,1.45E09

MP,EX,4,E_x_s                 	! Сталь опоры/силы
MP,NUXY,3,0.3

!Создание модели
! Продольная арматура
		!Нижняя
TYPE,2				! Тип элемента
MAT,2				! Материал
REAL,2			! Выбор р.к.
K,25,0,a_s1,b-a_sb		!Кейпойнты
K,26,l, a_s1,b-a_sb
L,25,26
MSHKEY,1
MOPT,QMESH,MAIN
		        ! Верхняя		
REAL,3			! Выбор р.к.
K,27,0,h-a_s1,b-a_sb
K,28,l,h-a_s1,b-a_sb
L,27,28
		 ! Мешинг продольной арматуры
LSEL,S,LINE,,1,2,1,1		! Выбор линий для применения параметров мешинга
LESIZE,ALL,0.02,,,,,,1		! Задание шага для мешинга
REAL,2			! Выбор р.к.
LMESH,1,1,1			! Мешинг нижней арматуры
REAL,3			! Переход к 3й р.к.
LMESH,2,2,1			! Мешинг верхней арматуры

	! Поперечная арматура
MAT,3				! Переход на сталь поперечной арматуры
REAL,4			! Переход к р.к.  поперечной арматуры
		! Создание линий поперечной арматуры
num=28
*DO,I,1,5
REAL,4
num=num+1
K,num,0.02+(i-1)*0.04,a_s1,b-a_sb
num=num+1
K,num,0.02+(i-1)*0.04,h-a_s1,b-a_sb
L,num-1,num
*ENDDO


*DO,I,1,6
num=num+1
K,num,0.02+4* 0.04+i*0.08,a_s1,b-a_sb
num=num+1
K,num, 0.02+4* 0.04+i*0.08,h-a_s1,b-a_sb
L,num-1,num
*ENDDO

num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04,a_s1,b-a_sb
num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04,h-a_s1,b-a_sb
L,num-1,num

num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2,a_s1,b-a_sb
num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2,h-a_s1,b-a_sb
L,num-1,num


num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2+0.175/2,a_s1,b-a_sb
num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2+0.175/2,h-a_s1,b-a_sb
L,num-1,num

num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2+0.18,a_s1,b-a_sb
num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2+0.18,h-a_s1,b-a_sb
L,num-1,num
		! Мешинг поперечной арматуры
LSEL,S,LINE,,3,17,1,1		! Выбор линий для применения параметров мешинга
LESIZE,ALL,0.02,,,,,,1		! Задание шага для мешинга
LMESH,3,17,1			! Мешинг

LSEL,S,LINE,,ALL		! Выбор всех линий
NSEL,S,NODE,,ALL		! Выбор всех точек
NUMMRG,NODE
NUMMRG,KP
 

! Создание бетонных блоков
TYPE,1				! Задание элемента, материала и констант
MAT,1
REAL,1

k,1,0,0,0			! Кейпойнты для поперечного сечения			
k,2,0,h,0
k,3,0,0,b
k,4,0,h,b	
a,1,3,4,2			! Плоскость для экструзии
allsel
asel,s,,,1			! Выбор плоскости для экструзии
vext,all,,,l			! Экструзия по выборке на 1м

! Создание опоры и силы
TYPE,3				! Задание элемента, материала и констант
MAT,4
REAL,5

	!Опора
K,9,0.18,0,0			! Кейпойнты
K,10,0.18,0,b
K,11,0.18,-0.04,0
K,12,0.18,-0.04,b
A, 9,11,12,10			! Плоскость для экструзии

	! Сила
K,17,0.18+c,0+ sh_f_v,0		! Кейпойнты
K,18,0.18+c,0+ sh_f_v,b
K,19,0.18+c,-0.04+ sh_f_v,0
K,20,0.18+c,-0.04+ sh_f_v,b
A, 17,19,20,18				! Плоскость для экструзии


ALLSEL
ASEL,s,,,7,8				! Выбор плоскости для экструзии
VEXT,7,8,1,0.04			! Экструзия по выборке на 4см



! Мешинг массивов
MSHKEY,1				! Тип мешинга - mapped
MOPT,QMESH,MAIN			! Опции мешинга - четырехугольный
ESIZE,0.01				! Размер границы элемента для мешинга
	! Мешинг бетона
TYPE,1					! Параметры элементов и материалов
MAT,1
REAL,1
VMESH,1,1,1				! Мешинг бетона
TYPE,3					! Параметры элементов и материалов
MAT,4
REAL,5

VMESH,2,3,1				! Мешинг силы и опоры	

ALLSEL

!Секция merge
NUMMRG,NODE
NUMMRG,KP

!Секция опор, закреплений и симметрии
DA,2,SYMM
DA,6,SYMM
DTRAN,ALL
D,14222,UY,0
D,14222,UZ,0
D,14240, UY,0
D,14240, UZ,0
D,14243, UY,0
D,14243, UZ,0
D,14246, UY,0
D,14246, UZ,0
D,14249, UY,0
D,14249, UZ,0
D,14237,UY,0
D,14237,UZ,0

! Секция нагрузок (ОМГ)
F,14374,FY,-13333
F,14422,FY,-13333
F,14419,FY,-13333
F,14416,FY,-13333
F,14413,FY,-13333
F,14401,FY,-13333
Просмотров: 14732
 
Непрочитано 08.08.2011, 08:03
1 | #2
СергейД

расчеты МКЭ и CFD. ктн
 
Регистрация: 11.05.2005
Подмосковье
Сообщений: 2,170


все самое интересное дальше.
какие параметры решения берете?
СергейД вне форума  
 
Автор темы   Непрочитано 08.08.2011, 19:24
#3
websword


 
Регистрация: 07.08.2011
Сообщений: 10


Пришлось подправить, там не все в порядке с MISO так что временно я его отключил.

Код:
[Выделить все]
/COM,Neutov Alexander
/PREP7
/TITLE, Balka_27
ANTYPE,STATIC! тип анализа – статический
/UNITS,SI

!Параметры балки
l=1				! Длина балки
h=0.22				! Высота балки
b=0.05				! Ширина балки
c=0.35				! Пролет среза
sh_f_v=h+0.04			! Высота балки+толщина силы/пластинки
a_s1=0.04			! Толщина защитного слоя снизу/сверху
a_sb=0.02			! Толщина защитного слоя сбоку
A_s=1.54E-4			! Площадь нижней рабочей арматуры в м2
A_s_str=0.785E-4		! Площадь верхней арматуры в м2
A_sw=0.2827E-4		! Площадь поперечной арматуры в м2

! Секция элементов и констант
ET,1,SOLID65			! тип элемента – солид65(бетон)
R,1                 			! реал константы под него
ET,2,LINK8                  		! тип элемента – линк8 (арматура)
R,2,A_s                     		! площадь арматуры продольной нижней
R,3,A_s_str			! площадь арматуры продольной верхней
R,4,A_sw			! площадь арматуры поперечной 
ET,3,SOLID45			  ! тип элемента – солид45(стальная опора/сила)
R,5

!Секция свойств материалов
E_x_s=2E11			! Модуль упругости стали продольной арматуры
E_x_sw=2E11			! Модуль упругости стали поперчной арматуры
E_x_b=3.94722222E10			! Модуль упругости бетона(начальный)

MP,EX,1,E_x_b          		! материал, линейный, 1(бетон), модуль упругости
MP,NUXY,1,0.2	     	! малый ?модуль пуассона 
!TB,MISO,1
!TBPT,DEFI,3.6E-4,1.421E7
!TBPT,DEFI,6E-4,2.233E7
!TBPT,DEFI,13E-4,3.991E7
!TBPT,DEFI,19E-4,4.656E7
!TBPT,DEFI,24.3E-4,4.8E7



TB,CONCR,1			! создает таблицу для нелинейных свойств бетона(1)
TBDATA,1,0.3,0.8,4.99E6,44.22E6           ! определяет константы модели начиная с номера(первого после команды)
! TB,CREEP,1 ! создает таблицу для ползучести свойств материала бетон(1)

MP,EX,2,E_x_s              	! материал, линейный, 2(сталь), модуль упругости
MP,NUXY,2,0.3	     	!модуль пуассона 
TB,BISO,2			! Билинейная диаграмма деформирования стали
TBDATA,1,2.5E08		! Предел текучести в Па
TBDATA,2,1.45E09		! Секущий модуль в Па

MP,EX,3,E_x_s                 	! Все тоже самое для стали поперечной арматуры
MP,NUXY,2,0.3
TB,BISO,2
TBDATA,1,2.5E08
TBDATA,2,1.45E09

MP,EX,4,E_x_s                 	! Сталь опоры/силы
MP,NUXY,3,0.3

!Создание модели
! Продольная арматура
		!Нижняя
TYPE,2				! Тип элемента
MAT,2				! Материал
REAL,2			! Выбор р.к.
K,25,0,a_s1,b-a_sb		!Кейпойнты
K,26,l, a_s1,b-a_sb
L,25,26
MSHKEY,1
MOPT,QMESH,MAIN
		        ! Верхняя		
REAL,3			! Выбор р.к.
K,27,0,h-a_s1,b-a_sb
K,28,l,h-a_s1,b-a_sb
L,27,28
		 ! Мешинг продольной арматуры
LSEL,S,LINE,,1,2,1,1		! Выбор линий для применения параметров мешинга
LESIZE,ALL,0.02,,,,,,1		! Задание шага для мешинга
REAL,2			! Выбор р.к.
LMESH,1,1,1			! Мешинг нижней арматуры
REAL,3			! Переход к 3й р.к.
LMESH,2,2,1			! Мешинг верхней арматуры

	! Поперечная арматура
MAT,3				! Переход на сталь поперечной арматуры
REAL,4			! Переход к р.к.  поперечной арматуры
		! Создание линий поперечной арматуры
num=28
*DO,I,1,5
REAL,4
num=num+1
K,num,0.02+(i-1)*0.04,a_s1,b-a_sb
num=num+1
K,num,0.02+(i-1)*0.04,h-a_s1,b-a_sb
L,num-1,num
*ENDDO


*DO,I,1,6
num=num+1
K,num,0.02+4* 0.04+i*0.08,a_s1,b-a_sb
num=num+1
K,num, 0.02+4* 0.04+i*0.08,h-a_s1,b-a_sb
L,num-1,num
*ENDDO

num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04,a_s1,b-a_sb
num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04,h-a_s1,b-a_sb
L,num-1,num

num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2,a_s1,b-a_sb
num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2,h-a_s1,b-a_sb
L,num-1,num


num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2+0.175/2,a_s1,b-a_sb
num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2+0.175/2,h-a_s1,b-a_sb
L,num-1,num

num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2+0.18,a_s1,b-a_sb
num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2+0.18,h-a_s1,b-a_sb
L,num-1,num
		! Мешинг поперечной арматуры
LSEL,S,LINE,,3,17,1,1		! Выбор линий для применения параметров мешинга
LESIZE,ALL,0.02,,,,,,1		! Задание шага для мешинга
LMESH,3,17,1			! Мешинг

LSEL,S,LINE,,ALL		! Выбор всех линий
NSEL,S,NODE,,ALL		! Выбор всех точек
NUMMRG,NODE
NUMMRG,KP
 

! Создание бетонных блоков
TYPE,1				! Задание элемента, материала и констант
MAT,1
REAL,1

k,1,0,0,0			! Кейпойнты для поперечного сечения			
k,2,0,h,0
k,3,0,0,b
k,4,0,h,b	
a,1,3,4,2			! Плоскость для экструзии
allsel
asel,s,,,1			! Выбор плоскости для экструзии
vext,all,,,l			! Экструзия по выборке на 1м

! Создание опоры и силы
TYPE,3				! Задание элемента, материала и констант
MAT,4
REAL,5

	!Опора
K,9,0.18,0,0			! Кейпойнты
K,10,0.18,0,b
K,11,0.18,-0.04,0
K,12,0.18,-0.04,b
A, 9,11,12,10			! Плоскость для экструзии

	! Сила
K,17,0.18+c,0+ sh_f_v,0		! Кейпойнты
K,18,0.18+c,0+ sh_f_v,b
K,19,0.18+c,-0.04+ sh_f_v,0
K,20,0.18+c,-0.04+ sh_f_v,b
A, 17,19,20,18				! Плоскость для экструзии


ALLSEL
ASEL,s,,,7,8				! Выбор плоскости для экструзии
VEXT,7,8,1,0.04			! Экструзия по выборке на 4см

DA,2,SYMM
DA,6,SYMM


! Мешинг массивов
MSHKEY,1				! Тип мешинга - mapped
MOPT,QMESH,MAIN			! Опции мешинга - четырехугольный
ESIZE,0.01				! Размер границы элемента для мешинга
	! Мешинг бетона
TYPE,1					! Параметры элементов и материалов
MAT,1
REAL,1
VMESH,1,1,1				! Мешинг бетона
TYPE,3					! Параметры элементов и материалов
MAT,4
REAL,5

VMESH,2,3,1				! Мешинг силы и опоры	

ALLSEL

!Секция merge
NUMMRG,NODE
NUMMRG,KP

!Секция опор, закреплений и симметрии
DTRAN,ALL
D,14222,UY,0
D,14222,UZ,0
D,14240, UY,0
D,14240, UZ,0
D,14243, UY,0
D,14243, UZ,0
D,14246, UY,0
D,14246, UZ,0
D,14249, UY,0
D,14249, UZ,0
D,14237,UY,0
D,14237,UZ,0

! Секция нагрузок (ОМГ)
F,14374,FY,-13333
F,14422,FY,-13333
F,14419,FY,-13333
F,14416,FY,-13333
F,14413,FY,-13333
F,14401,FY,-13333
А что касается собственно параметров решения

Код:
[Выделить все]
! Секция параметров решения
ANTYPE,STATIC			! тип анализа – статический

EQSLV,SPARSE 			!PCG,DPCG,DSPARSE
BCSOPTION,,,2048

AUTOTS,ON				! Авто таймстеппинг
OUTRES,ALL
NEQIT,50				        ! число итераций

NROPT,FULL				!FULL,MODI Тип алгоритма Ньютона-Рафсона
LNSRCH,ON				!OFF Только для Н-Р
PRED,ON				        ! В принципе не дефолтно с Солидом65
!ARCLEN,ON				! arc-length method
!NSUBST,50
!TIME,10
NLGEOM, OFF				!OFF большие перемещения

/SOLE
solve
websword вне форума  
 
Непрочитано 08.08.2011, 21:15
4 | #4
СергейД

расчеты МКЭ и CFD. ктн
 
Регистрация: 11.05.2005
Подмосковье
Сообщений: 2,170


запускать некогда , но очевидное скажу.
вы вообще отключили промеж. шаги. это нельзя
например nsubst,50,1000000,50 надо
число итераций можно уменьшить neqit,7 (50- бессысленно для бетона)
надо активировать запись невязок nldiag,nrre,on
тогда можно видеть, где в к-ции несходимость
arclen забудьте= это не для этих задач. до закритики еще далеко...
nropt,unsym,,on помогает
и установите запись протокола= /outp,,outp
нужно внимтельтно изучить всю диагностику.
рисуйте шаг за шагом и обязательно найдете причину

точность невязок по умолчанию слишком жестока для бетона
и контроль по перемещениям лучше отключить
cnvtol,f,,.5

вообще вывешивайте протокол. запускать задачу вашу некогда. а указать что-то можно сразу же.

линейно решали? убедитесь, что там все безупречно и сетка адекватна.
нарисуйте зоны, где сигма1 превысило предел на растяжение.



зы
реализовал свои советы...
вроде бы логично получилось
может кому пригодится.
Вложения
Тип файла: zip betonansys.zip (1.70 Мб, 579 просмотров)

Последний раз редактировалось СергейД, 09.08.2011 в 20:52. Причина: сделал
СергейД вне форума  
 
Непрочитано 09.08.2011, 22:38
#5
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 599
Отправить сообщение для derik с помощью Skype™


аааааааа...Спасибо Сергей Иванович!

Вот с моментом бы еще помогли

Последний раз редактировалось derik, 09.08.2011 в 22:42. Причина: пожелание
derik вне форума  
 
Непрочитано 10.08.2011, 06:26
#6
СергейД

расчеты МКЭ и CFD. ктн
 
Регистрация: 11.05.2005
Подмосковье
Сообщений: 2,170


интересно, что это за экперимент =сравнить.
кто бы это лирой порешал...
СергейД вне форума  
 
Автор темы   Непрочитано 10.08.2011, 19:23
#7
websword


 
Регистрация: 07.08.2011
Сообщений: 10


Громадное-громадное спасибо )))

Цитата:
Сообщение от СергейД Посмотреть сообщение
интересно, что это за экперимент =сравнить.
В принципе это было исследование работы наклонных сечений при длительном нагружении.
А модель - ну это не совсем экспериментальная балка, я шаги поперечной арматуры и размеры защитного слоя несколько округлил, потому что были сомнения насчет того все это будет работать после NUMMRG,ALL с учетом довольно крупного разбиения бетона(читай с узлами арматуры внутри объемных элементов).
и нагружение, естественно, в одну ступень только(и, говоря строго не последнюю), что конечно не соответствует

Лирой, кстати, решал, но размазывал арматуру. В конце-концов плюнул и сел Ansys разбирать, потому как в пригодности Лиры для численного эксперимента(туда еще ползучесть включить надо будет) у меня возникли очень серьезные сомнения.
Повожусь, сравню и напишу.
websword вне форума  
 
Автор темы   Непрочитано 17.08.2011, 20:09
#8
websword


 
Регистрация: 07.08.2011
Сообщений: 10


К сожалению не мог добраться до сети.
Просчитал, подправил характеристики арматуры и бетона(листинг ниже), только к сожалению не совсем стреляет с экспериментом.
Исходно нагрузка, на которой я тестировал - процентов 90 от разрушающей, так собственно и опытные загружал.
Только модель начинает рушиться при порядка 60%. Причем механизм деформирования в целом правдоподобный, но ускорен, а дальше все схлопывается.
Я б приложил протокол, если б знал что конкретно стоит приложить.
Что отдельной строкой интересно - когда ввожу диаграмму кусочную деформирования для бетона по Бамбуре - сходимость не то что падает - она исчезает как класс.
Попробую еще арматуру размазать, есть у меня ощущение что сходимость будет внятнее.

Код:
[Выделить все]
fini
/clear,start
!/COM,Neutov Alexander
/PREP7
/TITLE, Balka_27
ANTYPE,STATIC! тип анализа – статический
/UNITS,SI

!Параметры балки
l=1				! Длина балки
h=0.22				! Высота балки
b=0.05				! Ширина балки
c=0.35				! Пролет среза
sh_f_v=h+0.04			! Высота балки+толщина силы/пластинки
a_s1=0.02			! Толщина защитного слоя снизу/сверху
a_sb=0.02			! Толщина защитного слоя сбоку
A_s=1.54E-4			! Площадь нижней рабочей арматуры в м2
A_s_str=0.785E-4		! Площадь верхней арматуры в м2
A_sw=0.2827E-4		! Площадь поперечной арматуры в м2

! Секция элементов и констант
ET,1,SOLID65			! тип элемента – солид65(бетон)
R,1                 			! реал константы под него
ET,2,LINK8                  		! тип элемента – линк8 (арматура)
R,2,A_s                     		! площадь арматуры продольной нижней
R,3,A_s_str			! площадь арматуры продольной верхней
R,4,A_sw			! площадь арматуры поперечной 
ET,3,SOLID45			  ! тип элемента – солид45(стальная опора/сила)
R,5

!Секция свойств материалов
E_x_s=2.187499E11			! Модуль упругости стали продольной арматуры
E_x_sw=2E11			! Модуль упругости стали поперчной арматуры
E_x_b=3.94722222E10			! Модуль упругости бетона(начальный)

MP,EX,1,E_x_b          		! материал, линейный, 1(бетон), модуль упругости
MP,NUXY,1,0.2	     	! малый ?модуль пуассона 


MP,EX,2,E_x_s              	! материал, линейный, 2(сталь), модуль упругости
MP,NUXY,2,0.3	     	!модуль пуассона 
TB,kinh,2,1,13
tbpt,defi,0.0001,2.187499E7
tbpt,defi,0.00074,14E7
tbpt,defi,0.00137,26E7
tbpt,defi,0.002,38E7
tbpt,defi,0.003,50E7
tbpt,defi,0.005,50E7
tbpt,defi,0.007,50E7
tbpt,defi,0.009,50E7
tbpt,defi,0.011,50E7
tbpt,defi,0.013,50E7
tbpt,defi,0.015,50E7
tbpt,defi,0.017,50E7
tbpt,defi,0.02,50E7


MP,EX,3,E_x_s                 	! Все тоже самое для стали поперечной арматуры
MP,NUXY,2,0.3
TB,BISO,3
TBDATA,1,2.5E08
TBDATA,2,1.45E09

MP,EX,4,E_x_s                 	! Сталь опоры/силы
MP,NUXY,4,0.3

!Создание модели
! Продольная арматура
		!Нижняя
TYPE,2				! Тип элемента
MAT,2				! Материал
REAL,2			! Выбор р.к.
K,25,0,a_s1,b-a_sb		!Кейпойнты
K,26,l, a_s1,b-a_sb
L,25,26
MSHKEY,1
MOPT,QMESH,MAIN
		        ! Верхняя		
REAL,3			! Выбор р.к.
K,27,0,h-a_s1,b-a_sb
K,28,l,h-a_s1,b-a_sb
L,27,28
		 ! Мешинг продольной арматуры
LSEL,S,LINE,,1,2,1,1		! Выбор линий для применения параметров мешинга
LESIZE,ALL,0.02,,,,,,1		! Задание шага для мешинга
REAL,2			! Выбор р.к.
LMESH,1,1,1			! Мешинг нижней арматуры
REAL,3			! Переход к 3й р.к.
LMESH,2,2,1			! Мешинг верхней арматуры

	! Поперечная арматура
MAT,3				! Переход на сталь поперечной арматуры
REAL,4			! Переход к р.к.  поперечной арматуры
		! Создание линий поперечной арматуры
num=28
*DO,I,1,5
REAL,4
num=num+1
K,num,0.02+(i-1)*0.04,a_s1,b-a_sb
num=num+1
K,num,0.02+(i-1)*0.04,h-a_s1,b-a_sb
L,num-1,num
*ENDDO


*DO,I,1,6
num=num+1
K,num,0.02+4* 0.04+i*0.08,a_s1,b-a_sb
num=num+1
K,num, 0.02+4* 0.04+i*0.08,h-a_s1,b-a_sb
L,num-1,num
*ENDDO

num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04,a_s1,b-a_sb
num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04,h-a_s1,b-a_sb
L,num-1,num

num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2,a_s1,b-a_sb
num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2,h-a_s1,b-a_sb
L,num-1,num


num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2+0.175/2,a_s1,b-a_sb
num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2+0.175/2,h-a_s1,b-a_sb
L,num-1,num

num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2+0.18,a_s1,b-a_sb
num=num+1
K,num,0.02+4* 0.04+6*0.08+0.04*2+0.18,h-a_s1,b-a_sb
L,num-1,num
		! Мешинг поперечной арматуры
LSEL,S,LINE,,3,17,1,1		! Выбор линий для применения параметров мешинга
LESIZE,ALL,0.02,,,,,,1		! Задание шага для мешинга
LMESH,3,17,1			! Мешинг

LSEL,S,LINE,,ALL		! Выбор всех линий
NSEL,S,NODE,,ALL		! Выбор всех точек
NUMMRG,NODE
NUMMRG,KP


! Создание бетонных блоков
TYPE,1				! Задание элемента, материала и констант
MAT,1
REAL,1

k,1,0,0,0			! Кейпойнты для поперечного сечения			
k,2,0,h,0
k,3,0,0,b
k,4,0,h,b	
a,1,3,4,2			! Плоскость для экструзии
allsel
asel,s,,,1			! Выбор плоскости для экструзии
vext,all,,,l			! Экструзия по выборке на 1м

! Создание опоры и силы
TYPE,3				! Задание элемента, материала и констант
MAT,4
REAL,5

	!Опора
K,9,0.18,0,0			! Кейпойнты
K,10,0.18,0,b
K,11,0.18,-0.04,0
K,12,0.18,-0.04,b
A, 9,11,12,10			! Плоскость для экструзии

	! Сила
K,17,0.18+c,0+ sh_f_v,0		! Кейпойнты
K,18,0.18+c,0+ sh_f_v,b
K,19,0.18+c,-0.04+ sh_f_v,0
K,20,0.18+c,-0.04+ sh_f_v,b
A, 17,19,20,18				! Плоскость для экструзии


ALLSEL
ASEL,s,,,7,8				! Выбор плоскости для экструзии
VEXT,7,8,1,0.04			! Экструзия по выборке на 4см

DA,2,SYMM
DA,6,SYMM


! Мешинг массивов
MSHKEY,1				! Тип мешинга - mapped
MOPT,QMESH,MAIN			! Опции мешинга - четырехугольный
ESIZE,0.01				! Размер границы элемента для мешинга
	! Мешинг бетона
TYPE,1					! Параметры элементов и материалов
MAT,1
REAL,1
VMESH,1,1,1				! Мешинг бетона
TYPE,3					! Параметры элементов и материалов
MAT,4
REAL,5

VMESH,2,3,1				! Мешинг силы и опоры	

ALLSEL

!Секция merge
NUMMRG,NODE
NUMMRG,KP

!Секция опор, закреплений и симметрии

!Секция опор, закреплений и симметрии
DTRAN,ALL
D,14252,UY,0
D,14252,UZ,0
D,14270, UY,0
D,14270, UZ,0
D,14273, UY,0
D,14273, UZ,0
D,14276, UY,0
D,14276, UZ,0
D,14279, UY,0
D,14279, UZ,0
D,14267,UY,0
D,14267,UZ,0


allsel
! Секция нагрузок (ОМГ)
!	надо на оси симм нагрузку половинить
!	или лучше задать давлением

Fd=13333
F,14405,FY,-Fd/2
F,14453,FY,-Fd
F,14450,FY,-Fd
F,14447,FY,-Fd
F,14444,FY,-Fd
F,14432,FY,-Fd

! fsum=13333*(6)*2=16e4!	16 тонн
!___________________ дополнение ____________
/pnum,mat,1
/num,1
eplo

/outp,,outp

/pbc,u,,2
nsel,s,loc,z,0!	узлы накладок тоже дб симметризованы
	d,all,uz
	allsel

tbdele,all,1!	заново определим бетон
	rbc=25.5e6
	rbt=2.37e6
  	EPC1=1.81E-3
	EPC2=3.95E-3! предельные деформации
rr=.60!	трехлинейная диаграмма по СП
!	модель позволет учесть нисходящую ветвь диаграммы
TB,kinh,1,1,4
tbpt,defi,rr*RBC/E_x_b,rr*RBC
tbpt,defi,EPC1,RBC*.99
tbpt,defi,EPC2,RBC*1
tbpt,defi,EPC2*1.2,RBC*.2
! диаграмма по бамбуре
! TB,kinh,1,1,15
! tbpt,defi,0.001811,2.548365E7
! tbpt,defi,0.0014,2.452356E7
!tbpt,defi,0.001,2.138041E7
! tbpt,defi,0.00085,1.95261E7
! tbpt,defi,0.00075,1.805912E7
! tbpt,defi,0.00065,1.639544E7
! tbpt,defi,0.00055,1.452426E7
! tbpt,defi,0.00045,1.243433E7
! tbpt,defi,0.00035,1.011402E7
! tbpt,defi,0.00025,0.7551218E7
! tbpt,defi,0.00016,0.5027027E7
! tbpt,defi,0.0001,0.3224825E7
! tbpt,defi,0.00006,0.196861E7
! tbpt,defi,0.00001,	0.03352284E7
! tbpt,defi,0,0

TB,CONCR,1			! создает таблицу для нелинейных свойств бетона(1)
TBDATA,1,0.3,0.8,rbt,-1 
	на сжатие работа по диаграмме
tbdata,9,.2!	остаточная прочность
 
keyopt,1,6,3!		вывод пластики в арматуре
keyopt,1,3,2!	доп грузовой вектор для лучшей сходимости
keyopt,1,7,1!

	nc=node(L,0,0)!	узел мониторинга

	
/solu
ANTYPE,STATIC			! тип анализа – статический
AUTOTS,ON				! Авто таймстеппинг
OUTRES,ALL,all

monitor,2,nc,uy

NROPT,unsym,,on!	несимм решатель	 с прогноз-коррекцией	
LNSRCH,ON!		линейный поиск	



cnvtol,f,,.50!невязка контролируется только для сил и приближенно
NLGEOM, On		!большие перемещения
nldiag,nrre,on
cutcon,noshape,1!		отказ от контроля искажения формы	
cutcon,plslimit,1.0!		

NSUBST,100,1e6,100	!		шагов побольше
NEQIT,10		! число итераций на шаге поменьше
	TIME,16!		время в тоннах
	SOLVE,,,,,nocheck!	нет проверки искажения формы и разрушения

Последний раз редактировалось websword, 17.08.2011 в 20:32.
websword вне форума  
 
Непрочитано 18.08.2011, 05:30
#9
СергейД

расчеты МКЭ и CFD. ктн
 
Регистрация: 11.05.2005
Подмосковье
Сообщений: 2,170


значит, нужно подгонять х-ки. они не могут быть такой же догмой, как размеры.
их откуда брали?
СергейД вне форума  
 
Автор темы   Непрочитано 04.09.2011, 19:54 Большой перерыв...
#10
websword


 
Регистрация: 07.08.2011
Сообщений: 10


...забурился в теоретическую литературу. И нечего было толком ответить.
С характеристиками материалов чего только я не делал, но приемлемого совпадения с экспериментом не добился(упрочнение бетона в 4-4,5 раза по сравнению с проектной его прочностью за 1,5 года пусть даже в благоприятных условиях - это на мой взгляд неразумно; второй вариант увеличение несущей способности рабочего армирования хотя бы в 1.5-1.7 раз).
По глупости своей бетонных кубов под каждую серию балок я не давил(хотя и забивал), ограничился начальным соответствием В25 благо состав постоянен, и щебень с песком закупались разово.
Можно конечно исправить это сейчас и получить хотя бы верхнюю границу того, как изменились свойства моего бетона. Чем, вероятно, с понедельника и займусь.

По ходу чтения возникли определенные сомнения в адекватности модели solid65 под мою задачу. Потому как после начала трещинообразования процесс развивается очень уж быстро, а solid65, я так понял, разрабатывался под плотины с трехмерным напряженным состоянием.
Просчитал со 185м - и получил прекрасное совпадение, с разницей в пределах 5-8%(исходя из упрочнения бетону по СП).
Но, насколько я понимаю 185й не учитывает не только трещинообразования, но и разрушения, т.е. concrete я с таким же успехом мог не задавать вовсе, и бетон у меня сейчас нелинейно-изотропный материал?


Параллельно начал ковырять вопрос реализации ползучести
и что мне категорически неясно и буду очень благодарен, если кто подскажет - это значение колонки "equi stress" во входных данных Creep Curve Fitting.
У меня Ansys 12.0 и он, к сожалению собственный пример Creep Curve Fitting из справки не принимает, выдает
"Error: syntax error in expression "numrow6": variable reference require preceding$"
складывается впечатление что всяких creq, dcreq, seqv, temp он понимать не желает.

см
Код:
[Выделить все]
diag.txt
/seqv,4000	! indicate this creep has a constant stress of 4000
/temp,100	! indicate this creep data is at a constant temperature of 100
/1,creq		! indicate first column is creep strain
/2,dcreq	! indicate second column is creep strain rate
0.00215869 0.000203055
0.00406109 0.000181314
0.00664691 0.000165303
0.0102068 0.000152217
0.0151416 0.000140946
0.0220102 0.000130945
Код:
[Выделить все]
TBFT,EADD,1,creep,f:\diag.txt
websword вне форума  
 
Непрочитано 06.09.2011, 10:18
#11
СергейД

расчеты МКЭ и CFD. ктн
 
Регистрация: 11.05.2005
Подмосковье
Сообщений: 2,170


советую воспроизвести чужой авторитетный тест. Бреслер_скорделис например или из wOLANSKI
А уж потом (если получится) браться за собственный. на Вашу задачу времени сейчас, уж не обессудьте, совершенно нет.
как мне помнится, есть ограничение на применяемые схемы ползучести. только явные разрешены для 65.
проверьте.
СергейД вне форума  
 
Автор темы   Непрочитано 18.09.2011, 18:59
#12
websword


 
Регистрация: 07.08.2011
Сообщений: 10


Последовал вашему совету
Взял Волански.
И получил разницу в несущей способности порядка тех же 25% в сторону ее уменьшения, что и с моими данными.
Решил спуститься ниже. Взял в качестве поверочной балку без поперечной арматуры(которую автор книги, где я ее позаимствовал, рассчитывал МКЭ) - такая же картина.



Код:
[Выделить все]
/clear,start
/COM,Neutov Alexander
/PREP7
/TITLE, Klovanich
ANTYPE,STATIC! тип анализа – статический
/UNITS,SI

!Параметры балки
l=1.8				! Длина балки
h=0.3				! Высота балки
b=0.15				! Ширина балки
c=0.69				! Пролет среза
sh_f_v=h+0.02			! Высота балки+толщина силы/пластинки
a_s1=0.03			! Толщина защитного слоя снизу/сверху
a_sb=0.03			! Толщина защитного слоя сбоку
A_s=3.801E-4			! Площадь нижней рабочей арматуры в м2
A_s_str=2.545E-4		! Площадь верхней арматуры в м2
A_sw=0.2827E-4		! Площадь поперечной арматуры в м2


ET,1,SOLID65			! тип элемента – солид65(бетон)
R,1                 			! реал константы под него
ET,2,LINK8                  		! тип элемента – линк8 (арматура)
R,2,A_s                     		! площадь арматуры продольной нижней
R,3,A_s_str			! площадь арматуры продольной верхней
R,4,A_sw			! площадь арматуры поперечной
ET,3,SOLID45			  ! тип элемента – солид45(стальная опора/сила)
R,5

E_x_s=1.87096E11			! Модуль упругости стали продольной арматуры
E_x_sw=2.1E11			! Модуль упругости стали поперчной арматуры
E_x_b=3.0E10			! Модуль упругости бетона(начальный)

MP,EX,1,E_x_b          		! материал, линейный, 1(бетон), модуль упругости
MP,NUXY,1,0.2	     	! малый ?модуль пуассона

rbc=18.5e6
rbt=1.6e6
EPC1=2.5E-3
EPC2=3.5E-3! предельные деформации
rr=.60!	трехлинейная диаграмма по СП
!	модель позволет учесть нисходящую ветвь диаграммы
TB,kinh,1,1,4
tbpt,defi,rr*RBC/E_x_b,rr*RBC
tbpt,defi,EPC1,RBC*.99
tbpt,defi,EPC2,RBC*1
tbpt,defi,EPC2*1.2,RBC*.2

TB,CONCR,1			! создает таблицу для нелинейных свойств бетона(1)
TBDATA,1,0.3,0.9,rbt,-1
	! на сжатие работа по диаграмме
tbdata,9,.2!	остаточная прочность

keyopt,1,6,3!		вывод пластики в арматуре
keyopt,1,3,2!	доп грузовой вектор для лучшей сходимости
keyopt,1,7,1!

MP,EX,2,E_x_s              	! материал, линейный, 2(сталь), модуль упругости
MP,NUXY,2,0.3	     	!модуль пуассона
TB,kinh,2,1,3
tbpt,defi,0.0031/2,29E7
tbpt,defi,0.0031,58E7
tbpt,defi,0.02,58E7

MP,EX,3,E_x_sw                 	! Все тоже самое для стали поперечной арматуры
MP,NUXY,2,0.3
TB,BISO,3
TBDATA,1,235E07
TBDATA,2,1.25E09

MP,EX,4,E_x_s                 	! Сталь опоры/силы
MP,NUXY,4,0.3

! Создание модели
! Продольная арматура
		!Нижняя
TYPE,2				! Тип элемента
MAT,2				! Материал
REAL,2			! Выбор р.к.
K,25,0,a_s1,a_sb		!Кейпойнты
K,26,l, a_s1,a_sb
L,25,26
K,27,0,a_s1,b-a_sb		!Кейпойнты
K,28,l, a_s1,b-a_sb
L,27,28
MSHKEY,1
MOPT,QMESH,MAIN
		        ! Верхняя
REAL,3			! Выбор р.к.
K,29,0,h-a_s1,a_sb
K,30,l,h-a_s1,a_sb
L,29,30
K,31,0,h-a_s1,b-a_sb
K,32,l,h-a_s1,b-a_sb
L,31,32
allsel
		 ! Мешинг продольной арматуры
LSEL,S,LINE,,1,4,1,1		! Выбор линий для применения параметров мешинга
LESIZE,ALL,0.03,,,,,,1		! Задание шага для мешинга
REAL,2			! Выбор р.к.
LMESH,1,2,1			! Мешинг нижней арматуры
REAL,3			! Переход к 3й р.к.
LMESH,3,4,1			! Мешинг верхней арматуры

! Создание бетонных блоков
TYPE,1				! Задание элемента, материала и констант
MAT,1
REAL,1

k,1,0,0,0			! Кейпойнты для поперечного сечения
k,2,0,h,0
k,3,0,0,b
k,4,0,h,b
a,1,3,4,2			! Плоскость для экструзии
allsel
asel,s,,,1			! Выбор плоскости для экструзии
vext,all,,,l			! Экструзия по выборке на 1м

MSHKEY,1				! Тип мешинга - mapped
MOPT,QMESH,MAIN			! Опции мешинга - четырехугольный
ESIZE,0.03				! Размер границы элемента для мешинга
	! Мешинг бетона
TYPE,1					! Параметры элементов и материалов
MAT,1
REAL,1
VMESH,1,1,1				! Мешинг бетона


ALLSEL

!Секция merge
NUMMRG,NODE
NUMMRG,KP

!Секция опор, закреплений и симметрии
DTRAN,ALL
D,436,UY,0
D,436,UZ,0
D,495, UY,0
D,495, UZ,0
D,554, UY,0
D,554, UZ,0
D,613, UY,0
D,613, UZ,0
D,672, UY,0
D,672, UZ,0
D,377,UY,0
D,377,UZ,0

allsel
! Секция нагрузок (ОМГ)
!	надо на оси симм нагрузку половинить
!	или лучше задать давлением

Fd=120000/6             !120кН - ориентировочная разрушающая нагрузка
F,1353,FY,-Fd
F,1589,FY,-Fd
F,1530,FY,-Fd
F,1471,FY,-Fd
F,1412,FY,-Fd
F,763,FY,-Fd


/pnum,mat,1
/num,1
eplot

/outp,,outp
/pbc,u,,2
nsel,s,loc,x,l!
d,all,ux
allsel

nc=node(L,0,0)!	узел мониторинга

/solu
ANTYPE,STATIC			! тип анализа – статический
AUTOTS,ON				! Авто таймстеппинг
OUTRES,ALL,all

monitor,2,nc,uy

NROPT,unsym,,on!	несимм решатель	 с прогноз-коррекцией
LNSRCH,ON!		линейный поиск



cnvtol,f,,.50!невязка контролируется только для сил и приближенно
NLGEOM, OFF		!большие перемещения /не спасает
nldiag,nrre,on
cutcontrol,noshape,1!		отказ от контроля искажения формы
cutcontrol,plslimit,1.0!

NSUBST,12,1e6,12	!		шагов побольше
NEQIT,10		! число итераций на шаге поменьше
	TIME,120	!		время в тоннах
	SOLVE,,,,,nocheck!	нет проверки искажения формы и разрушения
Схватившись за голову, взял балку уже без арматуры вовсе, прикинул на коленке несущую способность(экспериментальные данные тоже брал) - и та же песня, разве разбег варьируется сильно в зависимости от класса бетона.
Код:
[Выделить все]
/clear,start
/COM,Neutov Alexander
/PREP7
ANTYPE,STATIC! тип анализа – статический
/UNITS,SI

!Параметры балки
l=1				! Длина балки
h=0.22			! Высота балки
b=0.05				! Ширина балки

ET,1,SOLID65			! тип элемента – солид65(бетон)
R,1                 			! реал константы под него
E_x_b=3.0E10			! Модуль упругости бетона(начальный)

MP,EX,1,E_x_b          		! материал, линейный, 1(бетон), модуль упругости
MP,NUXY,1,0.2	     	! малый ?модуль пуассона

rbc=25.48e6
rbt=2.37e6
EPC1=1.811E-3
EPC2=2.5E-3! предельные деформации
rr=.60!	трехлинейная диаграмма по СП

TB,kinh,1,1,4
tbpt,defi,rr*RBC/E_x_b,rr*RBC
tbpt,defi,EPC1,RBC*.99
tbpt,defi,EPC2,RBC*1
tbpt,defi,EPC2*1.2,RBC*.2

TB,CONCR,1			! создает таблицу для нелинейных свойств бетона(1)
TBDATA,1,0.3,0.9,rbt,-1
	! на сжатие работа по диаграмме
tbdata,9,.2!	остаточная прочность

keyopt,1,6,3!		вывод пластики в арматуре
keyopt,1,3,2!	доп грузовой вектор для лучшей сходимости
keyopt,1,7,1!


TYPE,1				! Задание элемента, материала и констант
MAT,1
REAL,1

k,1,0,0,0			! Кейпойнты для поперечного сечения
k,2,0,h,0
k,3,0,0,b
k,4,0,h,b
a,1,3,4,2			! Плоскость для экструзии
allsel
asel,s,,,1			! Выбор плоскости для экструзии
vext,all,,,l			! Экструзия по выборке на 1м

MSHKEY,1				! Тип мешинга - mapped
MOPT,QMESH,MAIN			! Опции мешинга - четырехугольный
ESIZE,0.01				! Размер границы элемента для мешинга
	! Мешинг бетона
TYPE,1					! Параметры элементов и материалов
MAT,1
REAL,1
VMESH,1,1,1				! Мешинг бетона


ALLSEL

!Секция merge
NUMMRG,NODE
NUMMRG,KP

/pnum,mat,1
/num,1
eplot

/outp,,outp
/pbc,u,,2
nsel,s,loc,x,l
d,all,ux
allsel
nsel,s,loc,z,0
d,all,uz
allsel

nc=node(L,0,0)!	узел мониторинга

!Секция опор, закреплений и симметрии
! DTRAN,ALL
D,395,UY,0
D,395,UZ,0
D,494,UY,0
D,494,UZ,0
D,593,UY,0
D,593,UZ,0
D,692,UY,0
D,692,UZ,0
D,791,UY,0
D,791,UY,0
D,296,UZ,0
D,296,UZ,0

allsel
! Секция нагрузок (ОМГ)
!	надо на оси симм нагрузку половинить
!	или лучше задать давлением

Fd=9.0*1000/11      ! суммарная сила 9кН, момент  3,15кНм, теоретическая разрушающая нагрузка порядка 8кН
F,3103,FY,-Fd/2
F,3499,FY,-Fd
F,3400,FY,-Fd
F,3301,FY,-Fd
F,3202,FY,-Fd
F,925,FY,-Fd

keyopt,1,3,2!	доп грузовой вектор для лучшей сходимости
keyopt,1,7,1!

/solu
ANTYPE,STATIC			! тип анализа – статический
AUTOTS,ON				! Авто таймстеппинг
OUTRES,ALL,all
monitor,2,nc,uy

NROPT,unsym,,on!	несимм решатель	 с прогноз-коррекцией
LNSRCH,ON!		линейный поиск

cnvtol,f,,.50!невязка контролируется только для сил и приближенно
NLGEOM, on		!большие перемещения /не спасает
nldiag,nrre,on
cutcontrol,noshape,1!		отказ от контроля искажения формы
cutcontrol,plslimit,1.0!

NSUBST,9,1e6,9	!		шагов побольше
NEQIT,10		! число итераций на шаге поменьше
	TIME,900	!		время в тоннах
	SOLVE,,,,,nocheck!	нет проверки искажения формы и разрушения
К выводу что быстро - это медленно и постепенно, я уже пришел. Текст перелопатил не один десяток раз.
Но не малейшего проблеска понимания, что я делаю глобально не так - так и не получил.
Был бы безумно благодарен, если бы подсказали в чем дело.
Или ткнули носом в текст любого примера (железо)бетонного изогнутого элемента, решенного в солидах.
websword вне форума  
 
Непрочитано 18.09.2011, 20:14
#13
Chardash

Соискатель
 
Регистрация: 12.03.2011
Урал
Сообщений: 1,497


в "KINH Specifications" не нашел SOLID65. Может быть в этом дело?
Chardash вне форума  
 
Непрочитано 18.09.2011, 22:17
3 | #14
СергейД

расчеты МКЭ и CFD. ктн
 
Регистрация: 11.05.2005
Подмосковье
Сообщений: 2,170


зато в 65 разрешены kinh. проверяли= работает по нисходящей. но это в закритике. до нее далеко.
к сожалению, загружен крайне. помочь не могу. Autodyn изучаю.
СергейД вне форума  
 
Непрочитано 20.09.2011, 12:49
1 | #15
Фролов Дмитрий


 
Регистрация: 11.02.2011
Москва
Сообщений: 223


cutcontrol,noshape,1 !отказ от контроля искажения формы
SOLVE,,,,,nocheck !нет проверки искажения формы и разрушения

Это какие-то недокументированные возможности что-ли? В хелпе 13-го Ансиса я таких опций не нашел.


По поводу уменьшения запаса несущей способности:
Выдержка вот из этого документа
3.5 LOADS AT FAILURE
Table 3.2 compares the ultimate loads for the full-size beams and the final loads from the finite
element simulations. ANSYS underestimates the strength of the beams by 5%-24%. One reason
for the discrepancy is that the inclined portions of the steel reinforcement are excluded from the
finite element models. Toughening mechanisms at the crack faces may also slightly extend the
failures of the experimental beams before complete collapse. The finite element models do not
have such mechanisms.

Последний раз редактировалось Фролов Дмитрий, 20.09.2011 в 14:08.
Фролов Дмитрий вне форума  
 
Непрочитано 20.09.2011, 23:17
1 | #16
СергейД

расчеты МКЭ и CFD. ктн
 
Регистрация: 11.05.2005
Подмосковье
Сообщений: 2,170


Дмитрий! вижу, вы только сейчас занялись нелином.
вижу, вы всерьез изучаете мои скрипты.... У меня их еще сотни.
да, это недок. возможности. И вам, инженеру поддержки, советую заглядывать на customer portal
и в интернете на сайт Имаоки.
СергейД вне форума  
 
Автор темы   Непрочитано 24.09.2011, 20:29
#17
websword


 
Регистрация: 07.08.2011
Сообщений: 10


Дмитрий, за документ спасибо, весьма познавательно и полезно.
Только вот, не применимо в моем случае, потому как:
1. Наклонной арматуры нет в помине.
2. Что качается свойств материалов, то ошибка имеет приблизительно такой порядок в достаточном широком диапазоне свойств бетона.
3. Про механизмы упрочнения, возразить нечего, но должен заметить, что в изогнутой балке они получили разницу в разрущающей нагрузке 10%, а 25% - работе на срез.
Может конечно накопительное.
С другой стороны те же Wolanski и Saifullah получили результаты в пределах 5-7%.
Значит что-то все же не так в реализации.
Но в любом случае, большое спасибо.
websword вне форума  
 
Непрочитано 05.01.2012, 23:07
#18
metrox


 
Регистрация: 07.09.2008
Сообщений: 51


Добрый вечер.
Удалось ли решить проблему с расчетом ?
Столкнулся с похожей задачей. Так же имеются некоторые проблемы. Спасибо
metrox вне форума  
 
Автор темы   Непрочитано 19.02.2012, 01:31
1 | #19
websword


 
Регистрация: 07.08.2011
Сообщений: 10


Да как вам сказать.
Неправильно нагрузку задал.
Она была почти в два раза больше проектной. Все перевернул, а в эту сторону не смотрел.
Ну а разница в 10-15% в прогибах и деформациях лечится подгонкой характеристик материала.
websword вне форума  
Ответ
Вернуться   Форум DWG.RU > Программное обеспечение > Расчетные программы > ANSYS > Несходимость. Расчет модели ж/б балки в ANSYS.

Размещение рекламы
Опции темы Поиск в этой теме
Поиск в этой теме:

Расширенный поиск


Похожие темы
Тема Автор Раздел Ответов Последнее сообщение
Расчет плохообтекаемого тела в Ansys CFX Amak ANSYS 6 10.04.2011 09:30
расчет ж/б сечения Жека Железобетонные конструкции 3 13.07.2010 21:16
Усиление балки (двутавр) тавром по нижнему поясу. Расчет в Lira 9.6R3 Alexmf Лира / Лира-САПР 6 08.07.2010 09:10
расчет перекрытия из сборного Ж/Б Maddog2003 Железобетонные конструкции 2 29.12.2005 19:08