LISP. Подготовка подосновы

LISP. Подготовка подосновы · 13.04.2011, 20:25

Набор команд, опубликованных в теме Подоснова
Желательно ознакомиться с указанной темой или как минимум с описанием
Описание команд

Код:

[Выделить все]

BGLAYDEL - Удаление выключенных и замороженных слоев с примитивами
BG1BLEXP - Взрывает блоки, состоящие из одного примитива (возможно другого блока)
BGBLEXP  - Взрывает блок и все блоки, входящие в него, превращая видимые атрибуты в текст
BGBLEXP1 - Взрывает блоки 1-го уровня, превращая видимые атрибуты в текст
BGBLDYNEXP1 - Взрывает динамические блоки 1-го уровня, превращая видимые атрибуты в текст
BGBLEXP1NOATT - Взрывает блоки 1-го уровня, у которых нет видимых атрибутов
BGBLXCLIP - Показывает подрезанные блоки
BGBLDYN2A - Преобразовывает динамические блоки в анонимные
BGBLDYN2S - Преобразовывает динамические блоки в статические
BGBLALLDYN2A - Преобразовывает ВСЕ динамические блоки в анонимные    
BGBLALLDYN2S - Преобразовывает ВСЕ динамические блоки в статические  
BGBLXCLIPEXP - взорвать подрезанный блок
BGCB - копирует одно из вхождений блока в блок с новым именем 
BGRB - переименовывает одно из вхождений блока в блок с новым именем
M2U - Преобразовать MINSERT в Unnamed блок
M2B - Преобразовать MINSERT в блок
U2B - Преобразовать UNNAMED в блок
U2BM - Преобразовать UNNAMED в блок множественный выбор
UX - Взорвать UNNAMED блок
=======================================
BGRGB2ACI - Изменяет цвет с RGB на ACI
BGAll2RGB - Изменяет ACI цвет в его RGB эквивалент
BGCOLOR - Задает выбранный цвет всем объектам
BGCOLORCMD - Задает выбранный цвет всем объектам с запросом в командной строке
BGCOLORXREF - Меняет цвет выбранных внешних сылок (только в текушем сеансе)
BGCOLBL - Установка "послою" цвета примитивов подосновы. Если цвет задан явно- создается новый слой !Новое с версии 3.0
BGResetXRef -Сброс настроек слоев выбранных внешних ссылок на установленные в исходном файле
BGBLCC - Изменяет цвет выбранных блоков
BGENCC - Изменяет цвет выбранного элемента блока
BGCATT - Изменяет цвет атрибутов выбранных блоков
BGCBL2 - Изменяет цвет в блоках 2 и более уровня (вложенных блоках)
BGBLFIX - Нормализация блоков (цвет, слой, взрываемость и т.п.)
BGCFT   - Конвертирует все поля в обычный текст
BGCFTSEL - конвертирование полей в обычный текст в выбранных примитивах
BGHATCHDEL - Удаление штриховки

Текущая версия 3.13a
Отличие версий 3.3 и 3.6 и выше - переписана функция взрыва блоков (команды BGBLEXP...)
В версии 3.3 - вариант из expresstools. Сохраняются поля при взрыве. Медленная обработка при большом количестве блоков
В версии 3.6 функция bg:BURST-ONE заменена функцией Lee Mac LM:burst. На порядок быстрее, если атрибут многострочный и включена маскировка - получаем маскированный мтест.
Поля не сохраняются.

Код:

[Выделить все]

