URSA
| Правила | Регистрация | Пользователи | Поиск | Сообщения за день | Все разделы прочитаны |  Справка по форуму | Файлообменник |

Вернуться   Форум DWG.RU > Программное обеспечение > Расчетные программы > ANSYS > Проблемы с расчетом Ж/Б каркаса в ANSYS

Проблемы с расчетом Ж/Б каркаса в ANSYS

Ответ
Поиск в этой теме
Непрочитано 15.05.2010, 18:58
Проблемы с расчетом конструкций в ANSYS
derik
 
Конструякер
 
Подмосковье
Регистрация: 27.07.2009
Сообщений: 594

Здраствуйте уважаемые форумчане! Просьба тех кто считает в Ансисе подсказать - где у меня ошибка в схеме! Хелп перечитал, он мне уже скоро сниться будет :-( помогите пожалуйста!
вот код:

Код:
[Выделить все]
/prep7
a=4
h=2.5
b=.4
t=.2
q=100
/view,1,1,1,1
/ang,1
/rep,fast
blc5,a/2,a/2,a,a,
k,,b/2,b/2,0
k,,a-b/2,b/2,0
k,,b/2,a-b/2,0
k,,a-b/2,a-b/2,0
k,,b/2,b/2,-h
k,,a-b/2,b/2,-h
k,,b/2,a-b/2,-h
k,,a-b/2,a-b/2,-h
lstr,5,9
lstr,6,10
lstr,7,11
lstr,8,12
nummrg,all
boptn,,keep
boptn,keep,1
boptn,nwar,0
boptn,vers,rv52
btol,1e-005,
lina,5,1
lina,6,1
lina,8,1
lina,7,1
mptemp,,,,,,,,
mptemp,1,0
mpdata,ex,1,,3e8
mpdata,prxy,1,,.3
mpdata,dens,1,,2500
et,1,shell63
r,1,t,,,,,,
et,2,beam4
keyopt,2,9,9
r,2,b*b,(b*b**3)/12,(b*b**3)/12,b,b,
lsel,s,,,5
lsel,a,,,6
lsel,a,,,7
lsel,a,,,8
latt,1,2,2,
asel,s,,,1
aatt,1,1,1
allsel,all
lesize,5,,,b,1
lesize,6,,,b,1
lesize,7,,,b,1
lesize,8,,,b,1
lmesh,5,6,
lmesh,7,8,
aesize,1,b/2,
amesh,1
LGEN,3,all, , , , ,h, ,0   
AGEN,3,all, , , , ,h, ,0
nummrg,all
allsel,all
/eshape,1
/replot
finish
/sol
nsel,s,loc,x,b/2
nsel,r,loc,y,b/2
nsel,r,loc,z,-h
D,all, , , , , ,ALL, , , , , 
nsel,s,loc,x,b/2
nsel,r,loc,y,a-b/2
nsel,r,loc,z,-h
D,all, , , , , ,ALL, , , , , 
nsel,s,loc,x,a-b/2
nsel,r,loc,y,b/2
nsel,r,loc,z,-h
D,all, , , , , ,ALL, , , , , 
nsel,s,loc,x,a-b/2
nsel,r,loc,y,a-b/2
nsel,r,loc,z,-h
D,all, , , , , ,ALL, , , , ,
allsel,all
acel,0,0,9.8,
solve
finish
/post1
set,first

Последний раз редактировалось derik, 30.07.2010 в 20:25. Причина: изм. названия
Просмотров: 156911
 
Непрочитано 19.11.2013, 22:19
#341
frostyfrost

Юмористические расчеты, комедийные диссертаций, цирковые статьи
 
Регистрация: 12.12.2012
Москва
Сообщений: 891


Там важно получить конкретную прочность. Поскольку для куба и призмы при одинаковых площадях опирания должна получиться разная прочность.
frostyfrost на форуме  
 
Непрочитано 19.11.2013, 22:20
1 | #342
СергейД

расчеты МКЭ и CFD. ктн
 
Регистрация: 11.05.2005
Подмосковье
Сообщений: 2,145


немного уточнений=
EQSLV,PSG,1E-6! надо pcg
NROPT,UNSYM,,ON! не активируется, поскольку только со sparse
CNVTOL,F,,.05
CNVTOL,U,,.09
NEQIT,50!
СергейД вне форума  
 
Автор темы   Непрочитано 19.11.2013, 22:20
#343
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 594
Отправить сообщение для derik с помощью Skype™


ставте свои данные и будет вам и призма и куб сейчас куб в макросе забит, точнее 1/4 куба.
Сергей Иванович, спасибо!!! изменения внесу
__________________
...
derik вне форума  
 
Непрочитано 19.11.2013, 22:22
#344
СергейД

расчеты МКЭ и CFD. ктн
 
Регистрация: 11.05.2005
Подмосковье
Сообщений: 2,145


немного уточнений=
EQSLV,PSG,1E-6! надо pcg
NROPT,UNSYM,,ON! не активируется, поскольку только со sparse
CNVTOL,F,,.05! начинаю с .50 потом уменьшаю. обычно уменьшение на результаты влияния не оказывает= просто решение дольше и может не сойтись.
CNVTOL,U,,.09! отключаю
NEQIT,50! 7 ставлю= много итераций нет резона=лучше шаг меньше делать
! решать нужно в контактной постановке.

Последний раз редактировалось СергейД, 19.11.2013 в 22:23. Причина: решать
СергейД вне форума  
 
Автор темы   Непрочитано 19.11.2013, 22:25
#345
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 594
Отправить сообщение для derik с помощью Skype™


Цитата:
Сообщение от СергейД Посмотреть сообщение
немного уточнений=
EQSLV,PSG,1E-6! надо pcg
NROPT,UNSYM,,ON! не активируется, поскольку только со sparse
CNVTOL,F,,.05! начинаю с .50 потом уменьшаю. обычно уменьшение на результаты влияния не оказывает= просто решение дольше и может не сойтись.
CNVTOL,U,,.09! отключаю
NEQIT,50! 7 ставлю= много итераций нет резона=лучше шаг меньше делать
стояло 10, и шагов побольше, но бывает он шаг делит до бесконечности, и несколькими итерациями довел что более менее решение сходится/расходится. сходимость тоже варьирую, это уже "нормально" (вроде как), если ставить чуть больше и + + + + то решение проскакивает
__________________
...
derik вне форума  
 
Непрочитано 20.11.2013, 00:53
#346
Stanum

Dr
 
Регистрация: 16.10.2011
Днепропетровск
Сообщений: 1,020
<phrase 1=


6pa4o, а здесь лучше грузить деформацией, или всё же нагрузкой?
equivalent plastic strain+ elastic strain/equivalent plastic stress = входной диаграмме напряжения деформации для точки центра куба - говорит ли это о приемлимости решения?
Stanum вне форума  
 
Непрочитано 20.11.2013, 01:20
#347
frostyfrost

Юмористические расчеты, комедийные диссертаций, цирковые статьи
 
Регистрация: 12.12.2012
Москва
Сообщений: 891


Если лабораторные испытания моделируете, то перемещениями вы сможете в ряде случаев ниспадающую ветвь поймать, тогда как для нагрузки будет "прощелкивание". Хотя все зависит от задачи.
frostyfrost на форуме  
 
Непрочитано 28.11.2013, 04:07
#348
Stanum

Dr
 
Регистрация: 16.10.2011
Днепропетровск
Сообщений: 1,020
<phrase 1=


Продолжаю разбираться с solid65, читая хелп у меня возникли вопросы по таким параметрам как:
real constant CSTIF(жесткость раздавленных элементов) имеет ли смысл увеличивать ее исходное значение 1е-6?
Параметр в solcontrol INCP - роль этого параметра непонятна, по нему практически нет описания кроме как того что он добавляет жесткость от нагрузки давлением, с чем и зачем его есть непонятно?
Также вычитал в интернете, что есть по solid65 не документированные возможности, где о них можно узнать поподробней?
Stanum вне форума  
 
Непрочитано 03.12.2013, 18:13
#349
retal

ОКБиЭП
 
Регистрация: 28.08.2006
Казань
Сообщений: 225


Обычно при сжатии призмы разрушение начинается с образованием продольных трещин, в конце вообще вырисовывается "огрызок" в виде 2-х пирамидок. Запускал код 6pa4o такой картинки не увидел.
__________________
все намного проще... как E=mc^2.
retal вне форума  
 
Непрочитано 03.12.2013, 22:27
#350
frostyfrost

Юмористические расчеты, комедийные диссертаций, цирковые статьи
 
Регистрация: 12.12.2012
Москва
Сообщений: 891


Цитата:
Сообщение от retal Посмотреть сообщение
Обычно при сжатии призмы разрушение начинается с образованием продольных трещин, в конце вообще вырисовывается "огрызок" в виде 2-х пирамидок
Зависит от закрепления по концам. Возможны 3 варианта. Продольные трещины, одна наклонная и огрызок. Достаточно специфическая задача моделирования бетона и в частности моделирования достоверного процесса разрушения.
frostyfrost на форуме  
 
Непрочитано 03.12.2013, 23:32
#351
СергейД

расчеты МКЭ и CFD. ктн
 
Регистрация: 11.05.2005
Подмосковье
Сообщений: 2,145


там еще трение о плиты может повлиять.
СергейД вне форума  
 
Непрочитано 04.12.2013, 02:35
#352
Stanum

Dr
 
Регистрация: 16.10.2011
Днепропетровск
Сообщений: 1,020
<phrase 1=


Решал ту же задачу (модель куб между двух плит(контактная задача с трением)) столкнулся с проблемой не сходится реакция для кубика. Решил проверить в бетоне ли проблема. В результате прогнал 2 задачи:
1) элементы куба solid 185(пробовал с разными опциями, полное интегрирование, улучшенные относительные деформации)
2) элементы куба solid 65
материал для них одинаковый: только tb,kinh без tb, conc/ В результате две абсолютно разные реакции к тому же задача с 65 расходится на самом последнем шаге.

