| Правила | Регистрация | Пользователи | Поиск | Сообщения за день | Все разделы прочитаны |  Справка по форуму | Файлообменник |

Вернуться   Форум DWG.RU > Программное обеспечение > Расчетные программы > ANSYS > Как заставить плиту работать и работать нелинейно

Как заставить плиту работать и работать нелинейно

Ответ
Поиск в этой теме
Непрочитано 10.05.2018, 09:59 #1
Как заставить плиту работать и работать нелинейно
Turik
 
Регистрация: 13.04.2010
Сообщений: 4

Здравствуйте, считаю плиту перекрытия 4х7м. Использую закон Menetrey с reinf264. В результате выдает ошибку: задача не сходится и прогибы выдает линейные. C concrete всё работает, но там нужно подгонять разбивку КЭ под положение арматуры. Что может быть не так?
Код:
[Выделить все]
/clear,nostart 
/REPLOT,RESIZE
!!!вход в препроцессор
/PREP7 

!Константы

!Геометрия плиты
*set,Tn,60       !Толщина нижней полки
*set,Tv,60       !Толщина верхней полки
*set,Ts,140      !Толщина стенки, диаметр пустот
*set,Dpust,140   !Толщина стенки, диаметр пустот
*set,Lplate,7000 !Длина плиты

!бетон!B25 
*set,E1,10000       !модуль упругости МПа бетона 
*set,ny1,.2         !коэффициент Пуассона бетона
*set,dens1,0.000023    !плотность Н/мм3 бетона 

!арматура!А500 
*set,E2,200000       !модуль упругости МПа стали 
*set,ny2,.3         !коэффициент Пуассона стали 
*set,dens2,0.0000785    !плотность Н/мм3 стали 
*set,As1,113		!Площадь стержня, мм2

!Параметры разбивки
*set,dlk,40		!Размер КЭ элемента по высоте
*set,dld,190		!Размер КЭ элемента по длине и ширине
*set,dlr,30		!Размер КЭ элемента по радиусу

!Строим геометрию
!Целиком
BLOCK, 0, 4000, 0, Tn+Ts+Tv, 0, Lplate 	!№3 Полка верхняя

*DO,I,215,3785,170 !Взять из компоновки сечения плиты, номера 2-23
	CYL4, I, (Tn+Ts+Tv)/2, Dpust/2,,,,Lplate
*ENDDO

!Создаем компоненты для вычитания с объединением сначала
ALLSEL,ALL  
VPLOT  
VSEL, , , ,1
CM,BASE,VOLU
VSEL,NONE, , ,
VSEL, , , ,2, 23
CM,PUST,VOLU
VSEL,NONE, , ,
ALLSEL,ALL  
VPLOT  
!Вычитаем пустоты
VSBV, BASE, PUST

!Задаем материалы
MP,EX,1,E1 
MP,prxy,1,ny1
mp,dens,1,dens1	

! base Menetrey-Willam concrete 
Rc=18.5        ! uniaxial compressive strength
Rt=1.55         ! uniaxial tensile strength
Rb=22.0        ! biaxial compressive strength

psi=35          ! dilatancy angle

! linear hardening softening 
kappa_cm=0.0025-Rc/20.0E3
kappa_cr=0.0025
omega_ci=0.33
omega_cr=0.1

kappa_tr=0.0005
omega_tr=0.2

TB,CONCRETE,1,,,MW
TBDATA,1,Rc,Rt,Rb

TB,CONCRETE,1,,,DILA
TBDATA,1,psi

TB,CONCRETE,1,,,HSD6
TBDATA,1,kappa_cm,kappa_cr,omega_ci,omega_cr,kappa_tr,omega_tr

MP,EX,2,E2 
mp,prxy,2,ny2
mp,dens,2,dens2	
!uimp,2,ex,dens,nuxy,E2,dens2,ny2
TB,KINH,2,1,6,0 
TBTEMP,0
TBPT,,0.0005,100
TBPT,,0.00105,210   
TBPT,,0.005,210 
TBPT,,0.01,210  
TBPT,,0.02,210  
TBPT,,0.025,210 

