Расчет жб армированной колоны

Расчет жб армированной колоны · 03.01.2014, 13:43

Предлагаю модель расчета ж.б. колоны. Ваши пожелание, предложения, критика

Код:

finish !
/clear,nostart !Очистка модели так как сохранение не найдено
/undo,on !Включаем возможность отмены действий

/prep7 !Вход в препроцессор
/units,si ! Устанавливаем единицы измерения СИ

!!!параметры, м и Па
*set,pi,3.1415926535897932384626433832795
*set,a,.3 !Высота сечения колоны м
*set,b,.3 !Ширина сечения колоны м
*set,h,3 !Высота колоны м
*set,k,50 !Расстояние от грани колоны до центра продольного арматурного стержня мм
*set,d,16 !Диаметр продольной арматуры мм
*set,arx,45 !для определния количества элементов разбиваемых по длине
*SET,APPROX,h/arx!Зададим размер разбиения сетки
*set,A_s,d*d*pi/(4*1E6) ! Площадь продольной арматуры в м2
*SET,M_Y,10E3 ! на колонну в Н*м

! Секция элементов и констант
ET,1,SOLID65 ! тип элемента – солид65(бетон)
R,1 ! реал константы под него
ET,2,LINK180 ! тип элемента – линк180 (арматура)
R,2,A_s ! площадь арматуры продольной
ET,3,plane42

!Секция свойств материалов
E_x_s=2E11 ! Модуль упругости стали продольной арматуры Па
E_x_b=3.94722222E10 ! Модуль упругости бетона(начальный)
MP,EX,1,E_x_b ! материал, линейный, 1(бетон), модуль упругости
MP,NUXY,1,0.2 ! малый ?модуль пуассона

MP,EX,2,E_x_s ! материал, линейный, 2(сталь), модуль упругости
MP,NUXY,2,0.3 !модуль пуассона
TB,BISO,2 ! Билинейная диаграмма деформирования стали
TBDATA,1,2.5E08 ! Предел текучести в Па
TBDATA,2,1.45E09 ! Секущий модуль в Па

!Создание модели
! Продольная арматура
TYPE,2 ! Тип элемента
MAT,2 ! Материал
REAL,2 ! Выбор реальной константы
K,1,a/2-k*0.001,b/2-k*0.001 ,0 !Кейпойнты
K,2,a/2-k*0.001,b/2-k*0.001 ,h
L,1,2 !Линия арматуры
MSHKEY,1!ЗАдание типа построения регулярной (1) сетки
MOPT,QMESH,MAIN!Определение параметров построения сетки, основной (main) генератор четырехугольной сетки (qmesh)
! Мешинг продольной арматуры
ALLSEL ! Выбор линий для применения параметров мешинга
LESIZE,ALL,APPROX,,,,,,1 ! Задание шага для мешинга
REAL,2 ! Выбор р.к.
LMESH,1,1,1 ! Мешинг арматуры

ALLSEL !Выбираем все объекты, линии
LSYMM,Y,ALL !Копируем симметрично осей X-Z
ALLSEL !Выбираем все объекты, линии
LSYMM,X,ALL !Копируем симметрично осей X-Y

!Бетонный массив
TYPE,3 ! Задание элемента, материала и констант
MAT,1
REAL,1

BLC4,0,0,a/2-k*0.001,b/2-k*0.001,0!Создаем плоскость ограниченную линиями арматуры
! Мешинг
BLC4,a/2,0,-k*0.001,b/2-k*0.001,0!Создаем правый квадрат
BLC4,0,b/2,a/2-k*0.001,-k*0.001,0!Создаем верхний квадрат
BLC4,a/2,b/2,-k*0.001,-k*0.001,0!Создаем верхний правый квадрат
ARSYM,X,ALL
ARSYM,Y,ALL
ESIZE,k*0.001
MSHKEY,1
AMESH,ALL

EXTOPT,ESIZE,arx,1,!Задаем параметры разбиения по длине
VEXT,all, , ,0,0,h,,,,
!Секция merge
NUMMRG,all

!Задаем граничные условия
asel,s,loc,z,0
DA,all,ALL

