[MrBrown]

Здравствуйте!
Решая свою задачу (простановка в модели AutoCAD нумерованных точек/окружностей/блоков по координатам из Excel) длительным поиском по разным сайтам нашёл тему https://www.planetaexcel.ru/forum/in...ID=8&TID=12330
Увы, ссылка на программу "Text_Excel_ACad" уже не работает.
Прошу помощи: у кого есть, выложите программу или подскажите рабочую ссылку.
Пятой точкой чувствую: это именно то, или близко к тому, что мне нужно.
Спасибо.

[trir]

всё гораздо проще делается

[MrBrown]

trir,

Сообщение от trir всё гораздо проще делается

Как-проще? Прощу, подскажите.
Меня не устраивает распространённый алгоритм, по которому в Excel в координатах запятые меняют на точки, затем конвертируют таблицу в формат txt, ну и т.д.
Мне нужно, чтобы из таблицы Excel были выужены координаты и их нумерация, а в модели AutoCAD по этим координатам были вставлены не только точки, а и, по моему хотению, круги, треугольники, блоки, короче любой объект, на который я укажу, в активном слое. И рядом проставлен номер, согласно таблице Excel. Номер - в своём слое для оперативного скрытия.
А, может быть, знаете иной способ, которого я не знаю, и он может оказаться даже лучше, чем мне надо.
Буду весьма признателен за конструктивную помощь.
p.s. AutoCAD 2020.

[trir]

в Excel'е в ячейке пишется формула в кторой получаем (command "_insert" <параметры>) и просто вставляем результат в AutoCAD

в Excel в координатах запятые меняют на точки

я просто в системных настройках один раз меняю и не мучаюсь

[MrBrown]

trir, спасибо, попробую.

[MrBrown]

trir, прошу конкретизировать, что мне сделать, чтобы, к примеру, закинуть пять вот этих координат (см. приложенный файл Excel) в модель AutoCAD, чтобы рядом оказались их номера. Точнее, не координат, а, к примеру, маленьких кружочков по этим координатам.
А у меня что-то не получается закинуть даже точки.

[Сергей812]

Например, написать крошечный макрос

Код:

[Выделить все]

Public Sub HlopTop()
  If (Application.Selection.Columns.Count <> 3) Then Exit Sub
  Dim lData As Variant: lData = Application.Selection
  Dim lAcadApp As Object: Set lAcadApp = GetObject(, "AutoCAD.Application")
  Dim lCurrDoc As Object: Set lCurrDoc = lAcadApp.ActiveDocument
  Dim I1 As Long, lCenter(0 To 2) As Double
  For I1 = 1 To UBound(lData, 1)
    lCenter(0) = CDbl(lData(I1, 1))
    lCenter(1) = CDbl(lData(I1, 2))
    lCenter(2) = CDbl(lData(I1, 3))
    lCurrDoc.ModelSpace.AddCircle lCenter, 1
  Next I1
  Set lCurrDoc = Nothing
  Set lAcadApp = Nothing
End Sub

Выделить диапазон данных на листе и вызвать макрос HlopTop через Alt-F8. Можно как надстройку Excel оформить, чтобы внутри экселевского файла с данными не держать сам код.

[MrBrown]

Сергей812, интересный способ!
И, если модератор разрешит (тема-то называется "Ищу" конкретную готовую программу, уже созданную программистом LISP), то хотел бы разобраться в нюансах вашего варианта макроса.
Первая строчка, как я понимаю, запрещает выделять четыре столбца таблицы. А нужно, чтобы рядом с кружком появлялся номер, взятый из столбца "А", например мтекст или текст текушего стиля и размера, с "ручкой" слева-внизу. Ручка находится в центре кружка.
Это возможно прописать в макросе?
Спасибо.
p.s. Для модератора: если необходимо, я поменяю название темы.

[Сергей812]

Сообщение от MrBrown Первая строчка, как я понимаю, запрещает выделять четыре столбца таблицы.