вот сам текст задачи

Код:
[Выделить все]
 finish
/CLEAR,NOSTART  
/units, si
/filnam, kinh
/title, kinh
/OUTPUT, kinh_1, txt, , D:\ANSYS files
!бетон не обжатый
!параметры
fc=40e6!прочность не обжатого бетона максимальная (М)Па
fct=2.1e6! прочность бетона на растяжение (М)Па
ec1=0.00186! напряжения соответствующие макс напряжениям
ecu=0.003! предельные напряжения в необжатом бетоне
Eb=32e9! модуль упругости бетона (Г)Па
nub=0.2
an=15
*dim, eps_b, array, 20
*dim, sig_b, array, 20
eps_b(1)=0.3*fc/Eb
eps_b(an)=ec1
eps_b(20)=ecu

*do,i,2,an
eps_b(i)=eps_b(i-1)+(eps_b(an)-eps_b(1))/(an-1)
*enddo
*do,i,an+1,20
eps_b(i)=eps_b(i-1)+(eps_b(20)-eps_b(an))/(20-an)
*enddo

sig_b(1)=0.3*fc
*do,i,2,20
x=eps_b(i)/ec1
Ebc1=5e6*(fc**(1/2))
Esec1=fc/ec1
r1=Ebc1/(Ebc1-Esec1)
sig_b(i)=fc*x*r1/(r1-1+x**r1)
*enddo