!Прикладываем нагрузку в верхней части колонны
NSEL,S,LOC,Z,h
NSEL,R,LOC,X,a/2
*GET,NCOUNTPLUS,NODE,0,COUNT
F,all,FZ,M_Y/a/NCOUNTPLUS
NSEL,S,LOC,Z,h
NSEL,R,LOC,X,-a/2
*GET,NCOUNTMINUS,NODE,0,COUNT
F,all,FZ,-(M_Y/a/NCOUNTMINUS)

/sol
allsel,all
SOLVE

Chardash · 03.01.2014, 14:15

К расчету хотелось бы увидеть сравнительную талицу значений полученных в ANSYS и по методике СНИП (прочность, устойчивость и тп). Желательно в графиках, процентном соотношении. Спасибо.

03.01.2014, 14:20

Пожелание - нужны результаты. Сравнения с экспериментами, с нормативными методиками расчета. Без этого и говорить не о чем...
Нет поперечной арматуры..? Тогда сам по себе расчет не имеет особого смысла - быстрее в Excel посчитать или в специализированной программе. Ведь одна из прелестей моделирования - как раз возможность наглядно отлавливать различные механизмы разрушения (по нормальным, либо наклонным сечениям, к примеру) - в зависимости от характера нагружения.
Также не видать начальных несовершенств (случайного эксцентриситета), без чего центральное сжатие должно дать неверный результат, как и расчет статически определимой колонны.
Было бы интересно, если бы размер сетки по сечению определялся от соотношения M/N, а не задавался пользователем - ведь для больших эксцентриситетов (либо изгиба) сетка по сечению нужна существенно гуще, думается можно процесс ее выбора "алгоритмизировать".
Хотя все эти вопросы отвлеченные, до тех пор пока не заявлено назначение модели - с этого можно начать

СергейД · 03.01.2014, 14:24

дальше начинается самое интересное= параметры нелинейного расчета...

Stanum · 03.01.2014, 14:43

Не хватает в 65 его свойств , параметров его поверхности разрушения.

----- добавлено через ~4 мин. -----
Ал-й, там же изгиб без сжатия.
iliorik, не уверен, но нагрузка приложенная напрямую к узлам бетона, может привести к проблемам со сходимостью.

03.01.2014, 14:55

Цитата:

Сообщение от Stanum

Ал-й, там же изгиб без сжатия.

А я то тут при чем?

p.s. в том то и дело, что без понимания того - для чего создавалась модель - сложно делать выводы.
Если верить названию - "расчет жб армированной колонны" - без сжатия и несовершенств не обойтись.

А вот без

Цитата:

параметров его поверхности разрушения.

для изгибаемых элементов (раз Вы настаиваете что у автора с пониманием назначения колонн в этом плане все нормально

) - зачастую можно и обойтись (если разрушение происходит по арматуре).

derik · 03.01.2014, 16:35

а смысл 65-го без conc? Ал-й прав - где колонна там и эксцентриситет, а вот как его вводить это отдельный разговор

и linc мона заменить 264-м имхо

Stanum · 03.01.2014, 16:50

6pa4o, а 264 разве с 65 работают вместе?(в справке только current tech указан)
Ал-й, не совсем Вас понял, разрушение по арматуре, но бетон в растянутой зоне работать же не должен,

derik · 03.01.2014, 17:00

264 - это дискретная арматура, как они могут не работь вместе с 65-м?

Stanum · 03.01.2014, 17:03

6pa4o,

Цитата:

REINF264 Assumptions and Restrictions
...
This element can be used only with base element types LINK180, SHELL181, SHELL281, SOLID185, SOLID186, SOLID187, BEAM188, BEAM189, SOLSH190, and SOLID285.

derik · 03.01.2014, 17:05

Offtop: REINF264
3-D Discrete Reinforcing

REINF264 Element Description

Use REINF264 with standard 3-D link, beam, shell and solid elements (referred to here as the base elements) to provide extra reinforcing to those elements.

The element is suitable for simulating reinforcing fibers with arbitrary orientations. Each fiber is modeled separately as a spar that has only uniaxial stiffness. You can specify multiple reinforcing fibers in one REINF264 element. The nodal locations, degrees of freedom, and connectivity of the REINF264 element are identical to those of the base element.

