[МишаИнженер]

Помогите найти файл acrobat.tlb чтобы можно было запустить код VBA показанный на странице: https://vbaplanet.com/appacrobat.php

Код:

[Выделить все]

Option Explicit

Private Function GetAVApp() As Object

    On Error Resume Next
    Set GetAVApp = GetObject("", "AcroExch.App")
    On Error GoTo 0

    If GetAVApp Is Nothing Then
        Set GetAVApp = CreateObject("AcroExch.App")
    End If

End Function

Public Sub AutomateAdobeAcrobatPDF()

    '''Requires a reference to Adobe Acrobat 10.0 Type Library

    Dim aApp    As Acrobat.AcroApp
    Dim aAVDoc  As Acrobat.AcroAVDoc
    Dim aPDDoc  As Acrobat.AcroPDDoc
    Dim JSO     As Object 'There is no explicit class type for the JSObject

    'Set PDF template file path
    Dim TemplatePath As String
    TemplatePath = "C:\PDFTemplate.pdf"

    'Get Acrobat Application
    Set aApp = GetAVApp()

    'Use the AV layer document object to control how the document is viewed
    Set aAVDoc = CreateObject("AcroExch.AVDoc")
    If Not aAVDoc.Open(TemplatePath, "") Then
        MsgBox "There was a problem opening template: " & TemplatePath, vbCritical
        Exit Sub
    End If

    'Use the PD layer document object to access info about the document
    Set aPDDoc = aAVDoc.GetPDDoc

    'Use the JSObject object to access PDF JavaScript API
    Set JSO = aPDDoc.GetJSObject

    '''Do something''''''''''''''''''''''''
    '''''''''''''''''''''''''''''''''''''''

        'Check a checkbox
        JSO.getField("Checkbox1").checkThisBox 0, True

        'Add a signature from an image file
        'This is a workaround - add a button and add image to button
        Dim SigRect(3) As Single
        SigRect(0) = 400
        SigRect(1) = 65
        SigRect(2) = 500
        SigRect(3) = 30
        JSO.addField "sigbutton", "button", 0, SigRect
        JSO.getField("sigbutton").buttonPosition = 2
        JSO.getField("sigbutton").buttonImportIcon "Signature.png"
        JSO.getField("sigbutton").buttonFitBounds = True

        'Add Date
        Dim DateRect(3) As Single
        DateRect(0) = 360
        DateRect(1) = 55
        DateRect(2) = 405
        DateRect(3) = 42
        JSO.getField("date").rect = DateRect
        JSO.getField("date").Value = Format$(Date$, "dd/mm/yyyy")
        JSO.getField("date").TextSize = 8

    '''''''''''''''''''''''''''''''''''''''
    '''''''''''''''''''''''''''''''''''''''

    'Close Docs
    aPDDoc.Close
    aAVDoc.Close False

    'Exit Adobe
    aApp.Exit

    'Cleanup
    Set JSO = Nothing
    Set aPDDoc = Nothing
    Set aAVDoc = Nothing
    Set aApp = Nothing

End Sub

[stas_org]

У меня лежит по пути:
"C:\Program Files (x86)\Adobe\Acrobat 11.0\Acrobat\acrobat.tlb"

У тебя, скорее всего, там же.

[Boxa]

Так Вам весь акробат нужно установить, там же прямо об этом написано и как установите акробат, там и будет нужный Вам файл, зачем его искать то?

[МишаИнженер]

Сообщение от Boxa Так Вам весь акробат нужно установить, там же прямо об этом написано и как установите акробат, там и будет нужный Вам файл, зачем его искать то?

Выполнил установку, но Акробат все равно не запускается.
В папке Акробата у меня нет папки "\Acrobat 11.0\Acrobat" вместо этого есть папка "Reader 11.0". В этой папке есть папка "Setup Files" и там есть пустая папка с каким-то длинным номером. В общем что-то с установкой Акробата не получается

[trir]

Program Files\Adobe\Acrobat DC\Acrobat

VBA это боль

[AlexCondor]

Сообщение от МишаИнженер В папке Акробата у меня нет папки "\Acrobat 11.0\Acrobat" вместо этого есть папка "Reader 11.0".

Судя по всему вы устанавили только Acrobat Reader, а вам нужен полный Acrobat Pro