!бетон без ниспадающей ветви
*dim, eps_bn, array, an+1
*dim, sig_bn, array, an+1
*do,i,1,an
eps_bn(i)=eps_b(i)
sig_bn(i)=sig_b(i)
*enddo
eps_bn(an+1)=eps_b(20)
sig_bn(an+1)=sig_b(an)*1.01

!сталь
nus=0.3! коэффициент пуассона стали
Es=210e9!модуль упругости стали, (Г)Па


/prep7
!тип элемента
et,1,185
et,2,65
et,3,185
keyopt,1,2,3
!keyopt,1,1,1
!keyopt,2,3,2
!keyopt,2,6,3
!keyopt,2,7,1
!keyopt,2,10,1
keyopt,3,2,0

!материала
mp,ex,1,Eb
mp,nuxy,1,nub
mp,mu,1,0.3
TB, conc, 1, 1, 9, 0, 
tbtemp,0
tbdata,1,0.2,0.6,fct,fc,
tb,kinh,1,1,20,0 
tbtemp,0
*do, i, 1, 20
tbpt, ,Eps_B(i), Sig_B(i)
*enddo

mp,ex,5,Es
mp,nuxy,5,nus
mp,mu,5,0.3						! коэффициент трения

mp,ex,6,Eb
mp,nuxy,6,nub
mp,mu,6,0.3
!TB, conc, 6, 1, 9, 0, 
!tbtemp,0
!tbdata,1,0.2,0.6,fct,fc,
tb,kinh,6,1,an+1,0 
tbtemp,0
*do, i, 1, an+1
tbpt, ,Eps_Bn(i), Sig_Bn(i)
*enddo