любое количество столбцов, не равное трем. И не запрещает выделять - а не дает словить ошибку в ходе обращения к ячейкам массива lData.

Сообщение от MrBrown А нужно, чтобы рядом с кружком появлялся номер, взятый из столбца "А", например мтекст или текст текушего стиля и размера, с "ручкой" слева-внизу. Ручка находится в центре кружка. Это возможно прописать в макросе?

код открыт, прописывайте) Тогда нужно:
1. Брать 4 столбца и прописать условие продолжения по наличию 4 столбцов в выделении.
2. Создать блок в виде окружности с точкой вставки в центре окружности и атрибутом.
3. Вместо AddCircle будет уже InsertBlock. Вставили блок и сразу задали из первого столбца значение атрибута, пока есть ссылка на вставленный блок.

[MrBrown]

Сергей812, Спасибо за подсказку. Ушёл творить.

[trir]

="(command ""_insert"" ""test1"" '(" & B2 & " " & D2 & " " & C2 & ") 1 1 0 """ & A2 & """)"

[MrBrown]

trir, Спасибо, но не понимаю, как связать команду с моей таблицей.
"test1" - это, наименование блока (ИМХО). Я его создал из кружка. А как приклеить к блоку кружка атрибут номера? Если не трудно, дайте ссылку на какой-нибудь коротенький урок.

[trir]

https://knowledge.autodesk.com/ru/su...13169-htm.html

[Сергей812]

с 2009 года никогда не создавали блоков с атрибутами?) А занести номер из первого столбца в атрибут - программно это делается на раз-два

Код:

[Выделить все]

Public Sub HlopTop2()
  If (Application.Selection.Columns.Count <> 4) Then Exit Sub
  Dim lData As Variant: lData = Application.Selection
  Dim lAcadApp As Object: Set lAcadApp = GetObject(, "AutoCAD.Application")
  Dim lCurrDoc As Object: Set lCurrDoc = lAcadApp.ActiveDocument
  Dim I1 As Long, lCenter(0 To 2) As Double, lBlockRef As Object, lAttrs As Variant
  For I1 = 1 To UBound(lData, 1)
    lCenter(0) = CDbl(lData(I1, 2))
    lCenter(1) = CDbl(lData(I1, 3))
    lCenter(2) = CDbl(lData(I1, 4))
    Set lBlockRef = lCurrDoc.ModelSpace.InsertBlock(lCenter, "MARKER", 1, 1, 1, 0)
    If (lBlockRef.HasAttributes) Then
      lAttrs = lBlockRef.GetAttributes
      lAttrs(0).TextString = CStr(lData(I1, 1))
    End If
  Next I1
  Set lCurrDoc = Nothing
  Set lAcadApp = Nothing
End Sub

а как здесь предлагают через комстроку - ну тоже можно вроде консольно вызвать команду для редактирования значения атрибута, но это будет уже по две строчки на каждый блок минимум - сначала вставить блок, потом задать атрибут

[MrBrown]

trir, Сергей812, буду пробовать вариант каждого. По результатам отпишусь.
От души благодарю вас обоих за конструктивные ответы, подсказки и ссылки.
p.s. Кстати, да, ни разу (в жизни!) не пришлось создавать блок с атрибутами, хотя частенько в чужих файлах встречал блоки разной сложности. А сам создавал только обычный блок. Просто, тупо объединял несколько примитивов в блок. Вот так бывает.

[trir]

но это будет уже по две строчки на каждый блок минимум - сначала вставить блок, потом задать атрибут

одна строчка

[MrBrown]

Сергей812, макрос ругается на строчку:

Код:

[Выделить все]

 Set lBlockRef = lCurrDoc.ModelSpace.InsertBlock(lCenter, "MARKER", 1, 1, 1, 0)

вот таким окном-предупреждением (прилож. картинка)

[trir]

блок MARKER существует?

[MrBrown]

trir, Пока нет. Разбираюсь с атрибутами. Из вопроса понял свою задачу. Спасибо.