Stanum · 03.01.2014, 17:20

Offtop: 6pa4o, и чему теперь верить?

(началу справки или ее окончанию)

Chardash · 03.01.2014, 17:24

REINF264

derik · 03.01.2014, 17:26

сами подумайте, как это так - исполдьзовать элемент массивного жб и не использовать элемент армирования?! это как 45-й, в хелпе нет его описания, а использовать можно

вообщем вместо линка лучше его юзать, тем более можно макрос на все случаи сделать с ним.

MrWhite · 03.01.2014, 17:47

От связки 65 и 264 поддержка Ansys открестилась сославшись на старость 65-ого элемента. По факту - 264 работает со всеми MDTT элементами. Это я лично проверял. При этом сходимость нелинейных задач с ним соответствует внутреннему размазанному армированию 65-ого и намного лучше линков и beam'ов.
По сабжу: ценность макроса была бы вещественна если бы можно было задавать произвольное сечение колонны с произвольным армированием, а также эксцентриситетом нагрузки и настройками решателя. Без всего этого сабж просто генерация колонны с армированием, что само по себе интересно только совсем уж начинающим для освоения параметризации APDL.

derik · 03.01.2014, 17:50

Цитата:

Сообщение от MrWhite

если бы можно было задавать произвольное сечение колонны с произвольным армированием, а также эксцентриситетом нагрузки

а как? генерировать surf и через него прикладывать нагрузку с эксцентриситетом исходя из расчета по СП? или есть еще варианты?

MrWhite · 03.01.2014, 17:54

Цитата:

Сообщение от 6pa4o

а как? генерировать surf и через него прикладывать нагрузку с эксцентриситетом исходя из расчета по СП? или есть еще варианты?

Ну я бы да, через 154-ый решил. И уж конечно давлением, а не узловыми силами. Но конечно есть варианты

. Можно например создать одноузловой элемент, соединить его уравнением связи с колонной и приложить на него силу и момент, а можно разметить его не соосно и приложить только силу. Да много вариантов то

derik · 03.01.2014, 17:56

Цитата:

Сообщение от MrWhite

Можно например создать одноузловой элемент

я этого и боялся...это все сложно, а вот 154-й первое что приходит на ум

а с "пилотными" узлами как то не понял...или читал невнимательно

iliorik · 03.01.2014, 18:46

Спасибо за критику. Принимаю все к сведению.
В ближайшее время подготовлю расчет по СНиП того что хочу.
Данную модель решил сделать для оценки необходимости усиления колонны уголками, в следствие недостаточности или потери несущей способности.

Stanum · 03.01.2014, 18:53

Цитата:

Сообщение от iliorik

в следствие недостаточности или потери несущей способности.

а как Вы планируется это моделировать?

03.01.2014, 19:27

Цитата:

Сообщение от Stanum

Ал-й, не совсем Вас понял, разрушение по арматуре, но бетон в растянутой зоне работать же не должен,

и для чего нужен учет объемного НДС в этом случае? Или учет опции разрушения сжатого бетона? (автор статьи - Евгений Екатеринбург) https://www.google.ru/url?sa=t&rct=j...390WptbmoPeLHg

Цитата:

Сообщение от iliorik

Данную модель решил сделать для оценки необходимости усиления колонны уголками, в следствие недостаточности или потери несущей способности.

Очень сложновыполнимая задача...

Offtop: p.s. А все таки, ув. пользователи/владельцы Ansys - как там microplane? Или другие solid65 заменители? Вроде уже 16 я версия вышла - есть подвижки? Появились новые модели? Так - любопытство

Stanum · 03.01.2014, 19:36

Ал-й, ну так автор статьи использует поверхность разрушения conc, без этого solid65=solid45- и работает одинаково и на сжатие и на разрушение. А так как у автора темы и пластичность тоже для материала бетона не задана, то материал даже не уменьшает свои жесткостные характеристики.

03.01.2014, 19:52

Stanum, да хоть Друкера-Прагера бы он использовал - при чем тут особенности реализации?
Я про то, что для элемента с одноосным НДС в общем случае не нужно ничего кроме кроме пределов прочности на одноосное сжатие и растяжение, а в ряде случаев - достаточен даже только один из них.

