[Radle]

Здравствуйте!
Уже довольно давно бьюсь с решением казалось бы элементарной задачи - одна половина кольца нагружена давлением по определенному закону. Для материала кольца использую элемент Plane82. При решении задачи никак не могу добиться сходимости. В ансисе работаю недавно и с решением нелинейных задач постоянно возникают проблемы.
Уважаемые участники форума, подскажите пожалуйста как мне решить данную задачу и что я делаю не так.

P.S. Первоначально при запуске задачи возникала ошибка: Negative Jacobian 2D. Методом тыка я её убрал, но сам не знаю как. Подскажите пожалуйста, откуда возникает отрицательный якобиан и что надо в этом случае делать?

В приложении прикладываю файл с кодом.
Заранее благодарю за помощь!

[Фролов Дмитрий]

ну во первых сетка грубовата, по толщине надо минимум 3 узла иметь

[derik]

потекло?

Код:

[Выделить все]

fini
/clear
/outp,output,txt,d:\ansys\output
!ХАРАКТЕРИСТИКИ СТАЛИ
E=2.05E11 !Модуль упругости стали
Mu=0.3 !Коэффициент Пуассона стали
Sigma_t=316E6 !Предел текучести стали

D=0.54 !Наружный диаметр
Delta=0.01 !Толщина стенки

!Начало работы
/FILNAME, KOLC !Присваиваем имя файлу базы данных
/TITLE, KOLC ! Присваиваем имя заголовку
/UNITS, SI !Система СИ

/PREP7 !вход в препроцессор

!значение нагрузки
q=2E6

!Задание элементов
ET,1, PLANE82 !Определим плоский пластический элемент и присвоим ему номер 1

KEYOPT,1,3,0 ! Плосконапряженное состояние
KEYOPT,1,5,1 ! Напряжения вычисляются в квадратурных точках
KEYOPT,1,6,3 ! Поверхностные силы вычисляются в кв. точках

!Определение свойств билинейного пластического материала (сталь)
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,E
MPDATA,PRXY,1,,Mu  
TB,BISO,1,1,2,  
TBTEMP,0
TBDATA,,Sigma_t,4.4e9,,,, 


!ЗАДАНИЕ ОКРУЖНОСТИ

*AFUN, DEG 
CSYS,1

K,100,0,0,0

j=1
*do,i,180,360,10
K,j,D/2,i
j=j+1
*enddo

*do,i,1,18,1
LARC,i,i+1, 100, D/2
*enddo

K,,d/2,90

LARC,19,20, 100, D/2
LARC,20,1, 100, D/2

CIRCLE,100,(D-2*Delta)/2

LGLUE,ALL
AL,ALL


TYPE, 1 !Первый тип элемента
MAT, 1 !Первый тип материала
!REAL,1

LESIZE,ALL,,,5,1,,,,1 
ALLSEL,ALL


MSHKEY,0
MSHAPE, 1, 2D
SMRTSIZE,2
AMESH, ALL


SFL,9,PRES,q
SFL,8,PRES,(q*0.985)
SFL,7,PRES,(q*0.94)
SFL,6,PRES,(q*0.866)
SFL,5,PRES,(q*0.766)
SFL,4,PRES,(q*0.643)
SFL,3,PRES,(q*0.5)
SFL,2,PRES,(q*0.342)
SFL,1,PRES,(q*0.174)


SFL,10,PRES,q
SFL,11,PRES,(q*0.985)
SFL,12,PRES,(q*0.94)
SFL,13,PRES,(q*0.866)
SFL,14,PRES,(q*0.766)
SFL,15,PRES,(q*0.643)
SFL,16,PRES,(q*0.5)
SFL,17,PRES,(q*0.342)
SFL,18,PRES,(q*0.174)


DK,1,Uy
DK,19,Uy
DK,10,ux 
DK,20,ux 


FINISH !Выход из препроцессора 7
/SOLU !Вход в процессор решения


NLGEOM,1 !эффект больших деформаций

NROPT,UNSYM,,on!	Ньютон-Рафсон несимм решатель с прогноз-коррекцией
LNSRCH,ON!		линейный поиск
PRED, ON ! включен предиктор решений

!AUTOTS, ON !автоматический выбор шага нагружения

NSUBS,1000 !Число подшагов
time,1
nldiag,nrre,on !запись невязок

