[klaster]

Добрый день.
Необходимо рассчитать ж/б элемент в ANSYSе.
Для решения в моделе использую три элемента:
LINK8 - для арматуры,
SOLID65 - для бетона,
COMBIN39 - для связи бетона и арматуры.
Метод расчета на основании такой модели изложен здесь.
Для LINK8 задается площадь сечения и материал BISO (Bilinear Isotropic hardening Option with von Mises yield Criterion)
Для SOLID65 устанавливается материал БЕТОН (CONCR) с параметрами коэффициентов по передаче напряжений при открытых и закрытых трещинах, и расчетные сопротивления бетона осевому сжатию и растяжению. Арматура, которую можно задать непосредственно в самом элементе SOLID65, не используется.
Для COMBIN39 в Real Constants задается граик деформирования в зависимости от приложенных усилий.
При проверке отдельных элементов (только SOLID65 на сжатие/растяжение) и нескольких элементов (LINK8 и COMBIN39 на растяжение) программа всё подсчитывает адекватно, а при построении полной модели ANSYS не может найти условий равновесия даже при минимальных нагрузках.
К сообщению прикладываю маленькую модель, которая у меня не считается.
Уважаемые форумчане, буду признателен за любую помощь в решении этой проблемы.
Спасибо

Пример использования SOLID65 есть в ансисовской справке. VM146
Bending of a Reinforced Concrete Beam
Решается задача из
S. Timoshenko, Strength of Material, Part I, Elementary Theory and Problems, 3rd Edition, D. Van Nostrand Co., Inc., New York, NY, 1955, pg. 221, article 48.
Вот листинг

Код:

[Выделить все]

/COM,ANSYS MEDIA REL. 9.0 (10/15/2004) REF. VERIF. MANUAL: REL. 9.0
/VERIFY,VM146
/PREP7
/TITLE, VM146, BENDING OF A REINFORCED CONCRETE BEAM
C***    STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 221
ANTYPE,STATIC
ET,1,SOLID65,,,,,2           ! REINFORCED CONCRETE SOLID ELEMENT
ET,2,LINK8                   ! STEEL RODS
ET,3,PIPE16,,,,,,,1          ! DUMMY ELEMENTS FOR CONSTRAINT EQUATIONS
R,1                 
R,2,.15                      ! HALF AREA OF ROD
R,3,1,.5                     ! ARBITRARY CONSTANTS FOR DUMMY ELEMENTS
MP,EX,1,2E6                  ! CONCRETE PROPERTIES
MP,NUXY,1,0
TB,CONCR,1
TBDATA,3,0.0,-1              ! ZERO TENSILE CRACKING STRENGTH
                             ! REMOVE CRUSHING CAPABILITY
MP,EX,2,30E6                 ! STEEL PROPERTIES
MP,NUXY,2,0.3
N,1
N,2,1.5
NGEN,5,2,1,2,1,,1.5
NGEN,2,10,1,10,1,,,5
E,7,8,10,9,17,18,20,19
TYPE,3                       ! DEFINE DUMMY ELEMENTS FOR ROTZ DOF
REAL,3
E,10,8
E,20,18
EGEN,4,-2,1,3
TYPE,2                       ! REINFORCING RODS AT THE BOTTOM SURFACE
MAT,2
REAL,2
E,1,2
E,11,12
CE,1,, 2,UX,-1, 6,UX,1, 6,ROTZ,3        ! CONSTRAINT EQUATION TO ENSURE
CE,2,,12,UX,-1,16,UX,1,16,ROTZ,3        !  PLANE SECTION REMAINS PLANE
CE,3,, 4,UX,-1, 6,UX,1, 6,ROTZ,1.5
CE,4,,14,UX,-1,16,UX,1,16,ROTZ,1.5
CE,5,, 8,UX,-1, 6,UX,1, 6,ROTZ,-1.5
CE,6,,18,UX,-1,16,UX,1,16,ROTZ,-1.5
CE,7,,10,UX,-1, 6,UX,1, 6,ROTZ,-3
CE,8,,20,UX,-1,16,UX,1,16,ROTZ,-3
NSEL,S,LOC,X
D,ALL,ALL                               ! FIX NODES IN Y-Z PLANE
NSEL,ALL
D,ALL,ROTY                              ! CONSTRAIN UNNEEDED PIPE ROTATIONS
F,6,MZ,300,,16,10                       ! APPLY BENDING MOMENT
FINISH
/SOLU    
AUTOTS,ON
NSUBST,5
OUTPR,,LAST
SOLVE
/POST1
ESEL,S,ELEM,,1,1
*GET,SCON,NODE,9,S,X
ESEL,S,ELEM,,13,13
ETAB,ST,LS,1
ESORT,ST
*GET,STL,SORT,,MAX
*status,parm
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'TSTR STL ','TSTR CON'
LABEL(1,2) = ' psi',' psi'
*VFILL,VALUE(1,1),DATA,387.28,-18.54
*VFILL,VALUE(1,2),DATA,STL,SCON
*VFILL,VALUE(1,3),DATA,ABS(STL/387.28),ABS(SCON/18.54)
/COM
/OUT,vm146,vrt
/COM,------------------- VM146 RESULTS COMPARISON --------------
/COM,
/COM,                 |     TARGET   |     ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F12.2,'  ',F12.2,'   ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM146 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm146,vrt

[klaster]

Спасибо, вроде сам разобрался, оказалось, что были неправильно заданы RealConstants для LINK8.
Ещё один вопрос возник. Создал модель используя Symmetric Boundary Conditions, т.е. только одну половину. Как в Plot Results на экран вывести не половину, а целую модель?
Спасибо

[MMV]

Plot controls/Style/Symmetry expansion/ (я обычно пользуюсь) User defined