Stanum · 04.01.2014, 01:18

Ал-й, так и я о том гутарю, автор темы не задал этих пределов в своем макросе.

derik · 10.01.2014, 23:31

https://cloud.mail.ru/public/e30c000...Project003.exe вот тут показана работа макроса по армированию колонны прямоугольного сечения (да хоть квадрата

) все параметризировано. вот с этого топик пастеру нужно было начать, осталось решить вопрос с эксцентриситетом

(макрос расчитан только на армирование, расчета и подбора сечений нет

)

кстати арматура смоделирована 264

iliorik · 13.01.2014, 07:37

Праздники закончились - УРА!
Расчет еще не подготовил, каюсь. Надеюсь руки дойдут и до него.
Вообщем как я понял в ANSYS мне еще учиться и учиться. А я то думал все знаю)

----- добавлено через ~5 ч. -----
бра4о спасибо большое за пример.
Вопрос первый: как учитывается совместное действие конечных элементов бетона и арматуры, когда стержень я так понимаю проходит по центру кубического КЭ.
Второй вопрос: где почитать, и на что обратить внимание для задания адекватных характеристик материала. Я предполагал выполнять расчет в линейной постановке.
Интересует больше всего конечно же напряжения в арматуре и бетоне, которые потом сравниваю с предельными по справочнику и определяю, необходимо усилить колонну или нет.
И маленькое пояснение. Результаты лично я всегда смотрю через "Resultat viewer". Поэтому результаты в коде не описываются (признаюсь, не умею писать код результатов).

derik · 13.01.2014, 12:35

1. почитайте описание 264, все ответы в хелпе;
2. здесь была выложена куча макросов с заданием материалов, поиск рулит

;
3. я тоже результаты смотрю через гуй, но просто через постпроцессора не через вивер.

iliorik · 16.01.2014, 21:14

Вот переписал код.
Добавил нелинейность, приложение нагрузки теперь через поверхности.
Вопросы:
Как задать шаговую нагрузку?
Показать график напряжений в арматуре и бетоне в зависимости от шага?

Код:

[Выделить все]

finish !
/clear,nostart !Очистка модели так как сохранение не найдено
/undo,on !Включаем возможность отмены действий

/prep7 !Вход в препроцессор
/units,si ! Устанавливаем единицы измерения СИ

!!!параметры, м и Па
*set,pi,3.1415926535897932384626433832795
*set,a,.3 !Высота сечения колоны м
*set,b,.3 !Ширина сечения колоны м
*set,h,3 !Высота колоны м
*set,k,50 !Расстояние от грани колоны до центра продольного арматурного стержня мм
*set,d,16 !Диаметр продольной арматуры мм
*set,arx,45 !для определния количества элементов разбиваемых по длине
*SET,APPROX,h/arx!Зададим размер разбиения сетки
*set,A_s,d*d*pi/(4*1E6) ! Площадь продольной арматуры в м2
*SET,M_Y,35E3 ! Момент на колонну в Н*м 
*SET,F_z,1200E3 !Сжимающая сила в Н 
*SET,RBt,1.55E6!Прочность бетона на растяжение Па
*SET,RB,18.5E6!Прочность бетона на сжатие Па
*SET,EB,3.6E10/(1+1.9)!Модуль упругости бетона в Па с учетом длительного воздействия нагрузки по СП27.13330.2011 ф.5.10

! Секция элементов и констант
ET,1,SOLID65,,,2,,1,3			! тип элемента – солид65(бетон)
R,1                 			! реал константы под него
ET,2,link180             		! тип элемента –  (арматура)
R,2,A_s                     		! площадь арматуры продольной
ET,3,plane42					!Для свипинга

KEYOPT,1,7,1 !Включите растяжение после трещинообразования, для сходимости
KEYOPT,1,8,1 !Отключить печать предупреждений