;;;	Версии:
;;;	1.0 - исправлены ошибки burst - при наследовании типа линии поблоку, показ скрытых атрибутов и наследования типа линии блока
;;;	                                если в блок примитив входил не на 0 слое, тип линии поблоку.
;;;	      добавлена обработка Burst LineWeight
;;;	1.1  изменение цвета блока при наличии атрибутов (см ;;; Change VVA 12.09.2008)
;;;	...
;;;	1.4  Обработка стилей мультилиний
;;;	1.11 ChangeAllObjectsColor - Обработка размеров, leader и mtext с явным заданием цвета.
;;;	     BGBLEXP - обработка видимостей динамических блоков (если в видимости включены атрибуты)
;;;	     BG1BLEXP - Обабатываются блоки, состоящие из одного элемента и
;;;	     - имя блока A$C*
;;;	     - или любое другое имя и этот один элемент другой блок
;;;	1.12 - Не удаляет блоки, расположенные на выключенном/ замороженном слое
;;;	       и имеющие хотя бы 1 примитив на включенном слое, отличном от "0"
;;;	2.0  - BGBLEXP - исправлена ошибка со списком
;;;	2.1  - обработка блоков внешних ссылок ChangeXrefAllObjectsColor
;;;	2.2  - команда BGCFT
;;;	2.3  - add BGCOLORXREF and BGRGB2ACI
;;;	2.4  - Обработка многострочных атрибутов
;;;     2.5  - Добавленна gc:FieldCode ChangeAllObjectsColor ChangeXrefAllObjectsColor - обработка Unicode символов
;;;     2.6  - Добавленны команды BGBLDYN2A BGBLDYN2S
;;;     2.7  - Добавлена обработка предварительного выбора
;;;     2.8  - Баги с обработкой атрибутов и visibility
;;;     2.9 - Команда BGBLDYNEXP1 
;;;     2.9.1 - добавлена ф-ция bg:massoc
;;;     2.10  - Конвертация динамических блоков  bg:DynToStatic. Сохранение и восстановление значений атрибутов
;;;     2.11 - Изменения в bg:get-all-atts (обработка UNICOD символов в значениях атрибутов)
;;;              добавлена команда BGHATCHDEL
;;;             ChangeAllObjectsColor - change table text and grid color
;;;    2.12  - Учтен lineweight для атрибутов. Изменен BgBlFIX
;;;    2.13  - Добавлена функция BG:GET-TEXTSTRING (как замена vla-get-textstring. Т.к. неверно возвращает строку при наличии юникод символов)
;;;    2.14  - Добавлена команда BGAll2RGB Изменена ClearFieldInAllObjects
;;;    2.15  - Небольшие изменения в BGAll2RGB. добавлены BGCB и BGRB
;;;;   2.16  - BGCBL2 теперь работает с RGB и ACI цветами
;;;;   2.17  - BGBLCC  теперь работает с RGB и ACI цветами + мелкие изменения
;;;;   2.18  - Учтено предложение http://forum.dwg.ru/showpost.php?p=949149&postcount=102
;;;;           Добавлена команда BGBLXCLIPEXP
;;;;   2.19  - Команда BGBLFIX. Добавлена опция игнорирования блокированных слоев
;;;    2.22  - Добавлены опции Одинаковые масштабы и Разрешить расчленение
;;;    2.23 - Внесены изменения в команду BGBLXCLIPEXP
;;;    2.24  - Отредактирована команда UX (вложенность анонимных блоков)
;;;    2.25  - Fix BGBLCC и BGCBL2 command. Add BGCFTSEL
;;;    2.26  - BGCFT - добавлена обработка формата текста в таблице. Добавлены команды BGBLALLDYN2A и BGBLALLDYN2S
;;;    2.27  - в командах U2B ,UX добавлена обработка блоков с именем *E
;;;    2.28  - BGCFT - исправлена ошибка + изменения в function bg:DynToStatic
;;;    2.29  - Исправлен недочет ClearFieldInThisObject
;;;    2.30    Fixed minor bugs in function ClearFieldInThisObject   http://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/vla-get-textstring-u-symbols/td-p/4365165
;;;    2.31    BGCFT добавлена очистка полей в размерах  ( http://forum.dwg.ru/showthread.php?p=1335110#post1335110 )
;;;    2.32    изменения в bg:get-TextString (http://forum.dwg.ru/showpost.php?p=1386990&postcount=235)
;;;    2.33    изменения в bg:get-TextString (http://forum.dwg.ru/showpost.php?p=1386990&postcount=252) 
;;;    2.34    BGBLFIX обработка именованных стилей печати
;;;    2.35    BGBLEXP изменения
;;;    2.36    изменения в команде UX http://forum.dwg.ru/showthread.php?p=1421560#post1421560
;;;    2.37    BGCFT исправлена ошибка при обработке заблокированных ячеек таблицы
;;;    2.38    BGLAYDEL исправлена ошибка с востановлением слоев
;;;    2.40    Изменения в ф-ции bg:FieldCode. Добавлена ф-ция bg:GetObjectIDString mark VVA 2015-12-07
;;;    2.41    Изменения в ф-ции ClearFieldInThisObject. Обработка значений размеров над и под размерной линией. Mark VVA 2016-01-04
;;;    3.0    Добавлена команда BGCOLBL
;;;            Установка послою цвета примитивов подосновы. Если цвет задан явно- создается новый слой
;;;    3.1    BGBLEXP - сохранение полей в атрибутах
;;;   3.2    BGCFT игнор
;;;   3.3    Исправление в команде M2B
;;;   3.4    Исправление fix bg:explode-block (исключение обработки внешних ссылок)
;;;   3.5    BG:BURST-ONE измененая для сохранения постоянных атрибутов
;;;   3.6    добавлено bg:del-constraint в BGBLEXP
;;;   3.7    изменения в команде M2B
;;;   3.8    Изменения в bg:FieldCode (http://forum.dwg.ru/showpost.php?p=1754063&postcount=467)
;;;   3.9    Изменения BGLAYDEL. Слои удаляются командой _-LAYDEL
;;;   3.10   Добавлена команда BGCOLORCMD
;;;;  3.11   Изменения BGLAYDEL
;;;;  3.12   Изменения в функции mip_MTEXT_Unformat (VVA 2021-12-24)
;;;;          https://forum.dwg.ru/showthread.php?p=1975506#post1975506
;;;;   3.12a   Изменения в функции bg:hatch-delete-form-Block (VVA 2022-05-13)
;;;;            https://forum.dwg.ru/showpost.php?p=1991289&postcount=624

Полезные ссылки
C2L - Color to Layer или еще здесь
COLORFL - Color From Layer
PFL - Properties From Layer

Кулик Алексей aka kpblc · 14.02.2023, 07:51

pickfirst ?

mogulfx · 16.02.2023, 05:24

Попробовал, pickfirst on/off не влияет. Кстати Bricscad.

VVA · 17.02.2023, 13:06

Проверить в Брикскаде не могу, в Автокаде работает. При выборе секрамкой объекты должны быть гарантированно на экране. Добавил пару библиотечных функций

Код:

[Выделить все]

; ! ***********************************************************
;; !                             lib:Zoom2Lst
;; ! **********************************************************
;; ! Function : Zoom границ списка точек
;; ! Arguments: 'vlist' - Список точек в МСК!!!!
;; ! Зуммирует экран, чтобы все точки были видны
;; ! Returns  : t - было зуммирование nil - нет
;; ! **********************************************************
(vl-load-com)
;;; Версия с vla- объектами
    (defun lib:Zoom2Lst (vlist / pts)
      (setq pts (lib:pt_extents (mip:ZZero vlist)))
      (if (not (and (lib:IsPtInView (car pts)) (lib:IsPtInView (cadr pts))))
        (progn
          (vla-ZoomWindow (vlax-get-acad-object) (vlax-3d-point (car pts)) (vlax-3d-point (cadr pts)))
          (vlax-invoke (vlax-get-acad-object) 'ZoomScaled 0.85 acZoomScaledRelative)
          T
        )
        nil
      )
    )  ;end
;|
   ! ***************************************************************************
;; !           lib:pt_extents
;; ! ***************************************************************************
;; ! Function : Возвращает границы MIN, MAX X,Y,Z списка точек
;; ! Argument : 'vlist' - Список точек
;; ! Returns  : Список точек (ЛевНижн ПравВерхн)
;; ! ***************************************************************************
|;
    (defun lib:pt_extents (vlist / tmp)
      (setq tmp (apply 'mapcar (cons 'list vlist)))
      (list (mapcar '(lambda (x) (apply 'min x)) tmp) (mapcar '(lambda (x) (apply 'max x)) tmp))  ;_defun
    )