!построение модели
a=0.15
a1=0.151
hpl=0.05
apl=0.2
apl1=0.201
block,0,-a1/2,0,a,0,-a/2
vsel,u,,,all
block,-a1/2,0,-hpl,0,-a/2,0
block,-apl1/2,-a1/2,-hpl,0,-a/2,0
block,-a1/2,0,-hpl,0,-apl/2,-a/2
block,-apl1/2,-a1/2,-hpl,0,-apl/2,-a/2
vglue,all
vsel,u,,,all
block,-a1/2,0,a,a+hpl,-a/2,0,
block,-apl1/2,-a1/2,a,a+hpl,-a/2
block,-a1/2,0,a,a+hpl,-apl/2,-a/2
block,-apl1/2,-a1/2,a,a+hpl,-apl/2,-a/2
vglue,all
alls
!vglue,all

!граничные условия
asel,s,loc,y,-hpl,-hpl
Da,all,Uy,0
asel,s,loc,x,0,0
asel,a,loc,z,0,0
DA,all,Symm

alls

!сетка
elem=a/20
lsel,s,length,,hpl
LESIZE,ALL, , ,6, ,1, , ,1,
lsel,inve
LESIZE,ALL,elem, , , ,1, , ,1,  
alls
vsel,s,loc,y,0,a
VATT, 6, 1, 2, !(3)
vsel,s,loc,y,-hpl,0
VATT, 5, 1, 1, 
vsel,s,loc,y,a,a+hpl
VATT, 5, 1, 1, 
alls
MSHAPE,0,3d 
MSHKEY,1
VMESH,all
alls

!контакт
MAT,6							!задание номера материала 
R,101							!константы для третего типа кэ
REAL,101							!номер типа констант
R,102							!константы для третего типа кэ
REAL,102							!номер типа констант
ET,100,170						!создаёт тип кэ цель
ET,101,173						!создаёт тип кэ контактор

	FKN=10
	FTOLN=0.01
	!ICONT=0.2
	PINB	=0.1
	!PMAX=0
	!PMIN=0
	TAUMAX=1.00E+20
	!CNOF=0.001
	FKT=1
	!COHE=0
	!FHTG=0
	!FACT=1
	!DC=1

!Real Constants

R,102,, , FKN, FTOLN, , PINB,
RMORE,, , TAUMAX, , , FKT,

R,101,, , FKN, FTOLN, , PINB,
RMORE,, , TAUMAX, , , FKT,

!Real Constants
!R,3,R1, R2, FKN, FTOLN, ICONT, PINB,
!RMORE,PMAX, PMIN, TAUMAX, CNOF, FKOP, FKT,
!RMORE,COHE, TCC, FHTG, SBCT, RDVF, FWGT,
!RMORE,ECC, FHEG, FACT, DC, SLTO, TNOP,
!RMORE,TOLS, MCC, PPCN, FPAT, COR, STRM
!RMORE,FDMN, FDMT, FDMD, FDMS, TBND