!!!указание элементов и опций  базового элемента
ET,1,SOLID186
TYPE,1   
MAT,1

!Количество на пустотах
LSEL,NONE, , ,
LSEL,S,LENGTH,,109.96
CM,LINERAD,LINE
LSEL,NONE, , ,
ALLSEL,ALL  
VPLOT
LESIZE,LINERAD,dlr

!Количество на длинных гранях, размер dld 
ALLSEL,ALL  
VPLOT
LSEL, , , ,9
LSEL,A, , ,10
LSEL,A, , ,11
LSEL,A, , ,12
CM,LINEDLIN,LINE
LSEL,NONE, , ,
ALLSEL,ALL  
VPLOT
LESIZE,LINEDLIN,dld
LSEL,NONE, , ,
ALLSEL,ALL  
VPLOT
ESIZE,dlk,0,
vsweep,ALL

!!!указание элементов и опций армирования

!*  
!Типы сечений арматуры
sectype,2,reinf,discrete 	
secdata,2,As1, MESH

ET,2,200,2
mat,2	
secnum,2	
!Рисуем армирование
!Вдоль пустот
numstr,line,1001
J=501
*DO,I,130,3910,170 !Взять из компоновки сечения плиты
	K,J,I,Tn/2,0,
	K,J+1,I,Tn/2,Lplate,
	L,J,J+1
	J=J+2
*ENDDO
!Поперек пустот
numstr,line,2001
J=601
*DO,I,100,Lplate-100,200 !Взять из компоновки сечения плиты
	K,J,0,Tn/2,I,
	K,J+1,4000,Tn/2,I,
	L,J,J+1
	J=J+2
*ENDDO
LSEL, , , ,1001,1023
LSEL,A, , ,2001,2035
CM,LINEARM,LINE
LSEL,NONE, , ,
ALLSEL,ALL  
VPLOT
LESIZE,LINEARM,dld
LMESH,LINEARM
! Генерируем армирование	
! 	
esel,all	
EREINF	
!Удаляем элементы mesh200
!esel,s,ename,,mesh200
lclear,all
!*  
!ETDEL,2 
!ALLSEL,ALL  
!VPLOT

!Связи
!По коротким сторонам
!DL,4, ,UZ,
!DL,4, ,UX,
!DL,4, ,UY,
!DL,5, ,UZ,
!DL,5, ,UX,
!DL,5, ,UY,
!Альтернативное закрепление
DL,4, ,ALL,
DL,5, ,ALL,
DA,6,UX
!По длинным сторонам
!DL,9, ,UZ,
!DL,9, ,UX,
!DL,9, ,UY,
!DL,10, ,UZ,
!DL,10, ,UX,
!DL,10, ,UY,
!Нагрузки
SFA,4,1,PRES,0.01
!Собственный вес
ACEL,0,-0.98,0

!Решение
/SOL
ALLSEL,ALL  
/REPLOT,RESIZE

!Параметры решателя
!*  
!*  
NROPT,FULL
!NROPT,UNSYM,,ON
ANTYPE,0
NLGEOM,ON
!NLGEOM,OFF
OUTRES,ALL,ALL
NSUBST,20,30,10
!NSUBST,100,1000,50
NEQIT,10
AUTOTS,ON
Pred, off 
KBC,0
CNVTOL,F,,0.01,,0.01 ! Сходимость по силе
CNVTOL,U,,0.01,,0.01 ! Сходимость по перемещению
!CNVTOL,F, ,0.1,2,1,
!EQSLV,SPARSE,1E-6

ALLSEL,ALL
/STATUS,SOLU
SOLVE   

etable,N11,smisc,1  
PLETAB,N11,NOAV

/POST26 
FILE,'Plate1-04','rst','.'  
/UI,COLL,1  
NUMVAR,200  
SOLU,191,NCMIT  
STORE,MERGE 
FILLDATA,191,,,,1,1 
REALVAR,191,191 
/VIEW,1,1   
/ANG,1  
/REP,FAST   
!*  
NSOL,2,45638,U,Y, UY_2,1
STORE,MERGE 
XVAR,1  
PLVAR,2,
С балкой из хелпа всё работает.

