[Mischa]

Здравствуйте. Помогите разобраться с таблицами.
Создать таблицу получилось, а вот изменить число строк и добавить в таблицу текст не получилось.

Dim Table As AcadTable
Dim Point(0 To 2) As Double

Private Sub CommandButton1_Click()
Point(0) = 0: Point(1) = 0: Point(2) = 0
Set Table = ThisDrawing.ModelSpace.AddTable(Point, 200, 6, 20, 30)
End Sub

Private Sub CommandButton2_Click()
Table.Rows = 5
Table.SetText (5, 5, "gfsegf")
End Sub


Table.Rows = 5 "неприменимо"
Table.SetText (5, 5, "gfsegf") "Syntax error"

P.S. Заранее спасибо

[fixo]

См. в хэлпе, там есть много чего полезного для таблиц

Код:

[Выделить все]

Option Explicit

Dim oTable As AcadTable
Dim dblPt(0 To 2) As Double

Private Sub CommandButton1_Click()
dblPt(0) = 0: dblPt(1) = 0: dblPt(2) = 0
Set oTable = ThisDrawing.ModelSpace.AddTable(dblPt, 10, 10, 20, 30)
End Sub

Private Sub CommandButton2_Click()

Dim acCol As New AcadAcCmColor
acCol.ColorMethod = acColorMethodByACI
' заголовок
oTable.TitleSuppressed = False
oTable.SetRowHeight 0, 18#
oTable.SetText 0, 0, "Заголовок таблицы"
oTable.SetCellTextStyle 0, 0, "Standard"
oTable.SetCellTextHeight 0, 0, 17.5
oTable.SetCellAlignment 0, 0, acMiddleCenter
acCol.ColorIndex = acRed
oTable.SetCellContentColor 0, 0, acCol
' вставка строки:
oTable.InsertRows 5, 20, 1 ' где:
' 5 - номер строки начиная с 0 после котрой вставить
' 20 - высота строки
' 1 -количество вставляемых строк
oTable.SetColumnWidth 5, 96#
oTable.SetText 5, 5, "применимо"
oTable.SetCellTextStyle 5, 5, "Standard"
oTable.SetCellTextHeight 5, 5, 12.5
oTable.SetCellAlignment 5, 5, acMiddleCenter
acCol.ColorIndex = acYellow
oTable.SetCellContentColor 5, 5, acCol

Unload Me
End Sub

~'J'~

[Mischa]

Спасибо большое!

[fixo]

Успехов,

~'J'~