OUTRES,,ALL
OUTRES,NLOAD,ALL

SOLVE

выделенное жирным - лучше добавить, видно что ему не хватает
напряжения по мизесу превосходят предел текучести...

[Radle]

Сообщение от Фролов Дмитрий ну во первых сетка грубовата, по толщине надо минимум 3 узла иметь

Ок... а как задать по толщине сетку? smrtsize,1 не помогает.

Сообщение от 6pa4o напряжения по мизесу превосходят предел текучести...

Да, они и должны превосходить, некоторые волокна в зоне пластичности.

[derik]

Сообщение от Radle Да, они и должны превосходить, некоторые волокна в зоне пластичности.

на 3 порядка?

вы нагрузку уменьшите и все сойдеться или задайте более прочный материал.

З.Ы. по поводу модели - а почему не решить четвертинку от кольца? сетку по толщине проще простого - нужно разрезать кольцо и поперечные линии lesize-ом разбить на три. все.

[Radle]

Сообщение от 6pa4o на 3 порядка? вы нагрузку уменьшите и все сойдеться или задайте более прочный материал.

Почему на 3 порядка? На последнем шаге напряжения по мизесу 0.379*10^9=379МПа, а у меня предел текучести 316 МПа. Там еще до предела прочности очень далеко, должно всё работать.
Я половину кольца не решаю, потому что банально не знаю как задавать симметрию.


ps Попробовал lesize-ом разбить, как вы и советовали, но сетка дробиться только около данной линии, на всем остальном кольце остается такая же грубая и опять сходимости нет... Что я делаю не так?

[Фролов Дмитрий]

самый быстрый способ это AREFINE,ALL,,,1
но это скорее всего это не поможет сходимости

[Radle]

да... а что же поможет?

Попробовал сделать мелкую сетку с помощью ESIZE,0.003. Всё равно не сходится на том же самом времени счета - как только начинают расти нагрузки в пластичной зоне, сразу расходится.

[Фролов Дмитрий]

могу посоветовать увеличить количество подшагов и посмотреть команду STABILIZE, возможно у вас просто теряет устойчивость конструкция и её нужно "придержать"

[СергейД]

смотреть некогда пока. нарисуйте невязки. мультик сделайте.
добавьте
cutcon,noshap,1

обязательно /outp,,outp
и читайте внимательно диагностики (особенно в каком элементе вырождение наступило.)
biso замените на kinh и добавьте несколько точек на диаграмму вокруг предела текучести= искривите излом графика


лично я не люблю двумерные задачи. элементы с усеченными возможностями. тем более старого образца. перешли бы на 182-183 хотя бы
нужно бы сделать один элемент по толщине и применить 186 или 185. поиграть их опциями.
но что ж вы взялись за пластику, ЕСЛИ ДАЖЕ ЕЩЕ СИММЕТРИЮ НЕ НАУЧИЛИСЬ ДЕЛАТЬ?
не спеша нужно учиться.

[Radle]

Спасибо большое за советы, постараюсь сделать.

Сообщение от СергейД добавьте cutcon,noshap,1 обязательно /outp,,outp и читайте внимательно диагностики (особенно в каком элементе вырождение наступило.) biso замените на kinh и добавьте несколько точек на диаграмму вокруг предела текучести= искривите излом графика

Ок, а есть какая-нибудь литература, где было бы подробно описано как и какие параметры АНАЛИЗИРОВАТЬ в процессе расчета в ансисе, особенно если задача не сходится. На что обратить внимание, какие показатели сходимости и как ими манипулировать и т.д. Например те же самые невязки - как их рисовать и что значят. А то в книгах Конюхова, Басова нету анализа при отсутствии сходимости, и я не знаю что делать. Опытного наставника, который бы объяснял что к чему тоже нету.

Сообщение от СергейД но что ж вы взялись за пластику, ЕСЛИ ДАЖЕ ЕЩЕ СИММЕТРИЮ НЕ НАУЧИЛИСЬ ДЕЛАТЬ? не спеша нужно учиться.

Как говорится: думать некогда-работать надо появился на работе ансис - появилось сто задач. Осваивать продукт приходится по мере поступления проблем, кусками.

[СергейД]

проводим курсы, консультации в мгсу.
я много советовал на форуме. повторять мне уж неловко да и некогда. почитайте мои посты.