!Секция свойств материалов
UIMP,1,EX,DENS,NUXY,EB,2500,0.2 !Задаем материал бетона
UIMP,2,EX,DENS,NUXY,2E10,7800,0.2 !Задаем материал арматуры
!Нелинейный бетон
TB,CONCR,1,1,3,1	!создает таблицу для нелинейных свойств бетона
TBDATA,,0.3,0.8,RBt,RB,,,!на сжатие работа по диаграмме
TBDATA,,,,0.6,,,!остаточная прочность
TB,KINH,1,1,3 !Ниспадающая ветвь
TBPT,,(RB*0.6)/EB,RB*0.6
TBPT,,0.0034,RB*1
TBPT,,0.0048,RB*1
!Нелинейная арматура
TB,BISO,2			! Билинейная диаграмма деформирования стали
TBDATA,1,2.5E08		! Предел текучести в Па
TBDATA,2,1.45E09		! Секущий модуль в Па

!Создание модели
! Продольная арматура
TYPE,2				! Тип элемента
MAT,2				! Материал
REAL,2			! Выбор реальной константы
K,1,a/2-k*0.001,b/2-k*0.001	,0	!Кейпойнты
K,2,a/2-k*0.001,b/2-k*0.001	,h
L,1,2 !Линия арматуры
MSHKEY,1!ЗАдание типа построения регулярной (1) сетки
MOPT,QMESH,MAIN!Определение параметров построения сетки, основной (main) генератор четырехугольной сетки (qmesh) 
		 ! Мешинг продольной арматуры
ALLSEL	! Выбор линий для применения параметров мешинга
LESIZE,ALL,APPROX,,,,,,1		! Задание шага для мешинга
REAL,2			! Выбор р.к.
LMESH,1,1,1			! Мешинг арматуры

ALLSEL !Выбираем все объекты, линии
LSYMM,Y,ALL !Копируем симметрично осей X-Z
ALLSEL !Выбираем все объекты, линии
LSYMM,X,ALL !Копируем симметрично осей X-Y

!Бетонный массив
TYPE,3				! Задание элемента, материала и констант
MAT,1
REAL,1

BLC4,0,0,a/2-k*0.001,b/2-k*0.001,0!Создаем плоскость ограниченную линиями арматуры
! Мешинг
BLC4,a/2,0,-k*0.001,b/2-k*0.001,0!Создаем  правый квадрат
BLC4,0,b/2,a/2-k*0.001,-k*0.001,0!Создаем  верхний квадрат
BLC4,a/2,b/2,-k*0.001,-k*0.001,0!Создаем верхний правый квадрат
ARSYM,X,ALL
ARSYM,Y,ALL
ESIZE,k*0.001
MSHKEY,1
AMESH,ALL

EXTOPT,ESIZE,arx,1,!Задаем параметры разбиения по длине
VEXT,all, , ,0,0,h,,,, 
 !Секция merge
NUMMRG,all

 !Задаем граничные условия
 asel,s,loc,z,0
 DA,all,ALL

 !Рачет плоскостной нагрузки с учетом эксцентриситета
 Q_plus=F_z+M_Y/a !Максимальная нагрузка на полуплоскость колонны
 Q_minus=F_z-M_Y/a !Минимальная нагрузка на полуплоскость колонны
!Прикладываем нагрузку в верхней части колонны
ASEL,S,LOC,Z,h
ASEL,R,LOC,X,0,a/2
SFA,all,,pres,Q_plus
ASEL,S,LOC,Z,h
ASEL,R,LOC,X,-a/2,0
SFA,all,,pres,Q_minus

/sol
allsel,all
SOLVE
eplot,all
finish

derik · 16.01.2014, 21:21

а разве пуассон для арматуры не 0,3?

чучело-мяучело · 17.01.2014, 09:05

а разве Юнг для арматуры не 2E11 Па?

derik · 17.01.2014, 09:09

Offtop: чучело-мяучело, мы придираемся к мелочам

iliorik · 17.01.2014, 09:25

Согласен) Глаз замылился.
Теперь подскажите мне пожалуйста команды шага нагружений и отображения графиков (а именно построения графика максимальных напряжений для материала арматуры). Разберусь про help apdl.
Арматуру решил оставить пока link180, потому что далее буду моделировать образование трещины (попытаюсь хотя бы). И будет интересно как поведет себя арматура в трещине.
Расчеты как и говорил сделаю, но только после того как замечаний к модели в ansys будет по минимуму. Паралельно уже занимаюсь поиском опытов по образованию трещин в жб что б сравнить хоть, что то.
Железобетон - целая среда, где чем дальше, тем интересней и интересней)) Боже как увлекательно!