Код:
[Выделить все]
/CLEAR,NOSTART  
/REPLOT,RESIZE
!!!вход в препроцессор
/prep7
! ELASTIC CONSTANTS
*set,E1,30000       !модуль упругости МПа бетона 
*set,ny1,.2         !коэффициент Пуассона бетона
*set,dens1,0.000023    !плотность Н/мм3 бетона 

!арматура!А500 
*set,E2,200000       !модуль упругости МПа стали 
*set,ny2,.3         !коэффициент Пуассона стали 
*set,dens2,0.0000785    !плотность Н/мм3 стали 
*set,radiusn,6		!Радиус арматуры

!Параметры разбивки
*set,dlk,50		!Размер КЭ элемента по высоте

MP,EX,1,E1 
MP,NUXY,1,ny1
mp,dens,1,dens1	


MP,EX,2,E2 
mp,prxy,2,ny2
mp,dens,2,dens2	

! base Menetrey-Willam concrete 
Rc=18.5        ! uniaxial compressive strength
Rt=1.5         ! uniaxial tensile strength
Rb=22.0        ! biaxial compressive strength

psi=10           ! dilatancy angle

! linear hardening softening 
kappa_cm=0.0025-Rc/20.0E3
kappa_cr=0.0025
omega_ci=0.33
omega_cr=0.1

kappa_tr=0.0005
omega_tr=0.2

TB,CONCRETE,1,,,MW
TBDATA,1,Rc,Rt,Rb

TB,CONCRETE,1,,,DILA
TBDATA,1,psi

TB,CONCRETE,1,,,HSD6
TBDATA,1,kappa_cm,kappa_cr,omega_ci,omega_cr,kappa_tr,omega_tr

!Строим геометрию базового элемента
BLOCK, 0, 250, 0, 500, 0, 3000 !№1 Блок 
!!!указание элементов и опций  базового элемента
ET,1,SOLID186
TYPE,1   
MAT,1
ESIZE,dlk,0,
!Vmesh,1
vsweep,1

!!!указание элементов и опций армирования

!*  
!Типы сечений арматуры
sectype,2,reinf,discrete 	
secdata,2,100, MESH

ET,2,200,2
mat,2	
secnum,2	

!Рисуем армирование
numstr,line,1001
K,101,50,50,0,
K,102,50,50,3000,
K,103,200,50,0,
K,104,200,50,3000,
L,101,102
L,103,104
lesize,1001,,,dlk
lesize,1002,,,dlk
LMESH,1001
LMESH,1002
! Create reinforcing elements via EREINF command	
! 	
esel,all	
EREINF	

!Связи
DL,4, ,ALL,
DL,5, ,ALL,
!Нагрузки
SFA,4,1,PRES,0.16

! Inspect newly created reinforcing elements	
!	
esel,s,type,,1	
! adjust the translucency level of the 	
! base element to reveal the embedded reinforcing	
! elements	
/trlcy,elem,0.9 	
esel,all	
! Activate the expanded element shapes	
/eshape,1    	
eplot

!Решение
/SOL
ALLSEL,ALL  
/REPLOT,RESIZE

!Параметры решателя
!*  
!*  
CNVTOL,U, ,0.9,2, , 
!*  
ANTYPE,0
NLGEOM,1
OUTRES,ALL,ALL
NSUBST,100,1000,50
NEQIT,10
AUTOTS,ON
NROPT,FULL
Pred, off 

!Решение 

ALLSEL,ALL
/STATUS,SOLU
SOLVE
Просмотров: 5201
 
Непрочитано 10.05.2018, 11:52
1 | #2
MrWhite


 
Регистрация: 18.09.2011
Нахабино
Сообщений: 1,040


У вас настройки решателя разные в задачах. Все смотреть не стал, но вот только из-за этого: NSUBST,20,30,10, он точно не сможет ничего сделать. И зачем количество итераций "зарезали" до десяти? Когда угол в даете в градусах, знаете что по-умолчанию в Ansys радианы?
MrWhite вне форума  
 