KEYOPT,101,2,1						!Контактный алгоритм
KEYOPT,101,5,0						!автоматическое закрытие открытых контактов
!KEYOPT,101,6,2						!?
KEYOPT,101,7,0						!доп контроль шага нагрузки, уменьшение шага при высоком проникновении
KEYOPT,101,9,1						!начальный пенетрации борьба
KEYOPT,101,10,2   						!когда обновлять контактную жесткость
KEYOPT,101,12,0
KEYOPT,100,5,0						!Определяет тип контактируемых поверхностей объём/объём, оболочка/оболочка и т.д

! Generate the target surface1   
vsel,s,loc,y,a,hpl+a

eslv, s
aslv,s
asel,r,loc,y,a,a
NSLA,S,1							!Выбор узлов принадлежащих area 
ESLN,r,0							!Выбор элементов которым принадлежат выбранные узлы
TYPE,100							!
REAL,101
ESURF							!Создаём элементы контакта на поверхности

! Generate the contact surface 1 
vsel,s,loc,y,0,a
eslv, s
aslv,s
asel,r,loc,y,a,a
NSLA,S,1							!Выбор узлов принадлежащих area
ESLN,r,0							!Выбор элементов которым принадлежат выбранные узлы
TYPE,101							
REAL, 101
ESURF							!Создаём элементы контакта на поверхности
ALLSEL							

! Generate the target surface2   
vsel,s,loc,y,-hpl,0
eslv, s
aslv,s
asel,r,loc,y,0,0
NSLA,S,1							!Выбор узлов принадлежащих area 
ESLN,r,0							!Выбор элементов которым принадлежат выбранные узлы
TYPE,100							!
REAL,102
ESURF							!Создаём элементы контакта на поверхности

! Generate the contact surface 2 
vsel,s,loc,y,0,a
vsel,r,loc,x,-a1/2,0
vsel,r,loc,z,-a/2,0
eslv, s
aslv,s
asel,r,loc,y,0,0
NSLA,S,1							!Выбор узлов принадлежащих area
ESLN,r,0							!Выбор элементов которым принадлежат выбранные узлы
TYPE,101							
REAL, 102
ESURF							!Создаём элементы контакта на поверхности
ALLSEL							

CNCHECK,AUTO
fini

/sol
/gst,1
/NERR, 10000,
nlgeom,on
nldiag,nrre,on
antype,0
autots,on
OUTRES,ALL,ALL  
!EQSLV,PCG,1E-5 
nropt,unsym,,on
lnsrch,on
!pred,on
cutcon,noshape,1
cutcon,plslimit,0.3
neqit,10
nsubst,400,10000,100
cnvtol,f,,0.005
cnvtol,u,,0.002

asel,s,loc,y,a+hpl,a+hpl
Da,all,Uy,-a*0.005
alls
time, 100
solve, , , , , nocheck

!*do,i,1,100
!asel,s,loc,y,a+hpl,a+hpl
!Da,all,Uy,-a*0.005*i/100
!cnvtol,f,,0.05+i/100*0.45
!time, i
!solve, , , , , nocheck
!*GET, dal, ACTIVE, 0, solu, cnvg,
!*IF, dal,eq, 0, exit,:label1
!*enddo
!:label1

fini
/post1
alls
set,last
*GET, sets, ACTIVE, 0, set, nset
sets=sets-1
*dim, react_sum1, array, sets,,,Time
*do,i,1,sets
SET,,, ,,, ,i 
nsel,s,loc,y,-hpl
*get,node_count,node,0,count
*do,j,1,node_count
*get, ni, node, 0, num, min
*get, react, node, ni, rf, fy
react_sum1(i)=react_sum1(i)+react
nsel,u,node,,ni
*enddo
*enddo
alls

