[МишаИнженер]

В VBA Excel сделал 2 функции для создания матриц 3х3:

Код:

[Выделить все]

Public Function Матрица0() As Variant
Dim dM(1 To 3, 1 To 3) As Double
Dim I As Integer, J As Integer, K As Integer
   K = 1
   For I = 1 To 3
      For J = 1 To 3
         dM(I, J) = K
         K = K + 1
      Next J
   Next I
   Матрица0 = dM
End Function

Public Function Матрица(ix As Integer, jy As Integer) As Variant
Dim dM(1 To 3, 1 To 3) As Double
Dim I As Integer, J As Integer, K As Integer
   K = 1
   For I = 1 To 3
      For J = 1 To 3
         dM(I, J) = K
         K = K + 1
      Next J
   Next I
   Матрица = dM(ix, jy)
End Function

Пробовал вывести эти функции как формулы МАССИВА в ячейки Excel
Функция "Матрица0" выдает ошибку и не работает в формуле массива.
Функция "Матрица" в формуле массива выводит только "1".
А надо чтобы выводились 1,2,3,4,5,6 и тд.
Как вывести матрицу 1,2,3,4,5,6 и тд из функции VBA на лист Excel?

[Сергей812]

а зачем формула массива? Собираете в массиве типа Variant размерностью (1 To 3, 1 to 3) значения и потом одним присваиванием диапазону выводите на лист

----- добавлено через ~10 мин. -----
типа такого

Код:

[Выделить все]

Public Sub SetMatrix(ByVal aRow As Long, ByVal aColumn As Integer)
  Dim lImg As Variant: Redim lImg(1 To 3, 1 To 3)
  Dim I As Integer, J As Integer, K As Integer
  K = 1
  For I = 1 To 3
     For J = 1 To 3
        lImg(I, J) = K
        K = K + 1
     Next J
  Next I
  ActiveSheet.Range(Cells(aRow, aColumn), Cells(aRow + 2, aColumn + 2)) = lImg
End Sub

Public Sub Test001()
  SetMatrix 10, 10
End Sub

[Петр-и-Алекс]

На мой взгляд, тема должна быть перемещена в раздел "функции".
И вообще, Excel достоен иметь самостоятельный раздел на этом форуме.

----- добавлено через ~6 мин. -----
как по мне, а "матрица" это один объект, а не набор из девяти...
так что... перебирать элементы через For ... некузяво как то

----- добавлено через ~2 ч. -----
Миша, глянте вот это https://excelpedia.ru/makrosi-v-excel/massivi-v-vba
Должно породить новые идеи по работе с матрицами.
Имею ввиду разделы:"For Each" и "Чтение из диапазона ячеек в массив". и еще всякое

[Dinoxromniy]

Сообщение от МишаИнженер Функция "Матрица" в формуле массива выводит только "1".

Потому что у вас в аргументах всех ячеек две единицы, в каждой ячейке и отрабатывается строчка Матрица = dM(1, 1)
По факту формула массива пишется не так, первый аргумент должен содержать диапазон всех Х, второй - диапазон со всеми Y. А ваш код заточен под обработку одной пары индексов: Function Матрица(ix As Integer, jy As Integer) As Variant
Если формулу вводить не как формулу массива, и протянуть аргументы как положено - все работает.

Сообщение от МишаИнженер Функция "Матрица0" выдает ошибку и не работает в формуле массива.

... по причине банальной опечатки - должно быть "Матрица0()" со скобками как и у любой другой функции. Если поставить скобки - в актуальном офисе все прекрасно работает (но тут оговорка, что формулы массива в 2021 версии слегка допилили до ума, тестировал на нем).

----- добавлено через ~8 мин. -----

Сообщение от Петр-и-Алекс Имею ввиду разделы:"For Each" и "Чтение из диапазона ячеек в массив"

С таким раскладом проще вбить как формулу массива ={1;2;3:4;5;6:7;8;9} и будет ровно нужный результат. Если нужно менять цыферки - значит VBA функция, которая генерирует такую строку.

[МишаИнженер]

Сообщение от Dinoxromniy по причине банальной опечатки - должно быть "Матрица0()" со скобками как и у любой другой функции

Спасибо Dinoxromniy Вам большое! Все заработало. Теперь без труда можно выводить матрицы из VBA на лист Excel.