MrWhite · 17.01.2014, 09:29

Цитата:

Сообщение от iliorik

Арматуру решил оставить пока link180, потому что далее буду моделировать образование трещины (попытаюсь хотя бы). И будет интересно как поведет себя арматура в трещине.

В каком смысле моделировать образование трещины собираетесь?

derik · 17.01.2014, 09:29

У Вас даже нелинейность не включена

а опции, примерно такие:

Код:

[Выделить все]

/GST,1,1
NLDIAG,NRRE,ON
LNSRCH,ON
NLGEOM,ON
AUTOTS,ON
EQSLV,SPARSE
!NROPT,UNSYM,,ON
OUTRES,ALL,ALL
CUTCON,NOSHAPE,1
CUTCON,PLSLIMIT,1
CNVTOL,F,,.5
NSUBST,25,100000,25
TIME,50
NEQIT,7
SOLVE,,,,,NOCHECK

воспользуйтесь поиском, тут куча макросов с опциями, сообщения СергеД и MrWhite полны информации и полезных советов!

чучело-мяучело · 17.01.2014, 09:33

У меня вопрос по заданию нагрузки. Нагрузка у Вас задается через SFA,all,,pres,Q_plus, т.е. задаваться должно давление, а размерность Q_plus - Н.
Так же считаю, что задавать на всю половину сечения максимальное значение давления не верно, нагрузка получится завышенной.

Offtop: Любая мелочь в итоге дорогого может стоить

iliorik · 17.01.2014, 10:01

6pa4o спасибо, а так их смотрю. Твою тему про проблеы расчета жб всю замусолил. Вспомнил даже что там когда то светился, но потом времени небыло - забросил ansys. Теперь появились задачи которые в лире не посчитать.
чучело-мяучело - действительно так. Спасибо за подсказку. надо всего то поделить на площадь.
В ansys, что непривычно - это отсутсвие единиц измерений, из за этого порой теряешься в размерностях. Надо как систематизировать в текстовом файле эту особенность. Привык считать в тоннах

чучело-мяучело · 17.01.2014, 13:56

У меня вопрос про моделирование бетона. С какой целью к модели материала "бетон" (TB,CONCR) подключают KINH?

derik · 17.01.2014, 18:36

чучело-мяучело, диаграмма материала

чучело-мяучело · 17.01.2014, 21:51

Помогите разобраться.
Я думал, что, включая TB,KINH, мы задаем не только диаграмму, но и подключаем модель пластичности, в которой будут присутствовать остаточные пластические деформации и эффект Баушингера. К бетону, я считал, эти понятия не применимы.

чучело-мяучело · 26.01.2014, 13:16

Предлагаю продолжить обсуждение на сколько "законно" подключение KINH к бетону.
Считаю, это будет полезно для многих начинающих (в том числе и меня).

iliorik · 14.02.2014, 10:11

И так я пришел к закономерному концу. Колонну я посчитал. Реализации дальнейшего не вижу смысла. Руками пока проще.
В завершение выскажу одну мысль, когда уже начнут все совершенно считать по МКЭ (все элементы, усилени и прочее) тогда наступит будущее. Но это будет еще не скоро.

E_note · 19.02.2014, 17:06

Offtop: Коллеги, подскажите, пожалуйста, где на сайте я могу разместить просьбу о расчете в Ansys за вознаграждение? Новую тему форума же нельзя создавать такую...

Похожие темы
Тема	Автор	Раздел	Ответов	Последнее сообщение
расчет жб монолитной плиты перекрытия в лире	Лиза	Лира / Лира-САПР	24	16.11.2015 23:30
Лира, нелинейный расчет ЖБ плиты, отличие от линейного.	ivanoffsergei	Лира / Лира-САПР	46	25.11.2013 20:47
Расчет жб резервуара на температурные воздействия в холодном климате	high_zero	Железобетонные конструкции	1	24.09.2012 08:59
расчет монолитной жб плиты в лире	Лиза	Железобетонные конструкции	2	09.06.2010 09:37
Расчет жб балки?	Gsp	Железобетонные конструкции	12	10.07.2007 15:26

	Реклама i