Как-бы ярлычки листов расположить в 2 ряда

Witalij · 23.01.2008, 13:50

Акад 2006 рус.
В файле от 25 до 70 листов - все ярлыки листов на экране не видно, переключаться между листами геморно.

Пробовал программу Docbar (http://dwg.ru/dnl/3344, она открытые файлы располагает в виде ярлыков, как у листа), хочется что-то подобное, только для ярлыков листа, причём с возможностью расположения их в 2-3 ряда. Тогда можно будет отключить акадовские ярлыки.

Кто-нибудь подобное видел??

dextron3 · 23.01.2008, 17:18

ты читаешь мои мысли я точно такую же тему хотел открыть,..
у меня 120 листов мне бы в три ряда, сколько бы не было листов
все были видны на экране...

T-Yoke · 23.01.2008, 17:23

Цитата:

Сообщение от Witalij

Акад 2006 рус.
В файле от 25 до 70 листов - все ярлыки листов на экране не видно, переключаться между листами геморно.
Пробовал программу Docbar (http://dwg.ru/dnl/3344, она открытые файлы располагает в виде ярлыков, как у листа), хочется что-то подобное, только для ярлыков листа, причём с возможностью расположения их в 2-3 ряда...

Суровые у вас проекты, мне больше чем в 40 листов не удавалось развернуться. Обычно только кратким именем обходился 2-3 символа.
Хотя озвученная идея очень понравилась. Поспрашиваю у знатоков.

Witalij · 23.01.2008, 17:24

Цитата:

Сообщение от T-Yoke

Суровые у вас проекты, мне больше чем в 40 листов не удавалось развернуться. Обычно только кратким именем обходился 2-3 символа.
Хотя озвученная идея очень понравилась. Поспрашиваю у знатоков.

Я листы нумерую 1, 2, 3..... - мельче ярлык уже нельзя...

vvp · 23.01.2008, 17:57

Witalij,
интересно, а 10, 11 ... ?
вариант:
10 - q
11 - w
12 - e ....

Profan · 23.01.2008, 19:30

В 2008-м есть другой способ отображения Layouts на экране. Если отключить строку с листами в рисунке, то в статусной строке список листов можно получить в виде вертикального столбца. Правда, количество строк в этом столбце ограничено и зависит от размера экрана и разрешения. Больше 60 строк на 22-дюймовом мониторе вывести не удалось. Предполагаю, что это глюк графической подсистемы AutoCAD'а. В 2006-м такой возможности нет. Однако, воспользовавшись функцией AutoLisp (Layoutlist) и функцией DCL List_Box можно составить несложную программу вывода списка листов в диалоговом окне... Хотел я написать такую программу, однако полемика в аналогичной теме на форуме caduser.ru как-то остудила мой пыл.

isa · 23.01.2008, 20:18

А пользоваться таким инструментом как Sheet sets (подшивка) не пробовали?

Startrek · 23.01.2008, 20:29

Там в левом уголочке где лайоуты стрелочки - по ним постукать мышкой и лайоуты двигаются

Vova · 23.01.2008, 21:59

70 листов в одном файле. Я только тяжело вздыхаю, потому что спорить неохота уже. Неt у вас причин делать так, кроме неумения

Хмурый · 23.01.2008, 22:05

Интересен размер таких монстроподобных файлов.

Witalij · 24.01.2008, 15:15

Цитата:

Сообщение от Хмурый

Интересен размер таких монстроподобных файлов.

Да нет никаких монстроподобных файлов!

На бот. сад остекление, проект, 57 листов, если именовать листы 1, 2, 3..., то на 40-й лист уже не видно...
В файле - стойки, ригеля, примыкания, узлы крепления... Фасадка AGS150 III группа.

Размер файла - 8800 кб!

Просто много разных стоек и ригелей.
P.S. Файл не тормозит, не зависает, просто НЕУДОБНО ярлычки листов перебирать.

Хмурый · 24.01.2008, 15:19

Цитата:

Сообщение от Witalij

Размер файла - 8800 кб!

Ну-ну, не кипятись. Спасибо за ответ.
Полазил по иностранным сайтам с программами и ничего не нашёл.

Witalij · 24.01.2008, 16:52

Цитата:

Сообщение от Хмурый

Ну-ну, не кипятись. Спасибо за ответ.
Полазил по иностранным сайтам с программами и ничего не нашёл.

Не, я не кипячусь...

Просто большинство здесь пишущих работают в строительстве непосредственно (бетон, метал И т. п.), а моя сфера - фасадное остекление... У нас в КБ даже ни разу не было такого, чтоб файл тормозил Асад - больше 12-15 мб файлов никогда не видел...
Читаю про тормозящий Акад, и думаю - вот люди работают - только шум стоит - сколько-жу е них всего в чертеже...

Хмурый · 24.01.2008, 16:58

3D-моделирование ресурсоёмкая штука.

Vova · 24.01.2008, 17:00

Пусть и не тормозит, но неудобно-же. Гораздо удобнее разделить на файлы и хранить их в одной папке. Кстати, 8 мег это в формате какого автокада?

VVA · 24.01.2008, 17:50

Воспользовавшись идеей Profan'а что-то наваял

Код:

[Выделить все]

;;;Layout switch
(defun C:LS ( / _dwgru-get-user-dcl ret)
;;; ************************************************************************
;;; * Библиотека DWGruLispLib Copyright ©2008  DWGru Programmers Group
;;; *
;;; * _dwgru-get-user-dcl (Кандидат)
;;; *
;;; * Запрос значения у пользователя через диалоговое окно
;;; *
;;; *
;;; * 21/01/2008 Версия 0001. Редакция Владимир Азарко (VVA)
;;; ************************************************************************

(defun _dwgru-get-user-dcl (zagl info-list multi / fl ret dcl_id msg)
;|
* Запрос значения у пользователя через диалоговое окно
* Диалог формируется "налету"
* Параметры вызова:
    zagl - заголовок окна [String]
    info-list - список строковых значений[List of String]
    multi - t - разрешен множественный выбор, nil- нет
    
* Возвращает:
 Список выбранных строк или nil - отмена
* Пример
 (_dwgru-get-user-dcl "Укажите вариант" '("Первый" "Второй" "Третий") nil) ->("Первый") 
 (_dwgru-get-user-dcl "Укажите вариант" '("Первый" "Второй" "Третий") t) ->("Первый" "Второй") 
|;
  (if (null zagl)
    (setq zagl "Выбор")
    ) ;_ end if
  (setq fl (vl-filename-mktemp "dwgru" nil ".dcl"))
  (setq ret (open fl "w"))
  (mapcar '(lambda (x) (write-line x ret))
          (list "dwgru_msg : dialog { "
                (strcat "label=\"" zagl "\";")
                " :list_box {"
                "alignment=top ;"
                (if multi 
                "multiple_select = true ;"
                "multiple_select = false ;"
                  )
                "width=31 ;"
                (if (> (length info-list) 26)
                  "height= 26 ;"
                  (strcat "height= " (itoa (+ 3 (length info-list))) ";")
                  ) ;_ end of if
                "is_tab_stop = false ;"
                "key = \"info\";}"
                "ok_cancel;}"
                ) ;_ end of list
          ) ;_ end of mapcar
  (setq ret (close ret))
  (if (and (null (minusp (setq dcl_id (load_dialog fl))))
           (new_dialog "dwgru_msg" dcl_id)
           ) ;_ end and
    (progn (start_list "info")
           (mapcar 'add_list info-list)
           (end_list)
           (set_tile "info" "0")
           (setq ret "0")
           (action_tile "info" "(setq ret $value)")
           (action_tile "cancel" "(done_dialog 0)")
           (action_tile "accept" " (done_dialog 1)")
           (if (zerop (start_dialog))
             (setq ret nil)
             (setq ret (mapcar (FUNCTION (lambda (num) (nth num info-list)))
                               (read (strcat "(" ret ")"))
                               ) ;_ end mapcar
                   ) ;_ end setq
             ) ;_ end if
           (unload_dialog dcl_id)
           ) ;_ end of progn
    ) ;_ end of if
  (vl-file-delete fl)
  ret
  )
(vl-load-com)
(and
  (setq ret (layoutlist))
  (setq ret (car (_dwgru-get-user-dcl "Выберите лист" (acad_strlsort ret) nil)))
  (setvar "CTAB" ret)
  )
  (princ)
  )

dextron3 · 24.01.2008, 18:38

Идея понравилась, и не только мне

Дополнение:

1. Почему нет вкладки модель, обычно с модели иду в конец,
и затем опять на модель возвращаюсь.

Нашел баг математический в лиспе:

Числа которые не имеют две цыфры а тоесть простые 1, 2, 3, .... 9,
разбрасываются по десяткам, что очень мешает если нужно с 60 листа перейти на 4 й то приходиться искать 40 лист, а потом рядом с ним 4
, а если листов больше 100 то число 20 искать нужно возле 200

см. скриншот.

dextron3 · 24.01.2008, 18:49

Вот посмотрите количество листов:

файл весит 18.5 МБ, компьютер реально тормозит
по 10 листам пробежался ОЗУ заполняется приходится
презагружаться, листы формата А1.

буду ждать комментариев....

voodoo · 24.01.2008, 19:03

Цитата:

Сообщение от isa

А пользоваться таким инструментом как Sheet sets (подшивка) не пробовали?

Поддержую. Вот у меня был недавно РП-150 листов. Я всегда делаю подшивку-с ней очень удобно

. Весь проект виден как на ладоне, к тому же организую в групы... К тому же распечатка всего проекта - только нажатием одной кнопки - и вуаля. Советую переходить на работы с подшивками.

Profan · 24.01.2008, 19:44

Для VVA.
Программа работает так, как я и ожидал. Т.е., выполняется она нормально, однако сортировка листов в диалоговом окне не соответствует порядку листов в стандартном виде. Порядок листов в стандартном виде сохраняется навсегда и новый лист добавляется в конце списка. В программе же может получиться каша из-за сортировки по буквам и цифрам. Я на это обратил внимание еще когда экспериментировал с AutoCAD 2008. Это тоже явилось причиной, по которой я затормозился со своей программой. В принципе, если имена Layouts начинать с 2-х или 3-х значных чисел, то можно ожидать нужный порядок, например: 001Лист...255Лист Вот если бы выдержать тот порядок листов, который получается при создании этих листов?

Кулик Алексей aka kpblc · 25.01.2008, 00:56

Для сортировки (с указанием пространства модели) можно использовать такое:

Код:

[Выделить все]

(vl-load-com)
(defun dwgru-layouts-list (doc)
  (or doc (setq doc (vla-get-activedocument (vlax-get-acad-object))))
  (vl-sort
    ((lambda (/ res)
       (vlax-for item (vla-get-layouts doc)
         (setq res (cons item res))
         ) ;_ end of vlax-for
       ) ;_ end of lambda
     )
    '(lambda (a b)
       (< (vla-get-taborder a) (vla-get-taborder b))
       ) ;_ end of lambda
    ) ;_ end of vl-sort
  ) ;_ end of defun

В результате весь код станет примерно такого типа:

Код:

[Выделить все]

(vl-load-com)
(defun dwgru-layouts-list (doc)
  (or doc (setq doc (vla-get-activedocument (vlax-get-acad-object))))
  (vl-sort
    ((lambda (/ res)
       (vlax-for item (vla-get-layouts doc)
         (setq res (cons item res))
         ) ;_ end of vlax-for
       ) ;_ end of lambda
     )
    '(lambda (a b)
       (< (vla-get-taborder a) (vla-get-taborder b))
       ) ;_ end of lambda
    ) ;_ end of vl-sort
  ) ;_ end of defun

;;;Layout switch
(defun c:ls (/ _dwgru-get-user-dcl ret)
;;; ************************************************************************
;;; * Библиотека DWGruLispLib Copyright ©2008  DWGru Programmers Group
;;; *
;;; * _dwgru-get-user-dcl (Кандидат)
;;; *
;;; * Запрос значения у пользователя через диалоговое окно
;;; *
;;; *
;;; * 21/01/2008 Версия 0001. Редакция Владимир Азарко (VVA)
;;; ************************************************************************

  (defun _dwgru-get-user-dcl (zagl info-list multi / fl ret dcl_id msg)
                             ;|
* Запрос значения у пользователя через диалоговое окно
* Диалог формируется "налету"
* Параметры вызова:
    zagl - заголовок окна [String]
    info-list - список строковых значений[List of String]
    multi - t - разрешен множественный выбор, nil- нет
    
* Возвращает:
 Список выбранных строк или nil - отмена
* Пример
 (_dwgru-get-user-dcl "Укажите вариант" '("Первый" "Второй" "Третий") nil) ->("Первый") 
 (_dwgru-get-user-dcl "Укажите вариант" '("Первый" "Второй" "Третий") t) ->("Первый" "Второй") 
|;
    (if (null zagl)
      (setq zagl "Выбор")
      ) ;_ end if
    (setq fl (vl-filename-mktemp "dwgru" nil ".dcl"))
    (setq ret (open fl "w"))
    (mapcar '(lambda (x) (write-line x ret))
            (list "dwgru_msg : dialog { "
                  (strcat "label=\"" zagl "\";")
                  " :list_box {"
                  "alignment=top ;"
                  (if multi
                    "multiple_select = true ;"
                    "multiple_select = false ;"
                    ) ;_ end of if
                  "width=31 ;"
                  (if (> (length info-list) 26)
                    "height= 26 ;"
                    (strcat "height= " (itoa (+ 3 (length info-list))) ";")
                    ) ;_ end of if
                  "is_tab_stop = false ;"
                  "key = \"info\";}"
                  "ok_cancel;}"
                  ) ;_ end of list
            ) ;_ end of mapcar
    (setq ret (close ret))
    (if (and (null (minusp (setq dcl_id (load_dialog fl))))
             (new_dialog "dwgru_msg" dcl_id)
             ) ;_ end and
      (progn (start_list "info")
             (mapcar 'add_list info-list)
             (end_list)
             (set_tile "info" "0")
             (setq ret "0")
             (action_tile "info" "(setq ret $value)")
             (action_tile "cancel" "(done_dialog 0)")
             (action_tile "accept" " (done_dialog 1)")
             (if (zerop (start_dialog))
               (setq ret nil)
               (setq ret (mapcar (function (lambda (num) (nth num info-list)))
                                 (read (strcat "(" ret ")"))
                                 ) ;_ end mapcar
                     ) ;_ end setq
               ) ;_ end if
             (unload_dialog dcl_id)
             ) ;_ end of progn
      ) ;_ end of if
    (vl-file-delete fl)
    ret
    ) ;_ end of defun
  (vl-load-com)
  (and
    (setq
      ret
       (car (_dwgru-get-user-dcl
              "Выберите лист"
              (mapcar 'vla-get-name (dwgru-layouts-list nil))
              nil
              ) ;_ end of _dwgru-get-user-dcl
            ) ;_ end of car
      ) ;_ end of setq
    (setvar "CTAB" ret)
    ) ;_ end of and
  (princ)
  ) ;_ end of defun

Первоначальные тесты капитальных глюков не показали...

dextron3 · 25.01.2008, 05:36

Цитата:

Сообщение от voodoo

Поддержую. Вот у меня был недавно РП-150 листов. Я всегда делаю подшивку-с ней очень удобно

. Весь проект виден как на ладоне, к тому же организую в групы... К тому же распечатка всего проекта - только нажатием одной кнопки - и вуаля. Советую переходить на работы с подшивками.

Объясни что такое подшивки в чем их приемущества, и в чем недостатки, если они настолько хороши, то почему повсеместно
их не используют?

dextron3 · 25.01.2008, 05:52

VVA спасибо за лисп Кулик Алексей aka kpblc спасибо за доработку
действительно наинужнейший лисп

Преложение:
1. Как в появившемся окошко для выбора страниц появлялись все листы сразу, без скролера. т.е. увеличить окошко или распологать в несколько рядов в зависимости от количества листов.

VVA · 25.01.2008, 09:33

>dextron
За высоту диалогового окна в функции _dwgru-get-user-dcl отвечают эти строчки

Код:

[Выделить все]

 
(if (> (length info-list) 26)
"height= 26 ;"
(strcat "height= " (itoa (+ 3 (length info-list))) ";")
) ;_ end of if

И цифра 26 за кол-во строк без скроллинга. Замени по своему усмотрению

Profan · 25.01.2008, 09:44

Так ведь если задать height, например, 120, то диалоговое окно вылезет за пределы экрана?

Witalij · 25.01.2008, 09:53

Цитата:

Сообщение от Vova

Пусть и не тормозит, но неудобно-же. Гораздо удобнее разделить на файлы и хранить их в одной папке. Кстати, 8 мег это в формате какого автокада?

В формате 2006 Рус.
Только 2Д

Krieger · 25.01.2008, 10:11

Цитата:

Сообщение от dextron3

Объясни что такое подшивки в чем их приемущества, и в чем недостатки

В подшивке можно объеденить несколько файлов с несколькими листами и свободно через подшивку по ним перемещаться. Так, у меня, например, в файле больше 10 листов небывает, и то если там схемки одни, если что-то посложнее, то не больше 4-х. Иначе файл становится неперевариваемым.
Список листов располагается в столбец, что позволяет дать развернутое название.
В подшивке при выборе листа показывается его уменьшенное изображение. А с вашими "очень информативными названиями листов в 3 цифры", это очень кстати.
Через подшивку удобно следить за нумерацией страниц и всевозможными ссылками с листа на лист. Так, добавить лист в середину проекта из ста листов не составит труда.
Так как у всех листов настроена печать, то можно распечатать весь проект одним нажатием на "паблиш". При этом не нужно открывать все файлы проекта.
Минусы: При создании нового листа его нужно импортировать в подшивку, сам он там не появится. Подшивка не запоминает относительные пути к файлам проекта, поэтому при перемещении файлов нарушаются связи.

Цитата:

Сообщение от dextron3

, если они настолько хороши, то почему повсеместно их не используют?

А х.з. почему, вот даже в этой теме про подшивки сказали не один раз, а обратил внимание ты только сейчас, да еще и не пощупал до сих пор.

Witalij · 25.01.2008, 10:13

Сенкс, приложение работает, не глючит.

Вот только хочется, что-бы окно после выбора листа не исчезало с экрана, а выбор листа осуществлялся без нажатия кнопки ОК...
Это вроде называется - немодальное окно???

Кулик Алексей aka kpblc · 25.01.2008, 10:16

И пишется на VBA / arx / .NET

dextron3 · 25.01.2008, 10:42

Кулик Алексей aka kpblc, а за расположение в два ряда какой аргумент изменить?
Кулик Алексей aka kpblc, а если двойной щелчок на выбор листа подвесить?

Больше 70 уже не влазиет в экран выдает ошибку, а это только половина листов

vadim_evg1 · 25.01.2008, 11:06

>Krieger
Насчет подшивок поддерживаю, тока далеко не все могут с ними работать

У меня это выглядит примерно так:

Vova · 25.01.2008, 21:06

Обычно принято сохранять в формате более старой версии, чтобы не было конфуза у тех, кто не догоняет новейшие версии. У тебя получится вдвое тяжелей

Yura · 28.01.2008, 00:39

А я вобще не пойму, чего мешает разработчикам Autodesc-а сделать одну кнопку с раскрывающимся списком layout-ов на весь экран в высоту и с полосой прокрутки, если надо. В конце концов, какая им разница, сколько layout-ов в файле, а раз так, то зачем так сильно ограничивать функциональность перехода с одного на другой, если у них длинноватые названия и их, к примеру, больше 10?
ЗЫ: А еще такая штука увеличила бы размер рабочего пространства, т.к. полоски со вкладками layout-ов больше бы не было...

VVA · 28.01.2008, 09:55

Цитата:

Сообщение от dextron3

Кулик Алексей aka kpblc, а за расположение в два ряда какой аргумент изменить?
Кулик Алексей aka kpblc, а если двойной щелчок на выбор листа подвесить?

Больше 70 уже не влазиет в экран выдает ошибку, а это только половина листов

Я тут на выходных немного усовершенствовал _DWGRU-GET-USER-DCL
Название команды осталось прежнее: LS

Код:

[Выделить все]

(vl-load-com)
(defun dwgru-layouts-list (doc)
  (or doc (setq doc (vla-get-activedocument (vlax-get-acad-object))))
  (vl-sort
    ((lambda (/ res)
       (vlax-for item (vla-get-layouts doc)
         (setq res (cons item res))
         ) ;_ end of vlax-for
       ) ;_ end of lambda
     )
    '(lambda (a b)
       (< (vla-get-taborder a) (vla-get-taborder b))
       ) ;_ end of lambda
    ) ;_ end of vl-sort
  ) ;_ end of defun
;;; ************************************************************************
;;; * Библиотека DWGruLispLib Copyright ©2008  DWGru Programmers Group
;;; *
;;; * _dwgru-get-user-dcl (Кандидат)
;;; *
;;; * Запрос значения у пользователя через диалоговое окно
;;; *
;;; *
;;; * 26/01/2008 Версия 0002. Редакция Владимир Азарко (VVA)
;;;              - Выход по двойному клику, если запрещен множественный выбор (multi-nil)
;;;              - Обработка нескольких колонок
;;; * 21/01/2008 Версия 0001. Редакция Владимир Азарко (VVA)
;;; ************************************************************************
 
(defun _DWGRU-GET-USER-DCL (ZAGL        INFO-LIST   MULTI
                            /           FL          RET
                            DCL_ID      MAXROW      MAX_COUNT_COL
                            COUNT_COL   I           LISTBOX_HEIGHT
                            LST         _LOC_FINISH _LOC_CLEAR
                            NCOL
                           )
                           ;|
* Запрос значения у пользователя через диалоговое окно
* Диалог формируется "налету"
* Количество строк на страницу без скроллинга задается переменной MAXROW.
* Необходимо помнить, что число MAXROW увеличивается на 3.
* Максимальное количество колонок задается переменной MAX_COUNT_COL
* Параметры вызова:
    zagl - заголовок окна [String]
    info-list - список строковых значений[List of String]
    multi - t - разрешен множественный выбор, nil- нет
 
* Возвращает:
 Список выбранных строк или nil - отмена
* Пример
 (_dwgru-get-user-dcl "Укажите вариант" '("Первый" "Второй" "Третий") nil) ;_->("Первый") 
 (_dwgru-get-user-dcl "Укажите вариант" '("Первый" "Второй" "Третий") t) ;_->("Первый" "Второй")
 (_dwgru-get-user-dcl "Укажите вариант"
   (progn (setq i 0 lst nil)(repeat 205 (setq lst (cons (strcat "Значение-" (itoa (setq i (1+ i)))) lst)))(reverse lst)) nil)
 (_dwgru-get-user-dcl "Укажите вариант, используя CTRL и SHIFT для выбора"
   (progn (setq i 0 lst nil)(repeat 205 (setq lst (cons (strcat "Значение-" (itoa (setq i (1+ i)))) lst)))(reverse lst)) t)
|;
 ;_ ===== КОНСТАНТЫ ============
  (setq MAXROW 40) ;_мак. кол-во строк без скроллинга (К нему дальше добавится еще 3 строчки)
  (setq MAX_COUNT_COL 5) ;_максимальное количество колонок
;;;==================== Локальные фунцкции START==================================
  (defun _LOC_FINISH ()
    (setq I   0
          RET NIL
    ) ;_ end ofsetq
    (repeat COUNT_COL
      (setq I (1+ I))
      (setq RET (cons (cons I (get_tile (strcat "info" (itoa I)))) RET))
    ) ;_ end ofrepeat
    (setq RET (reverse RET))
    (done_dialog 1)
  ) ;_ end ofdefun
  (defun _LOC_CLEAR (NOMER)
    (setq I 0)
    (repeat COUNT_COL
      (setq I (1+ I))
      (if (/= I NOMER)
        (progn
          (start_list (strcat "info" (itoa I)))
          (mapcar 'add_list (nth (1- I) LST))
          (end_list)
        ) ;_ end ofprogn
      ) ;_ end ofif
    ) ;_ end ofrepeat
  ) ;_ end ofdefun
;;;==================== Локальные фунцкции END ==================================
;;;==================== MAIN PART ===============================================
  (if (null ZAGL)
    (if (= (getvar "DWGCODEPAGE") "ANSI_1251")
      (setq ZAGL "Выбор")
      (setq ZAGL "Select")
    ) ;_ end ofif
  ) ;_ end if
  (if (zerop (rem (length INFO-LIST) MAXROW)) ;_Целое количество столбцов
    (setq COUNT_COL (/ (length INFO-LIST) MAXROW)) ;_Его и оставляем
    (setq COUNT_COL (1+ (fix (/ (length INFO-LIST) MAXROW 1.0)))) ;_Берем ближайшее целое
  ) ;_ end ofif
  (if (> COUNT_COL MAX_COUNT_COL)
    (setq COUNT_COL MAX_COUNT_COL)
  ) ;_Ограничиваем max количеством
  (setq LISTBOX_HEIGHT (+ 3 MAXROW)) ;_  добавляем 3 строчки для красоты и для исключения пограничного скроллинга
  (if (and (= COUNT_COL 1) (<= (length INFO-LIST) MAXROW))
    (setq LISTBOX_HEIGHT (+ 3 (length INFO-LIST)))
  ) ;_ end ofif
  (setq I 0)
  (setq FL (vl-filename-mktemp "dwgru" NIL ".dcl"))
  (setq RET (open FL "w")
        LST NIL
  ) ;_ end ofsetq
  (mapcar '(lambda (X) (write-line X RET))
          (append (list "dwgru_get_user : dialog { "
                        (strcat "label=\"" ZAGL "\";")
                        ": boxed_row {"
                        (if (= (getvar "DWGCODEPAGE") "ANSI_1251")
                          "label = \"Значение\";"
                          "label = \"Value\";"
                        ) ;_ end ofif
                  ) ;_ end oflist
                  (repeat COUNT_COL
                    (setq LST
                           (append
                             LST
                             (list
                               " :list_box {"
                               "alignment=top ;"
                               (if MULTI
                                 "multiple_select = true ;"
                                 "multiple_select = false ;"
                               ) ;_ end ofif
                               "width=31 ;"
                               (strcat "height= " (itoa LISTBOX_HEIGHT) " ;")
                               "is_tab_stop = false ;"
                               (strcat "key = \"info" (itoa (setq I (1+ I))) "\";}")
                             ) ;_ end oflist
                           ) ;_ end ofappend
                    ) ;_ end ofsetq
                  ) ;_ end ofrepeat
                  (list
                    "}"
                    ":row{"
                    "ok_cancel_err;}}"
                  ) ;_ end oflist
          ) ;_ end of list
  ) ;_ end of mapcar
  (setq RET (close RET))
  (if (and (null (minusp (setq DCL_ID (load_dialog FL))))
           (new_dialog "dwgru_get_user" DCL_ID)
      ) ;_ end and
    (progn
      (setq LST INFO-LIST)
      ((lambda (/ RET1 BUF ITM)
         (repeat (1- COUNT_COL)
           (setq I '-1)
           (while (and (setq ITM (car LST))
                       (< (setq I (1+ I)) MAXROW)
                  ) ;_ end ofand
             (setq BUF (cons ITM BUF)
                   LST (cdr LST)
             ) ;_ end ofsetq
           ) ;_ end ofwhile
           (setq RET1 (cons (reverse BUF) RET1)
                 BUF  NIL
           ) ;_ end ofsetq
         ) ;_ end ofrepeat
         (setq RET RET1)
       ) ;_ end oflambda
      )
      (if LST
        (setq RET (cons LST RET))
      ) ;_ end ofif
      (setq LST (reverse RET))
      (setq I 0)
      (mapcar '(lambda (THIS_LIST)
                 (if (<= (setq I (1+ I)) COUNT_COL)
                   (progn
                     (start_list (strcat "info" (itoa I)))
                     (mapcar 'add_list THIS_LIST)
                     (end_list)
                   ) ;_ end ofprogn
                 ) ;_ end ofif
               ) ;_ end oflambda
              LST
      ) ;_ end ofmapcar
      (set_tile "info1" "0")
      (setq I 0
            NCOL 1
      ) ;_ end ofsetq
      (repeat COUNT_COL
        (action_tile
          (strcat "info" (itoa (setq I (1+ I))))
          (strcat "(progn (setq Ncol "
                  (itoa I)
                  ")(if (not multi)(_loc_clear Ncol))"
                  "(if (and (not multi)(= $reason 4))(_loc_finish)))"
          ) ;_ end ofstrcat
        ) ;_ end ofaction_tile
      ) ;_ end ofrepeat
      (action_tile "cancel" "(done_dialog 0)")
      (action_tile "accept" "(_loc_finish)")
      (if MULTI
        (set_tile "error"
                  (if (= (getvar "DWGCODEPAGE") "ANSI_1251")
                    "Используйте CTRL и SHIFT для выбора"
                    "Use CTRL and SHIFT for a choicet"
                  ) ;_ end ofif
        ) ;_ end ofset_tile
        (set_tile "error"
                  (if (= (getvar "DWGCODEPAGE") "ANSI_1251")
                    "Можно выбирать двойным щелчком"
                    "It is possible to choose double click"
                  ) ;_ end ofif
        ) ;_ end ofset_tile
      ) ;_ end ofif
      (if (zerop (start_dialog))
        (setq RET NIL)
        (progn
          (setq
            RET (apply
                  'append
                  (mapcar
                    '(lambda (ITM)
                       (setq THIS_LIST (nth (1- (car ITM)) LST))
                       (mapcar
                         (function (lambda (NUM) (nth NUM THIS_LIST)))
                         (read (strcat "(" (cdr ITM) ")"))
                       ) ;_ end ofmapcar
                     ) ;_ end oflambda
                    RET
                  ) ;_ end ofmapcar
                ) ;_ end ofapply
          ) ;_ end ofsetq
        ) ;_ end ofprogn
      ) ;_ end if
      (unload_dialog DCL_ID)
    ) ;_ end of progn
  ) ;_ end of if
  (vl-file-delete FL)
  RET
) ;_ end ofdefun
;;;Layout switch
http://dwg.ru/f/showthread.php?t=168...=layout&page=2
(defun c:ls ( / ret)
 (vl-load-com)
  (and
    (setq
      ret
       (car (_dwgru-get-user-dcl
              "Выберите лист"
              (mapcar 'vla-get-name (dwgru-layouts-list nil))
              nil
              ) ;_ end of _dwgru-get-user-dcl
            ) ;_ end of car
      ) ;_ end of setq
    (setvar "CTAB" ret)
    ) ;_ end of and
  (princ)
  ) ;_ end of defun
(princ "\nНаберите LS в командной строке")

dextron3 · 28.01.2008, 10:00

Действительно в АвтоКАД Рапторе (т.е. 2009)
эта функция встроена, на подобие ДОКБАР,
там панелька с листами также перетягивается и формируется как обычные,

Еще можно не открывая чертеж посмотреть сколько в нем лайаутов
и что на них изображено.

Действительно не для слабых компьютеров.

dextron3 · 28.01.2008, 10:09

VVA, наверное нет ничего не возможного что можно сделать на лиспе...

СПАСИБО

PS. А можно сделать чтобы при выборе листа в лиспе,
выбранный лист был на середине листовой панели, а не в самом начале?

VVA · 28.01.2008, 10:13

Цитата:

Сообщение от dextron3

PS. А можно сделать чтобы при выборе листа в лиспе,
выбранный лист был на середине листовой панели, а не в самом начале?

Я пока не знаю, что тебе на это ответить. Поэтому пока ни да, ни нет.

dextron3 · 28.01.2008, 11:09

VVA, я придумал алгоритм как можно сделать, но боюсь тормозить будет:

1. Выбор листа двойным щелком
2. Замер количества листов на экране (именно количестов которое помещается на экране)
3. Количество листов делить на 2
4. Выбранный лист минус количество листов / 2
5. Выбирается предыдущий (см. пункт 4) лист так как он будет вначале листовой панели, то выбранный нами лист окажется посредине.
6. Выбор листа из пункта 1.

Hans667 · 27.02.2008, 16:15

Не правильно наверно чего-то делаю,подскажите пожалуйста,чего за дела?
Command: (_DWGRU-GET-USER-DCL)
; error: too few arguments

Кулик Алексей aka kpblc · 27.02.2008, 16:36

А примеры, предоставленные VVA в коде, прочитать не судьба?

lee · 27.02.2008, 16:58

Цитата:

Сообщение от Yura

А я вобще не пойму, чего мешает разработчикам Autodesc-а сделать одну кнопку с раскрывающимся списком layout-ов на весь экран в высоту и с полосой прокрутки, если надо. В конце концов, какая им разница, сколько layout-ов в файле, а раз так, то зачем так сильно ограничивать функциональность перехода с одного на другой, если у них длинноватые названия и их, к примеру, больше 10?
ЗЫ: А еще такая штука увеличила бы размер рабочего пространства, т.к. полоски со вкладками layout-ов больше бы не было...

Издеваешься.
Сделай Hide Layout and Model tabs. И посмотри, что получится.
Ты не поверишь

Yura · 27.02.2008, 17:07

lee, нет, не издеваюсь, только сегодня где-то про это прочитал, и то якобы для 2008-го, а я сейчас на 2007-м, 2008-й дома, поэтому не торопился пробовать. Сейчас вижу, работает, спасибо за совет..

lee · 27.02.2008, 17:20

Цитата:

Сообщение от Yura

Сейчас вижу, работает

Ну вот, а ты говоришь, чудес не бывает

VVA · 27.02.2008, 17:43

>Hans667 Судя по топику, откуда сюда пришел, думаю вряд ли тебе будет интересно использовать ф-цию _DWGRU-GET-USER-DCL. Подправил пост #34. Перечитай, а на будущее почитай статью по ссылке в моей подписи

Yura · 27.02.2008, 17:48

lee, кстати, тут нет ни Rename, ни Delete, ни Move or Copy, а это не есть хорошо, или я не там смотрю... Раньше эти операции делал из контекстного меню вкладки Layout-a, а сейчас непонятно... Может есть какой другой способ вывести эти команды... Кнопок, чтоли попробовать понаделать?

lee · 27.02.2008, 17:59

Цитата:

Сообщение от Yura

lee, кстати, тут нет ни Rename, ни Delete, ни Move or Copy, а это не есть хорошо, или я не там смотрю... Раньше эти операции делал из контекстного меню вкладки Layout-a, а сейчас непонятно... Может есть какой другой способ вывести эти команды... Кнопок, чтоли попробовать понаделать?

Правым кликом Show Layout and Model tabs. Далее все, что надо ... и снова правый клик.

Sopro · 27.02.2008, 19:31

У меня, машиностроителя, в одном файле бывает и по 150 и по 200 и больше форматов. Причем весьма желательно их все видеть сразу. Не подскажете как быть?

forMA · 27.02.2008, 19:41

Цитата:

Сообщение от Sopro

У меня, машиностроителя, в одном файле бывает и по 150 и по 200 и больше форматов. Причем весьма желательно их все видеть сразу. Не подскажете как быть?

А это ты у Vova спроси

Sopro · 27.02.2008, 19:45

А я и сам знаю. Это нещадно критикуемая матрица форматов в пространстве модели))) А все-таки она вертится! (Галилео Галилей)

Yura · 28.02.2008, 03:13

Цитата:

Сообщение от lee

Правым кликом Show Layout and Model tabs. Далее все, что надо ... и снова правый клик.

Ну, это понятно. Думал, может еще как... И кнопок не понаделать, т.к. непонятно, какой макрос на них цеплять. При команде с контекстного меню вкладки layout-a пишет: <Move or copy layout(s)>. В макросе кнопки это работать не будет.

skkkk · 21.12.2013, 04:31

Цитата:

Сообщение от Witalij

Сенкс, приложение работает, не глючит.
Вот только хочется, что-бы окно после выбора листа не исчезало с экрана, а выбор листа осуществлялся без нажатия кнопки ОК...
Это вроде называется - немодальное окно???

Знаю, что топик бородатый, но раскопав в местном Download некий аналог dwgru-layouts-list, но с немодальным окном, решил оставить тут ссылку.

hexD · 21.12.2013, 08:42

Цитата:
Сообщение от Sopro

У меня, машиностроителя, в одном файле бывает и по 150 и по 200 и больше форматов. Причем весьма желательно их все видеть сразу. Не подскажете как быть?

Подскажем.
1 поверить в то что автокад далеко не единственный и далеко не лучший CAD.
2 перейти на Компас, T-Flex, да пусть даже тот же Арчикад...забудьте о стереотипах - "архикад - для архитекторов" и т.п., это все бред. любой нормальный пакет даст фору автокаду...практически по всем "практическим вопросам"...
В архикаде все НА ПОРЯДОК УДОБНЕЕ.Включая само 2D черчение.

пример организации работы с подшивками(вот откуда они это слово взяли? подшивка - это такая белая трапочка в армии...) в арчикаде...и печать - хоть на принтер хоть в любой другой формат - ну все элементарно, я просто боюсь представить когда автодоски осчастливят пользователей тем чем другие пользуются, ну не наврать, с 1995 года...

а еще в арчикаде бесконечное количество "пространств модели" - называются они "рабочие листы", так что даже если в проекте 1500 тысячи макетов, никаких тормозов в модели не будет...

https://www.dropbox.com/s/f4pnfz39wf...0%BE%D0%B2.avi

357 · 21.12.2013, 11:47

Кулик Алексей aka kpblc, VVA, спасибо огромное!
И как я раньше без неё работал?

Хмурый · 21.12.2013, 18:53

Цитата:

Сообщение от hexD

Цитата:
Сообщение от Sopro

У меня, машиностроителя, в одном файле бывает и по 150 и по 200 и больше форматов. Причем весьма желательно их все видеть сразу. Не подскажете как быть?

Подскажем.
1 поверить в то что автокад далеко не единственный и далеко не лучший CAD.
2 перейти на Компас, T-Flex, да пусть даже тот же Арчикад...забудьте о стереотипах - "архикад - для архитекторов" и т.п., это все бред. любой нормальный пакет даст фору автокаду...практически по всем "практическим вопросам"...
В архикаде все НА ПОРЯДОК УДОБНЕЕ.Включая само 2D черчение.

пример организации работы с подшивками(вот откуда они это слово взяли? подшивка - это такая белая трапочка в армии...) в арчикаде...и печать - хоть на принтер хоть в любой другой формат - ну все элементарно, я просто боюсь представить когда автодоски осчастливят пользователей тем чем другие пользуются, ну не наврать, с 1995 года...

а еще в арчикаде бесконечное количество "пространств модели" - называются они "рабочие листы", так что даже если в проекте 1500 тысячи макетов, никаких тормозов в модели не будет...

Нажмите для просмотра

https://www.dropbox.com/s/f4pnfz39wfnolgs/%D0%9A%D0%BD%D0%B8%D0%B3%D0%B0_%D0%BC%D0%B0%D0%BA%D0%B5%D1%82%D0%BE%D0%B2.avi

это всё великолепно, но могу-ли я создавать для этих чертилок свои программы и приложения?
Завсегда требуется нечто большее, чем...
PS hexD не стоит быть вселенским троллем

ksumatokhin · Регистрация: 04.04.2019

Здравствуйте, у меня вопрос по опубликованной здесь
программе VVA - _DWGRU-GET-USER-DCL #34

Программа создает диалоговое окно, в котором можно выбрать значения.

Вопрос такой: Можно ли добавить в программу "предвыбор" , т.е. к примеру запись:

Код:

[Выделить все]

 (_dwgru-get-user-dcl "Укажите вариант" '("Первый" "Второй" "Третий") "Второй" nil)

Запускала бы окно в котором по умолчанию был выбран вариант "Второй". Нажал ОК - получил ("Второй"),
или выбирай другие значения?

skkkk · 27.01.2020, 21:48

Offtop: ksumatokhin, когда-то давно открыл для себя замечательную библиотеку DOSLib. Она добавляет в арсенал лиспописца много всяких полезных функций, среди которых есть много разных видов диалоговых окон. Вот одно из них, похоже, как раз то, что нужно. На мой взгляд, гораздо удобнее, чем DCL.

ksumatokhin · 27.01.2020, 22:09

skkkk, Вот сейчас для меня просто еще одно грандиозное открытие. Ничего не знал про DOSLib. И для BricsCADа есть. Спасибо за полезную ссылку.

Alex53234 · 15.02.2023, 04:06

Может кому-то этого будет достаточно: можно щелкнуть правой кнопкой по любому листу и внизу выбрать Dock above Status Bar.

VitalyAF · 15.02.2023, 06:13

Alex53234
Где ты был 3 года т.н., малясь опоздал...

23.01.2008, 13:50		#1
Как-бы ярлычки листов расположить в 2 ряда Witalij AL-остекление, фасадка, оконка Москва Регистрация: 25.07.2007 Сообщений: 113 Акад 2006 рус. В файле от 25 до 70 листов - все ярлыки листов на экране не видно, переключаться между листами геморно. Пробовал программу Docbar (http://dwg.ru/dnl/3344, она открытые файлы располагает в виде ярлыков, как у листа), хочется что-то подобное, только для ярлыков листа, причём с возможностью расположения их в 2-3 ряда. Тогда можно будет отключить акадовские ярлыки. Кто-нибудь подобное видел?? __________________ Фасадку черчу...
Просмотров: 22096

Похожие темы
Тема	Автор	Раздел	Ответов	Последнее сообщение
Как именно настроить параметры нового чертежа?	Макс_Северянин	AutoCAD	31	01.09.2010 10:16
Мониторы LCD CRT		Разное	94	17.06.2008 10:51
ЮМОР 2006 =)	Perezz!!	Разное	1122	04.01.2007 00:46