fini
на схемах представлены значения реакции. величина не сошедшехся сил и их расположение
Миниатюры
Нажмите на изображение для увеличения
Название: residual 65(2).png
Просмотров: 94
Размер:	47.3 Кб
ID:	117844  Нажмите на изображение для увеличения
Название: residual 65.png
Просмотров: 74
Размер:	11.0 Кб
ID:	117845  Нажмите на изображение для увеличения
Название: residual 185(full int).png
Просмотров: 54
Размер:	8.3 Кб
ID:	117846  Нажмите на изображение для увеличения
Название: реакция 65.png
Просмотров: 64
Размер:	8.1 Кб
ID:	117847  Нажмите на изображение для увеличения
Название: реакция 185(full int).png
Просмотров: 60
Размер:	9.4 Кб
ID:	117848  

Stanum вне форума  
 
Непрочитано 04.12.2013, 02:41
#353
Stanum

Dr
 
Регистрация: 16.10.2011
Днепропетровск
Сообщений: 1,020
<phrase 1=


Прошу прощения за двойной пост, все приложения не влезали
Прикладываю output для 2 задач и ещё одну картинку.
здесь на мой взгляд возможный источник проблемы напряжения по элементам имеют странный вид: они меняются очень резко от элемента к элементу
Миниатюры
Нажмите на изображение для увеличения
Название: элементные напряжения2.png
Просмотров: 109
Размер:	217.9 Кб
ID:	117850  
Вложения
Тип файла: rar вопрос форум.rar (2.16 Мб, 43 просмотров)
Stanum вне форума  
 
Непрочитано 04.12.2013, 09:11
#354
MrWhite


 
Регистрация: 18.09.2011
Нахабино
Сообщений: 1,021


Цитата:
материал для них одинаковый: только tb,kinh без tb, conc/
Запустил макрос, просматриваю кривые strain-stress существенно отличаются для материалов 1 и 6.
По элементному решению которое вы считаете корнем проблемы не беспокойтесь, это жертва скорости решения.
MrWhite вне форума  
 
Непрочитано 04.12.2013, 11:52
#355
Stanum

Dr
 
Регистрация: 16.10.2011
Днепропетровск
Сообщений: 1,020
<phrase 1=


MrWhite, материал оба раза 6. 1 с ниспадающей ветвью пока не использовал.

Цитата:
Сообщение от MrWhite Посмотреть сообщение
Цитата:
По элементному решению которое вы считаете корнем проблемы не беспокойтесь, это жертва скорости решения.
Вы имеете ввиду, что у меня сетка крупная?

Просто, при использовании 185, таких скачков нет.
Stanum вне форума  
 
Непрочитано 04.12.2013, 12:18
#356
frostyfrost

Юмористические расчеты, комедийные диссертаций, цирковые статьи
 
Регистрация: 12.12.2012
Москва
Сообщений: 891


Такой вопрос, а какую диаграмму KINH деформирования задавать для цилиндров, призм и т.д.? Ведь в РФ - диаграмма задается в призменной прочности, в ЕС - цилиндрическая. По идее должна быть одна диаграмма общая, поскольку в зависимости от того, что считаем (призму, куб, цилиндр), на выходе должны иметь соответствующую прочность, как этот момент можно увязать. Плюс вопрос в том, что по KINH и т.п. условие пластичности не совсем применимо к бетону.

Последний раз редактировалось frostyfrost, 04.12.2013 в 12:29.
frostyfrost на форуме  
 
Непрочитано 04.12.2013, 12:19
#357
MrWhite


 
Регистрация: 18.09.2011
Нахабино
Сообщений: 1,021


Я простите не понимаю суть Вашей проблемы.
Вы сравниваете одинаковый материал используя разные конечные элементы? Тогда зачем Вам 65-ый? Он не фига не аналог 185-ого. И зачем Вам менять опции 185-ого, когда в хелпе ясно описано какая для чего нужна. Какие вы там реакции на графике смотрите я тоже не понимаю. Опишите как Вы ее находите.
MrWhite вне форума  
 
Непрочитано 04.12.2013, 12:38
#358
Stanum

Dr
 
Регистрация: 16.10.2011
Днепропетровск
Сообщений: 1,020
<phrase 1=


