[Ольга Т]

Добрый день!
Столкнулась со следующей прблемой: необходимо просчитать стальную балку переменной высоты (типа Венталл). В Gen 3DIN разбила ее на дискретные участки разного сечения, получила приемлемый прогиб, но на прочность и устойчивость проверить затруднилась - закрепление в плоскости рамы фактическое брать нельзя - разная высота сечения на разных участках, какие методики существуют по данному вопросу, посоветуйте!

Сообщение от Ольга Т Спасибо, сейчас делаю расчет в Gen 3Dim, придерживаясь рекомендуемых принципов. Будет интересно сравнить результат

Усилия в стержневых рамных системах зависят от соотношения жесткостей элементов. Я принял соотношение жесткостей как для кубов ваших высот сечения. Потом, когда вы уточните ширину и толщину полки двутаврового сечения и толщину стенки, надо будет пересчитать поточнее, с учетом настоящих J1/J2. Но я думаю, что сильно усилия не изменятся - 5-10% или около того.

Вот решение в ANSYS ED (образовательная версия) с использованием плоского tapered - элемента beam54 (он отличается от того, что в "Раме"). (Так получилось, что по работе давно не приходилось решать такие задачи, поэтому просто стало интересно) Задача пока решена для тех же соотношений жесткостей, что и в FrameWork выше (потом вы их уточните, от соотношений J результаты могут сильно различаться, особенно в середине балки).

Код:

[Выделить все]

!Нагрузка
P1=14.44
P2=28.87
P3=28.87
P4=28.87
P5=29.59
P6=31.04
P7=16.48
P8=16.48
P9=31.04
P10=29.59
P11=28.87
P12=28.87
P13=28.87
P14=14.44
!Геометрические параметры 
L0=-0.3394
L1=2.082
L2=4.485
L3=6.888
L4=9.291
L5=11.819
L6=14.574
h=4.6675
b=0.2823
alpha=5.0379
!Характеристики сечений
A1=0.4
J1=0.4**3/12
HYT1=0.2
HYB1=0.2
!
A2=1
J2=1**3/12
HYT2=0.5
HYB2=0.5
!
A3=0.5
J3=0.5**3/12
HYT3=0.25
HYB3=0.25

!Модуль упругости
E=2.06e8
!
/PREP7
ET,1,BEAM54 

k1=0 $  k2=0.5
*SET,_RC_SET,1, 
R,_RC_SET,A1+(A2-A1)*k1,J1+(J2-J1)*k1,HYT1+(HYT2-HYT1)*k1,HYB1+(HYB2-HYB1)*k1,  
RMODIF,_RC_SET,5,A1+(A2-A1)*k2,J1+(J2-J1)*k2,HYT1+(HYT2-HYT1)*k2,HYB1+(HYB2-HYB1)*k2,  
k1=0.5 $  k2=1
*SET,_RC_SET,2, 
R,_RC_SET,A1+(A2-A1)*k1,J1+(J2-J1)*k1,HYT1+(HYT2-HYT1)*k1,HYB1+(HYB2-HYB1)*k1,  
RMODIF,_RC_SET,5,A1+(A2-A1)*k2,J1+(J2-J1)*k2,HYT1+(HYT2-HYT1)*k2,HYB1+(HYB2-HYB1)*k2,  
k1=0 $  k2=L1/L6
*SET,_RC_SET,3, 
R,_RC_SET,A2+(A3-A2)*k1,J2+(J3-J2)*k1,HYT2+(HYT3-HYT2)*k1,HYB2+(HYB3-HYB2)*k1,  
RMODIF,_RC_SET,5,A2+(A3-A2)*k2,J2+(J3-J2)*k2,HYT2+(HYT3-HYT2)*k2,HYB2+(HYB3-HYB2)*k2,  
k1=L1/L6 $  k2=L2/L6
*SET,_RC_SET,4, 
R,_RC_SET,A2+(A3-A2)*k1,J2+(J3-J2)*k1,HYT2+(HYT3-HYT2)*k1,HYB2+(HYB3-HYB2)*k1,  
RMODIF,_RC_SET,5,A2+(A3-A2)*k2,J2+(J3-J2)*k2,HYT2+(HYT3-HYT2)*k2,HYB2+(HYB3-HYB2)*k2,
k1=L2/L6 $  k2=L3/L6
*SET,_RC_SET,5, 
R,_RC_SET,A2+(A3-A2)*k1,J2+(J3-J2)*k1,HYT2+(HYT3-HYT2)*k1,HYB2+(HYB3-HYB2)*k1,  
RMODIF,_RC_SET,5,A2+(A3-A2)*k2,J2+(J3-J2)*k2,HYT2+(HYT3-HYT2)*k2,HYB2+(HYB3-HYB2)*k2,
k1=L3/L6 $  k2=L4/L6
*SET,_RC_SET,6, 
R,_RC_SET,A2+(A3-A2)*k1,J2+(J3-J2)*k1,HYT2+(HYT3-HYT2)*k1,HYB2+(HYB3-HYB2)*k1,  
RMODIF,_RC_SET,5,A2+(A3-A2)*k2,J2+(J3-J2)*k2,HYT2+(HYT3-HYT2)*k2,HYB2+(HYB3-HYB2)*k2,
k1=L4/L6 $  k2=L5/L6
*SET,_RC_SET,7, 
R,_RC_SET,A2+(A3-A2)*k1,J2+(J3-J2)*k1,HYT2+(HYT3-HYT2)*k1,HYB2+(HYB3-HYB2)*k1,  
RMODIF,_RC_SET,5,A2+(A3-A2)*k2,J2+(J3-J2)*k2,HYT2+(HYT3-HYT2)*k2,HYB2+(HYB3-HYB2)*k2,
k1=L5/L6 $  k2=L6/L6
*SET,_RC_SET,8, 
R,_RC_SET,A2+(A3-A2)*k1,J2+(J3-J2)*k1,HYT2+(HYT3-HYT2)*k1,HYB2+(HYB3-HYB2)*k1,  
RMODIF,_RC_SET,5,A2+(A3-A2)*k2,J2+(J3-J2)*k2,HYT2+(HYT3-HYT2)*k2,HYB2+(HYB3-HYB2)*k2,