Автор темы   Непрочитано 10.05.2018, 11:54
#3
Turik


 
Регистрация: 13.04.2010
Сообщений: 4


Про радианы не знал, щас подправлю. Шаги ставил и так NSUBST,100,1000,50, разницы особой нет.
Turik вне форума  
 
Непрочитано 10.05.2018, 12:39
1 | #4
MrWhite


 
Регистрация: 18.09.2011
Нахабино
Сообщений: 1,040


Цитата:
Сообщение от Turik Посмотреть сообщение
Про радианы не знал, щас подправлю. Шаги ставил и так NSUBST,100,1000,50, разницы особой нет.
Смотрите в сторону команды AFUN или *AFUN в справке.
Ну чудес не бывает . Вы достаточно ясно описали проблему: 1) не сходится; 2)там где сошлось все линейно. Это означает, что у Вас несходимость начинается в самый неприятный момент расчета - начало образования трещин. Путей для обеспечения сходимости на данном участке нагрузки много, но обычно один из них не помогает, нужно находить баланс всех. Я перечислю что в первую очередь влияет на сходимость:
1) Размер шага на котором решатель подходит к моменту разрушения и размер шага на который он может откатиться (настраивается в NSUBST);
2) Точность критериев решателя (настраивается в CNVTOL)
3) Параметры материалов отвечающие за плавность начала разрушения (у Вас это kappa_tr и omega_tr)
4) Предельное количество итераций (NEQIT)
И многое другое: тип матрицы, вкл/выкл нелинейных деформаций и т.д.
MrWhite вне форума  
 
Автор темы   Непрочитано 10.05.2018, 12:52
#5
Turik


 
Регистрация: 13.04.2010
Сообщений: 4


Спасибо за ответ! По шагам п.1 и итерациям п.4 эксперимент проводил, похоже тут именно совокупность факторов, которые я не охватил. Буду варьировать их дальше, может что и получится. По прогибам уже прогресс есть! Сходилось на 6 мм, сейчас на 12 мм при ручном счете в 21 мм.
Turik вне форума  
 
Непрочитано 10.05.2018, 12:56
1 | #6
MrWhite


 
Регистрация: 18.09.2011
Нахабино
Сообщений: 1,040


Цитата:
Сообщение от Turik Посмотреть сообщение
Спасибо за ответ! По шагам п.1 и итерациям п.4 эксперимент проводил, похоже тут именно совокупность факторов, которые я не охватил. Буду варьировать их дальше, может что и получится. По прогибам уже прогресс есть! Сходилось на 6 мм, сейчас на 12 мм при ручном счете в 21 мм.
Пробуйте конечно. Без этого никак. Если все равно не получится обращайтесь - посмотрим.
P.S. Это пока сходимость, потом нужно будет понять почему результат не такой как ожидается
MrWhite вне форума  
 
Автор темы   Непрочитано 10.05.2018, 12:59
#7
Turik


 
Регистрация: 13.04.2010
Сообщений: 4


Цитата:
Сообщение от MrWhite Посмотреть сообщение
Пробуйте конечно. Без этого никак. Если все равно не получится обращайтесь - посмотрим.
Спасибо!
Turik вне форума  
Ответ
Вернуться   Форум DWG.RU > Программное обеспечение > Расчетные программы > ANSYS > Как заставить плиту работать и работать нелинейно

Размещение рекламы
Опции темы Поиск в этой теме
Поиск в этой теме:

Расширенный поиск


Похожие темы
Тема Автор Раздел Ответов Последнее сообщение
Не удалось импортировать плиту в Лиру из DXF. 3MEi86 Лира / Лира-САПР 18 15.10.2014 19:01
как заставить работать файл c2.VLX в 2012 акаде Nikolays AutoCAD 2 05.03.2012 07:15
Помогите заставить трещать плиту!! XoXol321 Лира / Лира-САПР 2 26.11.2011 22:58
Как заставить работать AutoCaD c дискретной видеокартой alex-archi AutoCAD 2 10.11.2011 00:46
как заставить прокрутку на мышке работать наоборот в акаде? Смела AutoCAD 2 11.07.2011 21:51