MrWhite,спасибо за участие в теме, считал, нелинейно с 65 бетон, после разрушения, решил проверить, при какой нагрузке элемент разрушился, для каждого set, суммировал реакции в закреплении нижней пластины, в итоге имею зависимость суммарной реакции от прилагаемого смещения верхней пластины(времени). Умножав пиковую реакцию на 4 и поделив на площадь куба хотел бы получить ту прочность, что задал в начале. Не получил. Решил проверить где ошибся задал кубу 185 элемент, убрал tb, conc, проверил нагрузку снова - получил. Проверил тоже самое но с 65, не получил + вдобавок значение реакции менялось в зависимости от количества шагов.

Опции менял, для того, чтоб попытаться получить результат как с 65, не смог этого добиться. Я просто прочитав одну статью почему-то решил, что это из-за shear locking в элементах, хотя изгиба у меня нет.
Stanum вне форума  
 
Непрочитано 04.12.2013, 13:01
#359
MrWhite


 
Регистрация: 18.09.2011
Нахабино
Сообщений: 1,021


А... вот теперь более понятно (вы меня простите, Ваша задача очень долго считается на моем калькуляторе). Тогда такой вопрос вы когда 65-ым делали смотрели картину трещинообразования?
И да, как и правильно отметил frostyfrost, закон KINH работает по критерию мизеса, закон CONC (для 65-ого) это сочетания 4-х отличающихся законов прочности. Т.е. как Вы их так просто собираетесь сравнить - непонятно. Если пластика в бетоне наступит раньше чем в KINH (что очень вероятно) то и реакция будет конечно другой сразу (вы же нагрузку перемещениями прикладываете?).
MrWhite вне форума  
 
Непрочитано 04.12.2013, 14:08
#360
Stanum

Dr
 
Регистрация: 16.10.2011
Днепропетровск
Сообщений: 1,020
<phrase 1=


MrWhite, да трещины смотрел (когда использовал материал бетон), общий вид получал 2 пирамиды НО, что мне не понравилось, трещины на первом этапе проявлялись :
А) очень резко = одна трещинка на грани куба следующий шаг почти весь куб в трещинах
Б) проскакивали узлы, то есть появлялись в тех же местах, что и скачки на картинке, напряжений, что я выложил, то есть сначала к примеру во всех 65 трещит к примеру 8 узел, а, потом трещит и все остальное,
Поэтому и решил проверить, не ошибся ли где-то. 65 без законов , по идее должен быть = обычному 8 узловому объемнику, а не получился.

На ваш вопрос по совмещенную законов, пока не могу ответить, я считал, что поверхность Вилама - Варнаке, определит поверхность разрушения, а kinh, путь к этой поверхности, наверно, я здесь не прав, но это не должно влиять на задачу тестовую, так как поверхность Варнаке, я в ней не задал. И 65 должен работать только по закону kinh.

Да: нагрузка перемещением верхней пластины.
Stanum вне форума  
Ответ
Вернуться   Форум DWG.RU > Программное обеспечение > Расчетные программы > ANSYS > Проблемы с расчетом Ж/Б каркаса в ANSYS

Размещение рекламы
Опции темы Поиск в этой теме
Поиск в этой теме:

Расширенный поиск


Похожие темы
Тема Автор Раздел Ответов Последнее сообщение
Нужна помощь с расчетом ж/б "клюшки" по серии 1.822.1-2/82 вып.4 Lexzus Железобетонные конструкции 4 11.12.2011 11:10
Помогите с расчетом ж/б стены прямоугольного в плане бассейна Den_13 Железобетонные конструкции 2 18.01.2010 10:41
Скатная кровля для ж/б каркаса ИИ-04 Antony206 Железобетонные конструкции 6 14.12.2009 23:18
Наращивание существующего ж/б каркаса Белозерова Татьяна Железобетонные конструкции 17 16.02.2009 14:23
узлы сопряжения ж/б ригелей и стальных стоек каркаса ТОЛЬКО ПРИШЕДШИЙ Поиск литературы, чертежей, моделей и прочих материалов 0 10.12.2007 12:02