mp,ex,1,E	

*AFUN,DEG 
K,1,L0,,,
K,2,0,,,
K,3,L1,,,
K,4,L2,,,
K,5,L3,,,
K,6,L4,,,
K,7,L5,,,
K,8,L6,,,

LSTR,       1,       2  
LSTR,       2,       3  
LSTR,       3,       4  
LSTR,       4,       5  
LSTR,       5,       6  
LSTR,       6,       7  
LSTR,       7,       8  

CSYS,1   
LGEN, ,ALL, , , ,alpha, , , ,1 
CSYS,0  
LGEN, ,ALL, , ,-L6*cos(alpha),h, , , ,1  
KGEN,2,2, , ,-b/2,-h/2, , ,0 
LSTR,       9,       2 
KGEN,2,2, , ,-b,-h, , ,0 
LSTR,       10,       9

 
LSYMM,X,ALL, , , ,0,0 
NUMMRG,KP, , , ,LOW 



!Назначение атрибутов и меширование
LSEL,S,,,1
LSEL,A,,,9,10
LSEL,A,,,18
LATT,1,1,1, , , ,   

LSEL,S,,,8 $  LSEL,A,,,17
LATT,1,2,1, , , , 

LSEL,S,,,2 $  LSEL,A,,,11
LATT,1,3,1, , , ,   

LSEL,S,,,3 $  LSEL,A,,,12 
LATT,1,4,1, , , ,   

LSEL,S,,,4 $  LSEL,A,,,13
LATT,1,5,1, , , ,   

LSEL,S,,,5 $  LSEL,A,,,14
LATT,1,6,1, , , ,   

LSEL,S,,,6 $  LSEL,A,,,15
LATT,1,7,1, , , ,   

LSEL,S,,,7 $  LSEL,A,,,16
LATT,1,8,1, , , ,   

LSEL,ALL
LESIZE,ALL, , ,1, ,1, , ,1, 
LMESH,ALL   

FINISH  
/SOL
 
DK,10, , , ,0,UX,UY, , , , ,  
DK,20, , , ,0,UX,UY, , , , ,  

FK,1,FY,-P1   
FK,3,FY,-P2   
FK,4,FY,-P3  
FK,5,FY,-P4   
FK,6,FY,-P5   
FK,7,FY,-P6   
FK,8,FY,-P7-P8   
FK,17,FY,-P9   
FK,16,FY,-P10 
FK,15,FY,-P11 
FK,14,FY,-P12
FK,13,FY,-P13 
FK,11,FY,-P14 


SOLVE
FINISH
/POST1
etable,N1i,smisc,1      ! нормальная сила N в узле I
etable,N1j,smisc,7      ! нормальная сила N в узле J
etable,Q1i,smisc,2     ! поперечная сила Q в узле I
etable,Q1j,smisc,8     ! поперечная сила Q в узле J
etable,M1i,smisc,6     ! изгибающий момент M в узле I
etable,M1j,smisc,12    ! изгибающий момент M в узле J
etable,smax1i,nmisc,1  !Максимальное напряжение
etable,smax1j,nmisc,3  !Максимальное напряжение
etable,smin1i,nmisc,2  !Минимальное напряжение
etable,smin1j,nmisc,4  !Максимальное напряжение

[ATTACH]1189100643.GIF[/ATTACH]