;|
   ! *******************************************************************
;; !                  lib:IsPtInView
;; ! *******************************************************************
;; ! Проверяет находится ли точка в видовом экране
;; ! Auguments: 'pt'  - Точка для анализа в МСК!!!
;; ! Return   : T или nil если 'pt' в видовом экране или нет
;; ! *******************************************************************
|;
    (defun lib:get-viewctr-size (/ VCTR Y_Len SSZ X_Pix Y_Pix X_Len)
      (setq VCTR (getvar "VIEWCTR") Y_Len (getvar "VIEWSIZE")
            SSZ (getvar "SCREENSIZE")
            X_Pix (car SSZ) Y_Pix (cadr SSZ)
            X_Len (* (/ X_Pix Y_Pix) Y_Len)
      )
      (list (mapcar '- VCTR (list (* 0.5 X_len) (* 0.5 Y_len)))
            (mapcar '+ VCTR (list (* 0.5 X_len) (* 0.5 Y_len)))
      )
    )
    (defun lib:IsPtInView (pt / Lc Uc)
      (setq pt (trans pt 0 1))
      (setq Lc (lib:get-viewctr-size)
            Uc (cadr Lc)
            Lc (car Lc)
      )
      (if (and (> (car pt) (car Lc)) (< (car pt) (car Uc))
               (> (cadr pt) (cadr Lc)) (< (cadr pt) (cadr Uc))
          )
        T nil
      )
    )


(defun C:TEST ()
(setq minpt (getpoint "\nFirts point: "))
(setq maxpt (getcorner minpt  "\nOther corner: "))
(lib:Zoom2Lst (list MinPt MaxPt));_Гарантированно блоки на экране
  
(if (setq ss2 (ssget "_C" minpt maxpt'((0 . "INSERT"))))
  (progn
    (SSSETFIRST ss2 ss2)
    (C:BGBLEXP1)
    )
  )

superkot007 · 08.04.2023, 00:12

Доброго времени суток.
Как задать работу BGBLEXP без запроса выбора объектов? Либо выделением всего содержимого пространства модели, либо по двум фиксированным противоположным точкам.

engngr · 08.04.2023, 14:26

Цитата:

Сообщение от superkot007

Как задать работу BGBLEXP без запроса выбора объектов? Либо выделением всего содержимого пространства модели

bgblexp _all
?

VVA · 18.04.2023, 10:34

Цитата:

Сообщение от superkot007

Как задать работу BGBLEXP без запроса выбора объектов?

BGBLEXP работает с предварительным выбором. Поэтому алгоритм такой
1. Сформировать нужный набор объектов
2. Вызвать BGBLEXP
Пример (Взрывает все блоки в текущем пространстве)

Код:

[Выделить все]

(defun C:TEST ( / ss)
  (if (setq ss (ssget "_X" (list(cons 0 "INSERT")(cons 410 (getvar "CTAB")))))
    (SSSETFIRST ss ss)
    )
 (C:BGBLEXP)
  )

zenon · 24.05.2023, 10:38

Повторно подниму свой вопрос #402
Данный функционал так и не удалось реализовать?

VVA · 25.05.2023, 15:12

Цитата:

Сообщение от zenon

Повторно подниму свой вопрос #402
Данный функционал так и не удалось реализовать?

Пробуй. Добавь к bgtools.lsp

Код:

[Выделить все]

(defun C:BG1BLEXPONE ( / count xcount)
;;; Взрывает блоки, состоящие из одного примитива вставленные один раз  
  (setq count (bg:block-explode-one-item-ones)
	xcount (cadr count)
	count (car count)
	)
  
  (princ "\nExploded ")
  (princ count)
  (princ " blocks with one element. Found ")
  (princ xcount)
  (princ " blocks has xclip boundary.")
  (princ)
  )
(defun bg:block-explode-one-item-ones ( / blklist count xcount tmp Doc Blks ss)
;;; Взрывает блоки, состоящие из одного примитива и одного вхождения
;;; Explode blocks consisting of one primitive thing (it is possible other block)
   (bg:layer-status-save)
    (setq Doc (vla-get-activedocument (vlax-get-acad-object))
	Blks (vla-get-Blocks Doc)
	)
  (vlax-for Blk Blks
    (if (and (= (vla-get-IsXref Blk) :vlax-false)
	  (= (vla-get-IsLayout Blk) :vlax-false)
	  (= (vla-get-count Blk) 1)
	  )
      (setq blklist (cons (vla-get-Name Blk) blklist))
      )
    )
  (setq tmp blklist)
  (foreach blk tmp
    (if (eq (type (setq ss nil ss (ssget "_X" (list (cons 0 "INSERT")(cons 2  blk)(cons 410 (getvar "CTAB")))))) 'PICKSET )
      (if (/= (SSLENGTH ss) 1)(setq blklist (vl-remove blk blklist)))
      (setq blklist (vl-remove blk blklist))
      )
    )
  (setq count 0 xcount 0)
  (vlax-for obj (vla-get-block(vla-item (vla-get-Layouts(vla-get-activedocument (vlax-get-acad-object)))(getvar "CTAB")))
    (if (and (eq (vla-get-ObjectName obj) "AcDbBlockReference")
	     (not (vlax-property-available-p obj 'path))
	     (vl-position (bg:block-get-name obj) blklist)
        )
      (progn
	(if (and (setq tmp (bg:block-GetXclip obj))
		 (= 1 (cdr(assoc 71 tmp)))
		 )
	  (progn
	    ;;; Здесь должна быть реакция на подрезанный блок
	    ;;; Игнорируем
	    (setq xcount (1+ xcount))
	    )
	 (progn
	   (bg:explode-block (vlax-vla-object->ename obj) nil)
	   (setq count (1+ count))
	   )
	)
      )
      )
    )
  (bg:layer-status-restore)
  (list count xcount)
  )

egorus2014 · 25.07.2023, 20:51

Не ругайтесь, если повторю чей-то вопрос...
Можно ли перекрашивать всё, но в пределах выбранного?
Потому что если даже скопировать часть чертежа в новый файл, там его полностью перекрасить и вставить обратно - все блоки перекрашиваются обратно. Остаются перекрашенными только примитивы.

kp+ · 25.07.2023, 22:16

Цитата:

Сообщение от egorus2014

Потому что если даже скопировать часть чертежа в новый файл, там его полностью перекрасить и вставить обратно - все блоки перекрашиваются обратно

Вы же о команде bgblfix, так? Но она "перекрашивает" определения блоков. Соответственно, перекрашиваются все вставленные в чертеж экземпляры этих блоков, т.к. они ВСЕ тиражируются с определений.
А чтобы перекрасить ЧАСТЬ вставленных экземпляров блоков, надо заменить их на копии, идентичные по содержанию, но с другими именами. Для этого пригодится команда BGRB. Правда, она работает с отдельными блоками.
Как вариант, посмотрите здесь: https://dwg.ru/dnl/10891

egorus2014 · 25.07.2023, 22:37

Вообще пробовал команду BGCOLOR
Пусть в пространстве несколько планов. Один нужно перекрасить (почти все в один цвет).
BGCOLOR - перекрашивает вообще всё. Даже скрытые элементы.
Я пробовал скопировать в новый документ нужный план, перекрасить и скопировать обратно - при вставке перекрашенного плана в первоначальный документ все блоки возвращают свою первоначальную окраску.

kp+ · 25.07.2023, 23:20

Цитата:

Сообщение от egorus2014

при вставке перекрашенного плана в первоначальный документ все блоки возвращают свою первоначальную окраску.

Так в первоначальном документе определения блоков остались не перекрашенными, о чем я и говорил.
Более того, если не использовать bgtools, а перекрасить определения блоков по одному в штатном редакторе блоков - эффект будет тот же.

Цитата:

Сообщение от egorus2014

Пусть в пространстве несколько планов. Один нужно перекрасить (почти все в один цвет).

Если в каждом из планов в пределах одного файла используются одни и те же блоки, то, конечно, все и перекрасятся. Т.к. перекрашены определения блоков - то, с чего растиражированы экземпляры блоков, расставленные в чертеже.

Поймите разницу между определением блока и вставленными в чертеж экземплярами блока, и все станет на свои места. Разница - примерно как между типографской матрицей и напечатанными с нее листами

Только в типографии изменения в матрице влияют лишь на новые отпечатки, а в блоках Акада - на все, в том числе ранее "отпечатанные".

PS
Разбросать разные планы по разным файлам разве не представляется возможным?

posetitel · 27.01.2024, 12:18

Товарищи, гуру лиспа и автокада, допилите, пожалуйста, команду BGBLFIX, до возможности сбрасывать масштаб линий на 1 либо на задаваемый. Сейчас только реализована функция "одинаковый масштаб", но какой он будет конкретно - непонятно.

VVA · 29.01.2024, 16:38

Цитата:

Сообщение от posetitel

Товарищи, гуру лиспа и автокада, допилите, пожалуйста, команду BGBLFIX, до возможности сбрасывать масштаб линий на 1

Пробуй. Обновил до версии 3.13b. Дай обратную связь, сильно не тестировал

posetitel · 29.01.2024, 16:47

Спасибо, на тестовом блоке работает.
А можно сделать возможность назначить устанавливаемый масштаб линий, а не строго 1.

white_cat · 29.02.2024, 14:28

Автокад 2023. При использовании команды BGLAYDEL след ошибка:

Код:

[Выделить все]

Команда: BGLAYDEL
_.UNDO Текущие настройки: Авто = Вкл, Управление = Все, Объединить = Есть, Слой = Есть
Количество отменяемых операций или [Авто/Управление/Начало/Конец/Метка/Обратно] <1>: _Mark
Команда: ; ошибка: Возникло исключение: 0xC0000005 (Нарушение доступа)
; предупреждение: раскрутка пропущена для исключение
; ошибка: Возникло исключение: 0xC0000005 (Нарушение доступа)

VVA · 11.03.2024, 09:51

white_cat, Пока нет 2023 для проверки. Попробуй предварительно проверить черчеж на ошибки

kacugu · 14.03.2024, 13:26

Цитата:

Сообщение от VVA

Пока нет 2023 для проверки

Если что, то в 2024 отработало без ошибок

posetitel · 15.03.2024, 14:41

Неожиданно наткнулся вот на какой баг (фичу?): если в блоке с рамкой и штампом на листах есть поле с переменной ctab, то при выполнении команды BGCTF поле во всех листах преобразовывается в текст с названием только первого листа.
Это в принципе логично, но не совсем отвечает задумке команды, хотелось, конечно, чтобы в каждом блоке оставалось то значение ctab, которое и было, но тогда возникнет противоречие, не может быть один блок на разных листах с разным текстом (собственно поэтому и захотел потестить команду).

white_cat · 16.03.2024, 13:48

Цитата:

Сообщение от VVA

white_cat, Пока нет 2023 для проверки. Попробуй предварительно проверить черчеж на ошибки

Проверил на ошибки - их нет. Проверил с другими чертежами - аналогичная ошибка.

Похожие темы
Тема	Автор	Раздел	Ответов	Последнее сообщение
Научите лиспу на примере (или как kpblc, VVA и компания пытаются обучить чайника лиспу)	Red Nova	LISP	4555	24.03.2024 13:44
{Конкурс} Lisp. Задачки для студентов	gomer	LISP	10	05.01.2011 16:33
LISP на команду 3dcorbit	Малюк	LISP	2	30.09.2009 14:18
Запуск Lisp команды в новом документе	BlackHarp	LISP	1	26.03.2009 23:06
загрузка DOS прог через LISP	Gaa	LISP	15	12.08.2005 19:19