Schöck
| Правила | Регистрация | Пользователи | Поиск | Сообщения за день | Все разделы прочитаны |  Справка по форуму | Файлообменник |

Вернуться   Форум DWG.RU > Программное обеспечение > Расчетные программы > ANSYS > Пара вопросов по контактным задачам Ansys

Пара вопросов по контактным задачам Ansys

Ответ
Поиск в этой теме
Непрочитано 03.09.2010, 22:28 #1
Пара вопросов по контактным задачам Ansys
Цветочек
 
Регистрация: 29.03.2009
Сообщений: 38

1. Можно ли считать контакт bonded закреплением?
Я в общем-то считаю что можно, но поясню - решаю задачу сжатия двумя жесткими плоскостями(targe170) стального пластичного диска в трехмерной постановке. Так вот нагрузку прикладываю к пилотным узлам,
d,30001,all,0
d,30005,uz,-0.5
d,30005,ux,0
d,30005,uy,0
Поскольку использую keyopt,all,12,3 кажется что дополнительные граничные условия не нужны - права ли я?
2. Какие могут быть дефекты контакта если контакт изначально открыт - хотя детали рядом, и сколько не переставляю нормали - всё так и есть?
Просмотров: 13247
 
Непрочитано 03.09.2010, 22:43
#2
aka raduntsev-nias

tester
 
Регистрация: 23.08.2008
Сообщений: 1,006


Для связных контакт дб MPC или Penalty с bonded
пусть поправят , если не прав
aka raduntsev-nias вне форума  
 
Непрочитано 03.09.2010, 22:54
#3
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


а код мона посмотреть или это военная тайна?

http://forum.dwg.ru/showthread.php?t=52057&page=9

тут почитайте...
derik вне форума  
 
Автор темы   Непрочитано 03.09.2010, 23:19 Ну конечно можно, что тут сложного
#4
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Вот код по которому я спрашиваю

Код:
[Выделить все]
/prep7
ET,1,SOLID185   
!*  
KEYOPT,1,2,0
KEYOPT,1,6,1
KEYOPT,1,10,0   
!*  
!*  
MPTEMP,1,0                             
MPDATA,EX,1,,2.1E11            
MPDATA,PRXY,1,,0.3  
TB,BKIN,1,1,2,0
TBTEMP,0  
TBDATA,1,2.6E8,0,,,,  

real,1
CYL4,0,0,17.5, , , ,8   
vsweep,all


! Создание контактной пары на нижней площадке
ET,2,CONTA173 ! можно делать conta173
keyopt,2,12,3 ! контакт bonded
KEYOPT,2,5,4
ET,3,TARGE170 ! 3-D TARGET ELEMENT
KEYOPT,3,2,1
! Геометрия твердой поверхности = target
n,30001,30,-30
n,30002,30,30
n,30003,-30,30
n,30004,-30,-30
! Создание площадки
alls
real,2
type,3
tshap,quad
E,30001,30002,30003,30004 ! плоскость площадки элемент
! Сама поставит нормаль
tshape,pilo
EN,6001,30001 ! Создаётся элемент 6001 pilo для контроля
allsel,all
type,2
NSEL,S,LOC,z,0 ! Выделяю плоскость c z=0;
NSEL,U,NODE,,30001,30004
ESURF,, ! GENERATE
allsel,all
! Эта пара начально закрыта - всё хорошо

real,3
! Создание контактной пары на инденторе
ET,4,CONTA173 
KEYOPT,4,5,4
keyopt,4,12,3 ! контакт bonded
ET,5,TARGE170 
KEYOPT,5,2,1
! Геометрия твердой поверхности = target
n,30005,30,-30,8
n,30006,30,30,8
n,30007,-30,30,8
n,30008,-30,-30,8
! Создание площадки
alls
type,5
tshap,quad
E,30005,30006,30007,30008 ! плоскость площадки элемент
tshape,pilo
EN,7001,30005 ! Создаётся элемент 7001 pilo для контроля

allsel,all
type,4
NSEL,S,LOC,z,8 ! Выделяю плоскость c z=8;
NSEL,U,NODE,,30005,30008
esurf,,
allsel,all
fini
/solu
nlgeom,on
lnsrch,on
d,30001,all,0
d,30005,uz,-0.5
d,30005,ux,0
d,30005,uy,0
solve
тупой Цветочек седня!

Последний раз редактировалось Кулик Алексей aka kpblc, 04.09.2010 в 15:52.
Цветочек вне форума  
 
Непрочитано 03.09.2010, 23:38
#5
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


вроде как криманала нет...кейопт,3,2,1 стоит, пилотные узлы закреплены...Сергей Иванович скажет больше, у него опыта больше в подобных делах.
Цветочек не тупой, цветочек, вероятно всего, просто устал! ;-)
derik вне форума  
 
Автор темы   Непрочитано 04.09.2010, 14:15 Да, я устала
#6
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Дело в том, что вот эта ошибка - вообще преследует меня - часто пишу в ансис с двумя контактными парами и очень часто эта ошибка - первая пара всегда закрыта, а вот вторая! всегда открыта - неприятно что-то недопонимать, но видимо в данном случае это так: реальные константы для разных пар разные, определение quad и pilo, как обычно; контактор можно покрывать и esurf и amesh, тоже как-бы обычно; если меняю направление - esurf,,reve - контактная пара вообще не создаётся. Так что видимо дело не в направлении нормалей, но в чём? - неужели я правильно грешу на граничные условия?
Цветочек вне форума  
 
Непрочитано 04.09.2010, 14:30
#7
aka raduntsev-nias

tester
 
Регистрация: 23.08.2008
Сообщений: 1,006


в WB в случае открытого контакта использовал pinball
Но, насколько понимаю, открытый есть не всегда плохо

Yellow: "The contact status is open. This may be acceptable."
Workbench has detected an open contact Status condition on a nonlinear contact type, Frictionless, Rough, or Frictional, which is probably acceptable under certain conditions as stated in their descriptions.
If the Status is Far Open, the Penetration and the Gap will be set to zero even though the Resulting Pinball is non-zero.

в APDL
Use real constant PINB to specify a scaling factor (positive value for PINB when using command input) or absolute value (negative value for PINB when using command input) for the pinball region. You can specify PINB to have any value. By default, and assuming that large deflection effects apply (NLGEOM,ON), ANSYS defines the pinball region as a circle for 2-D or a sphere for 3-D of radius 4*depth (if rigid-to-flexible contact) or 2*depth (if flexible-to-flexible contact) of the underlying element. (See the discussion of element depth in Positive and Negative Real Constant Values.) If you include no large-deflection effects (NLGEOM,OFF), the default pinball region is half that of the large-deflection case. (For the no-separation (KEYOPT(12) = 4) and bonded-always (KEYOPT(12) = 5 options, the PINB default is different than described here. See Selecting Surface Interaction Models for more information.)

Последний раз редактировалось aka raduntsev-nias, 04.09.2010 в 14:39.
aka raduntsev-nias вне форума  
 
Непрочитано 04.09.2010, 14:57
#8
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


а ты попробуй поставить keyopt,,5,1 - для автоматического закрытия зазора.5,4 - закрытие зазора и уменьшение проникновения.
derik вне форума  
 
Непрочитано 04.09.2010, 15:21
#9
aka raduntsev-nias

tester
 
Регистрация: 23.08.2008
Сообщений: 1,006


только что закрыл такую же ситуацию функцией нащупывания в WB
auto CNOF adjustment to close geometric gap only = keyopt,,5,1
keyo,cid,5,1 в wb

Последний раз редактировалось aka raduntsev-nias, 04.09.2010 в 15:31.
aka raduntsev-nias вне форума  
 
Непрочитано 04.09.2010, 17:17
#10
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


вот а я про што! а вы мне не верите
derik вне форума  
 
Непрочитано 04.09.2010, 17:57
#11
aka raduntsev-nias

tester
 
Регистрация: 23.08.2008
Сообщений: 1,006


лучше разобраться с контактами можно по файлику, что я скинул у тебя в теме
подробно расписано

Последний раз редактировалось aka raduntsev-nias, 04.09.2010 в 18:49.
aka raduntsev-nias вне форума  
 
Автор темы   Непрочитано 04.09.2010, 18:17
#12
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Нет, автоматическое закрытие зазора не то - не помогло - контакт открыт и контактная пара вне контакта!
Цветочек вне форума  
 
Непрочитано 04.09.2010, 18:33
#13
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


а выходной файлик мона посмотреть? (перед прер7 пропиши - /outp,outfile,txt,C:\ansys\output или в любую другую директорию
derik вне форума  
 
Автор темы   Непрочитано 04.09.2010, 19:15 эХ не верите вы Цветочку!
#14
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Поясню позицию иначе, когда запускается решение можно лицезреть две параллельные линии - норма и решение, вообще без пересечений

cncheck первой пары


*** NOTE *** CP = 6528.000 TIME= 19:15:20
Internal nodes from 30521 to 30691 are created.
1 internal nodes are used for handling DOF on pilot nodes of rigid
target surfaces.
170 internal nodes are used for 18x elements with mixed formulation.

*** NOTE *** CP = 6528.031 TIME= 19:15:20
Internal nodes from 30521 to 30691 are created.
1 internal nodes are used for handling DOF on pilot nodes of rigid
target surfaces.
170 internal nodes are used for 18x elements with mixed formulation.

*** NOTE *** CP = 6528.047 TIME= 19:15:20
Rigid-deformable contact pair identified by real constant set 2 and
contact element type 2 has been set up. The DOF of rigid surface is
driven by pilot node 30001.
Please verify constraints on the pilot node which may be
automatically fixed by ANSYS.
Contact algorithm: Augmented Lagrange method
Contact detection at: Gauss integration point
Default contact stiffness factor FKN 1.0000
The resulting contact stiffness 0.12571E+11
Default penetration tolerance factor FTOLN 0.10000
The resulting penetration tolerance 0.33410
Default opening contact stiffness OPSF will be used.
Default tangent stiffness factor FKT 1.0000
Default Max. friction stress TAUMAX 0.10000E+21
Average contact surface length 2.3968
Average contact pair depth 3.3410
Default pinball region factor PINB 3.0000
The resulting pinball region 10.023
Auto contact offset used to close gap 0.0000
*WARNING*: Initial penetration is included.
Bonded contact is defined.

*** NOTE *** CP = 6528.047 TIME= 19:15:20
Max. Initial penetration 0 was detected between contact element 6002
and target element 511.
****************************************


1 CONTACT PAIR IS SELECTED
CONTACT PAIR HAVING REAL ID = 2 IS INITIALLY CLOSED

cncheck второй - проблемной пары


NOTE *** CP = 6528.500 TIME= 19:16:00
Internal nodes from 30521 to 30691 are created.
1 internal nodes are used for handling DOF on pilot nodes of rigid
target surfaces.
170 internal nodes are used for 18x elements with mixed formulation.

*** NOTE *** CP = 6528.547 TIME= 19:16:00
Internal nodes from 30521 to 30691 are created.
1 internal nodes are used for handling DOF on pilot nodes of rigid
target surfaces.
170 internal nodes are used for 18x elements with mixed formulation.

*** NOTE *** CP = 6528.562 TIME= 19:16:00
Rigid-deformable contact pair identified by real constant set 3 and
contact element type 4 has been set up. The DOF of rigid surface is
driven by pilot node 30005.
Please verify constraints on the pilot node which may be
automatically fixed by ANSYS.
Contact algorithm: Augmented Lagrange method
Contact detection at: Gauss integration point
Default contact stiffness factor FKN 1.0000
The resulting contact stiffness 0.18029E+11
Default penetration tolerance factor FTOLN 0.10000
The resulting penetration tolerance 0.23295
Default opening contact stiffness OPSF will be used.
Default tangent stiffness factor FKT 1.0000
Default Max. friction stress TAUMAX 0.10000E+21
Average contact surface length 2.3968
Average contact pair depth 2.3295
Default pinball region factor PINB 3.0000
The resulting pinball region 6.9886
Auto contact offset used to close gap 0.0000
*WARNING*: Initial penetration is included.
Bonded contact is defined.

*** NOTE *** CP = 6528.562 TIME= 19:16:00
No contact was detected for this contact pair.
****************************************


*** WARNING *** CP = 6528.562 TIME= 19:16:00
All selected contact pairs are initially open. Rigid body motion can
occur. You may use auto CNOF/ICONT by setting KEYOPT(5) to close
small gaps.

1 CONTACT PAIR IS SELECTED
CONTACT PAIR HAVING REAL ID = 3 IS INITIALLY OPEN
BUT MAY BE AUTOMATICALLY CLOSED
Цветочек вне форума  
 
Непрочитано 04.09.2010, 19:25
#15
aka raduntsev-nias

tester
 
Регистрация: 23.08.2008
Сообщений: 1,006


Contact algorithm: Augmented Lagrange method
Contact detection at: Gauss integration point
Default contact stiffness factor FKN 1.0000

для bonded penalty или MPC
для Augmented Lagrange method FKN 0,1
для bonded 1-10 можно поставить на проверку в интерациях если есть сомнение

и PINB бы не помешал, вроде у вас он по умолчанию. контакт точно закроется с ф-ией автоматического закрытия зазора

вообще. нафиг бондеды - связную сетку и все

Сергей Иванович в теме брачо писал что делать, когда нет сходимости
геометрию дадите (3d), прогоню через WB. быстрей найдем ошибки

Последний раз редактировалось aka raduntsev-nias, 04.09.2010 в 20:52.
aka raduntsev-nias вне форума  
 
Автор темы   Непрочитано 04.09.2010, 20:53 Ответ прост
#16
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Цилиндр 35 радиусом и 8 толщиной - блин, с двух сторон сжимается 2 плоскостями - вот и геометрия.
Цветочек вне форума  
 
Непрочитано 04.09.2010, 21:17
#17
aka raduntsev-nias

tester
 
Регистрация: 23.08.2008
Сообщений: 1,006


точно) открыл ваш файл.
решил, но видно, где то не то задал.
у меня пока это получилось
Миниатюры
Нажмите на изображение для увеличения
Название: 123.jpg
Просмотров: 187
Размер:	36.1 Кб
ID:	44757  Нажмите на изображение для увеличения
Название: 1234.jpg
Просмотров: 115
Размер:	27.4 Кб
ID:	44758  

Последний раз редактировалось aka raduntsev-nias, 05.09.2010 в 00:02.
aka raduntsev-nias вне форума  
 
Автор темы   Непрочитано 04.09.2010, 22:42
#18
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Хе-хе!, вот видите как быстро дурь распространяется на умы!
Здесь какая-то тонкость - дело в том, что та же задача но с одной плоскостью и с равномерно распределённой нагрузкой на другой стороне нормально решается, а вот когда нагрузка прикладывается к контактной паре - через пилотный узел, что-то никак.
Цветочек вне форума  
 
Непрочитано 04.09.2010, 22:51
#19
aka raduntsev-nias

tester
 
Регистрация: 23.08.2008
Сообщений: 1,006


Цветочек. Нужно разбираться, я корректировал только контакт в классике и все. Остальное не трогал

а ну дак конечно. у вас контакт твердое тело- плоскость

в одной из книг Огородниковой об этом написано

вот код
Код:
[Выделить все]
/prep7
ET,1,SOLID185   
!*  
KEYOPT,1,2,0
KEYOPT,1,6,1
KEYOPT,1,10,0   
!*  
!*  
MPTEMP,1,0                             
MPDATA,EX,1,,2.1E11            
MPDATA,PRXY,1,,0.3  
TB,BKIN,1,1,2,0
TBTEMP,0  
TBDATA,1,2.6E8,0,,,,  

real,1
CYL4,0,0,17.5, , , ,8   
vsweep,all


! Создание контактной пары на нижней площадке
ET,2,CONTA175 ! можно делать conta173
keyopt,2,12,3 ! контакт bonded
KEYOPT,2,5,4
ET,3,TARGE170 ! 3-D TARGET ELEMENT
KEYOPT,3,2,1
! Геометрия твердой поверхности = target
n,30001,30,-30
n,30002,30,30
n,30003,-30,30
n,30004,-30,-30
! Создание площадки
alls
real,2
type,3
tshap,quad
E,30001,30002,30003,30004 ! плоскость площадки элемент
! Сама поставит нормаль
tshape,pilo
EN,6001,30001 ! Создаётся элемент 6001 pilo для контроля
allsel,all
type,2
NSEL,S,LOC,z,0 ! Выделяю плоскость c z=0;
NSEL,U,NODE,,30001,30004
ESURF,, ! GENERATE
allsel,all
! Эта пара начально закрыта - всё хорошо

real,3
! Создание контактной пары на инденторе
ET,4,CONTA175 
KEYOPT,4,5,4
keyopt,4,12,3 ! контакт bonded
ET,5,TARGE170 
KEYOPT,5,2,1
! Геометрия твердой поверхности = target
n,30005,30,-30,8
n,30006,30,30,8
n,30007,-30,30,8
n,30008,-30,-30,8
! Создание площадки
alls
type,5
tshap,quad
E,30005,30006,30007,30008 ! плоскость площадки элемент
tshape,pilo
EN,7001,30005 ! Создаётся элемент 7001 pilo для контроля

allsel,all
type,4
NSEL,S,LOC,z,8 ! Выделяю плоскость c z=8;
NSEL,U,NODE,,30005,30008
esurf,,
allsel,all
fini
/solu
nlgeom,on
lnsrch,on
d,30001,all,0
d,30005,uz,-0.5
d,30005,ux,0
d,30005,uy,0
solve

фу. устал. WB рулит!

Последний раз редактировалось aka raduntsev-nias, 05.09.2010 в 00:03.
aka raduntsev-nias вне форума  
 
Автор темы   Непрочитано 05.09.2010, 02:30 Отличный ответ! Спасибо,
#20
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


процитируйте пжлста эту фразу из Огородниковой, по поводу контакта с плоскостью.
Цветочек вне форума  
 
Непрочитано 05.09.2010, 08:15
#21
СергейД

расчеты МКЭ и CFD. ктн
 
Регистрация: 11.05.2005
Подмосковье
Сообщений: 2,098


друзья! Уж извините. занят очень срочной и важной работой.аэродинамика вовсе. Форум просматривать нет времени. ЕСли действительно важные вопросы (не учебные..) пишите в личку.
Только советы общего плана дать могу.
=
Пилотными узлами не пользуюсь принципиально (когда-то что-то не понравилось в них = возможно, что тоже самое, о чем волнуется Цветочек) и разбираться в них сейчас нет времени.
с обычным контактом какие проблемы?

А всех интересующихся (кстати) приглашаю на курсы ансис (начало октября) и на конференции (конец октября и середина ноября)в МГСУ (MGSU.ru).
СергейД вне форума  
 
Непрочитано 05.09.2010, 10:58
#22
aka raduntsev-nias

tester
 
Регистрация: 23.08.2008
Сообщений: 1,006


Цветочек, извините, не могу найти) Пропадаю на время. Tekla(AdvanceSteel) ждет, кроме расчетов я конструктор
мало времени на ansys остается
Миниатюры
Нажмите на изображение для увеличения
Название: molodech.jpg
Просмотров: 178
Размер:	67.4 Кб
ID:	44767  

Последний раз редактировалось aka raduntsev-nias, 05.09.2010 в 11:45.
aka raduntsev-nias вне форума  
 
Непрочитано 05.09.2010, 12:04
#23
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


Цитата:
Сообщение от aka raduntsev-nias Посмотреть сообщение
Цветочек, извините, не могу найти)
а что за книга? как называется, а то так каждую открывать и смотреть автора...
derik вне форума  
 
Непрочитано 05.09.2010, 12:28
#24
aka raduntsev-nias

tester
 
Регистрация: 23.08.2008
Сообщений: 1,006


Offtop: хоть убейте, не помню.
контакт - дело темное
WB = future
APDL = always

Последний раз редактировалось aka raduntsev-nias, 05.09.2010 в 12:39.
aka raduntsev-nias вне форума  
 
Автор темы   Непрочитано 05.09.2010, 12:52 Да ладно, главное вспомнили что там написано!
#25
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Вы уже мне сильно помогли друзья! Постоянно забываю про conta175. Моей основной заботой является контакт.
В столе лежит стопка неоконченных программ поскольку вот такие - как выше,дефекты, портят мне жизнь. Одну из головных болей я сняла. Но есть и другая!,Как заменить пилотные узлы если сама задача кажется что сформулирована через них, например, внутри обода колёс имеется контактная пара так что на этом рисунке есть по сути 3 контактные пары - в идеале нужна еще одна пара поскольку у одного из цилиндров бандаж 2 слойный. Если например принять контакт с пилотами, то получается тупо - один узел закрываем от перемещений, другой подвигаем вверх. А что тут поделать если без пилотов?
В моём примере контакт правда кривой(несколько не физичен), но думаю хорошая иллюстрация.
Толщина пластин - чисто номинально плоскости, это безразлично.
Миниатюры
Нажмите на изображение для увеличения
Название: file000.jpg
Просмотров: 170
Размер:	105.6 Кб
ID:	44768  

Последний раз редактировалось Цветочек, 05.09.2010 в 13:06.
Цветочек вне форума  
 
Непрочитано 05.09.2010, 13:05
#26
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


Offtop: а как книга то называется?

а толщина какаяпластин, что сжимают цилиндр, решу но без пилотных узлов, я вообще про них только слышал и читал ни разу, даже не пробывал, не применял переходи на обычный контакт
derik вне форума  
 
Непрочитано 05.09.2010, 13:35
#27
aka raduntsev-nias

tester
 
Регистрация: 23.08.2008
Сообщений: 1,006


Цитата:
Сообщение от Цветочек Посмотреть сообщение
3 контактные пары - в идеале нужна еще одна пара поскольку у одного из цилиндров бандаж 2 слойный.
возможно контакт симметричный, если нет, то слой и target, и contact
те 2 контакта
aka raduntsev-nias вне форума  
 
Непрочитано 05.09.2010, 19:29
#28
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


Код:
[Выделить все]
fini
/clear,nostart  
/outp,outfile,txt,C:\ansys\output   
/cwd,'C:\ansys\out' 

a=.600
h=.08
t=.02
r=.35
p=3e6

/prep7

et,1,185

mptemp,,,,,,,
mptemp,1,0  
mpdata,ex,1,,3e11
mpdata,prxy,1,,.3
mptemp,,,,,,,
mptemp,1,0
mpdata,ex,2,,6e11
mpdata,prxy,2,,.3

cylind,r,,,h,,90,
blc5,a/2,a/2,a,a,-t 
vgen,2,2,,,,,h+t,,,0
vsel,s,,,2,3
vatt,2, 
allsel,all  
!sfa,13,1,pres,p

mshkey,1
mshape,0,3d 
esize,t*2
vsweep,all  
allsel,all  

et,2,170
et,3,174
keyopt,3,2,1
keyopt,3,5,1
keyopt,3,9,1
keyopt,3,10,5
keyopt,3,12,5

mp,mu,3,.3  
mat,3   

r,3,,,.01,,,50
r,4,,,.01,,,50

type,2  
real,3  
asel,s,,,12 
nsla,s,1
esln,s,0
esurf   
type,3  
asel,s,,,2  
nsla,s,1
esln,s,0
esurf   

type,2  
real,4  
asel,s,,,7  
nsla,s,1
esln,s,0
esurf   
type,3  
asel,s,,,1  
nsla,s,1
esln,s,0
esurf   
allsel,all  
!cncheck,auto

asel,s,loc,y
asel,a,loc,x
da,all,symm 
da,6,all
da,13,uz,-1.3
allsel,all  
fini

/sol

/gst,1  
nldiag,nrre,on  
nropt,unsym,,on 
antype,0
nlgeom,1
nsubst,100,1000,50   
outres,erase
outres,all,all  
time,1
solve   
fini

/post1  

set,first   
fini
вот что получилось у меня, правда тоже не фонтан...нужно еще поиграться с опциями - но это позже чуть-чуть, счас другие дела есть немножко
derik вне форума  
 
Автор темы   Непрочитано 05.09.2010, 20:57 К сожалению, вынуждена учитывать специфику своих задач
#29
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


В том смысле что их тяжело перевести в безпилотное состояние. Поэтому если кто-то не знает пилотов, я ему объясню - это не сложно.
За коды спасибо!

Итак у меня трудный орешек. Рисунок имеется выше. Задача такова:
два трёхмерных цилиндра из стали контактируют друг с другом, но при этом их внутренние диаметры остаются без изменений - ну как будто начинка этих цилиндров абсолютно твёрдая. 3 контактные пары:
две внутри цилиндров, и одна между ними - обычная задача Герца.
Код,

Код:
[Выделить все]
/prep7
ex,1,1 ! модуль юнга 1 МПа
nuxy,1,0.3 ! коэффициент пуассона 0.3
et,1,82 ! элемент код 82
r=0.1 ! внутренний радиус верхнего цилиндра
dr=0.02 ! толщина бандажа верхнего цилиндра
k,1 ! 1 точка = координаты 0,0,0
k,2,r ! 2 точка = r,0,0
k,3,r+dr ! 3 точка r+dr,0,0
k,4,0,r ! 4 точка 0,r,0
k,5,0,r+dr ! 5 точка 0,r+dr,0
k,6,-r !  6 точка -r,0,0
k,7,-r-dr ! 7 точка -r-dr,0,0 ! здесь -r-dr - наружный диаметр 
k,8,0,-r ! 8 точка 0,-r,0
k,9,0,-r-dr! 9 точка 0,-r-dr
LARC,2,4,1,r, !1 кривая по 3 точкам и радиусу
LARC,4,6,1,r, 
LARC,6,8,1,r, 
LARC,8,2,1,r, 
LARC,3,5,1,r+dr, !5
LARC,5,7,1,r+dr, 
LARC,7,9,1,r+dr, 
LARC,9,3,1,r+dr, 
lstr,2,3 !9 ! прямая линия в глобальной системе координат - линия 9
lstr,4,5
lstr,6,7
lstr,8,9
al,1,10,5,9 ! площадь - четверть окружности малого вала 1 площадь
LESIZE,9,,,3,,,,,0 ! разбиваем линии с 9 по 12 на три участка - число ! элементов по толщине
LESIZE,10,,,3,,,,,0 
LESIZE,11,,,3,,,,,0 
LESIZE,12,,,3,,,,,0 
al,2,11,6,10 ! 2 площадь
al,3,12,7,11 ! 3 - - 
al,4,9,8,12 ! 4 - -
type,1 ! применяем элемент 82
real,1 ! реальные константы номер 1
mat,1 ! материал 1
MSHAPE,0,2D ! сетка из 4-угольников!
MSHKEY,1 ! mapped meshing
esize,0.01 ! характерный размер 1 элемента - 0.01
AMAP,1,2,3,5,4 ! mapped mesh площади 1 по угловым точкам 2,3,5,4
AMAP,2,5,4,7,6 !
AMAP,3,7,6,9,8 !
AMAP,4,9,8,3,2 !


ex,2,1! материал номер 2
nuxy,2,0.3 ! коэффициент пуассона номер 2
et,2,82 ! элемент 82 номер 2
r1=0.3 ! внутренний диаметр нижнего цилиндра
dr1=0.02 ! толщина стенки нижнего цилиндра
dy=-r-dr-r1-dr1 ! величина dy - межосевое расстояние между !верхним и нижним цилиндрами
k,11,0,dy ! центр нижнего цил коорд 0,dy,0
k,12,r1,dy ! далее и ниже прорисовка нижнего цилиндра
k,13,r1+dr1,dy
k,14,0,r1+dy
k,15,0,r1+dr1+dy
k,16,-r1,dy
k,17,-r1-dr1,dy
k,18,0,-r1+dy
k,19,0,-r1-dr1+dy
LARC,12,14,11,r1, !13 дуги окружности нижнего цилиндра
LARC,14,16,11,r1, 
LARC,16,18,11,r1, 
LARC,18,12,11,r1, 
LARC,13,15,11,r1+dr1, !17
LARC,15,17,11,r1+dr1, 
LARC,17,19,11,r1+dr1, 
LARC,19,13,11,r1+dr1, 
lstr,12,13 !21 прямые линии с 21 по 24 для указания количества слоев элементов по толщине
lstr,14,15
lstr,16,17
lstr,18,19
LESIZE,21,,,3,,,,,0 ! разбивка вышеперечисленных линий на 3 подлинии
LESIZE,22,,,3,,,,,0 
LESIZE,23,,,3,,,,,0 
LESIZE,24,,,3,,,,,0 
num=12 ! количество линий в верхнем цилиндре
al,num+1,num+10,num+5,num+9 ! создание 4 подобластей для слоя нижнего цилиндра 
al,num+2,num+11,num+6,num+10
al,num+3,num+12,num+7,num+11
al,num+4,num+9,num+8,num+12
type,2 ! тип элементов теперь 2 - реальные константы 2 материал 2 
real,2
mat,2
MSHAPE,0,2D  ! сетка 4-угольников
MSHKEY,1 ! mapped meshing
esize,0.01 ! характерный размер элемента 0.01
AMAP,5,12,13,15,14 ! mapped meshing всех 4-подобластей нижнего цилиндра
AMAP,6,15,14,17,16 
AMAP,7,17,16,19,18 
AMAP,8,19,18,13,12 

mat,1
ET,10,SOLID185
TYPE,10
ESIZE,,1
VEXT,1,4,,,,0.05

mat,2
ET,12,SOLID185   
TYPE,12
ESIZE,,1
VEXT,5,8,,,,0.05

!!!!!!!!!!!!! внеконтактная геометрия, сетка и элементы с материалами !созданы
!!!!!!! создание первой контактной пары - верхний цилиндр - между жестким валом и покрытием
mat,3 ! материал 3 не создан но мы все равно его используем что отвлечь ансис
ET,13,TARGE170 ! элемент типа недеформируемая цель
KEYOPT,13,2,1 ! граничные условия для этого элемента будут задаваться пользователем
type,13
R,13,r,0, ! радиус цели r
real,13 
tshap,cyli  ! определяем форму поверхности цели
n,100000 ! узел с номером 100000 имеет координаты 0,0,0
n,120000,0,0,0.05
en,100000,100000,120000 ! задаем элемент cyli номера 100000 вида цель с узлом 100000 центре верхнего - здесь элемент 100000 это цилиндрический элемент цель.
TSHAP,PILO ! создаем мастер узел - элемент 100001
En,100001,100000 ! элемент 100001 pilot создаем с узлом в центре верхнего 
et,14,conta173 ! декларируем элемент вида контакт 174
KEYOPT,14,12,5 ! он всегда будет always bonded
type,14
real,13! используем  реальные константы номер 13  
CSYS,1
ASEL,S,LOC,x,r
NSLA,,1                    
ESURF              
csys,0
allsel,all

mat,4 ! материал номер 15 - его тоже нету
ET,15,TARGE170 ! элемент 15 - недеформируемая цель
KEYOPT,15,2,1 ! граничные условия задает пользователь
type,15
R,15,r1,0, ! радиус поверхности цели - мишени
real,15
tshap,cyli ! задаем форму поверхности цели
n,1000000,0,dy ! создать узел номером 10000 с координатами 0,dy,0
n,1200000,0,dy,0.05
en,1000000,1000000,1200000! создать элемент типа элемент-цель номером 1000000
TSHAP,PILO  ! создаем мастер-узел с номером 1000001
En,1000001,1000000 ! создание элемента 10001 с мастер-узлом
et,16,conta173 ! элемент вида conta173
KEYOPT,16,12,5  ! этот контактный элемент будет always bonded
type,16 ! создаем теперь контактные элементы
real,15 ! реальные константы номер 5 
local,11,1,0,dy,0
csys,11
asel,s,loc,x,r1
NSLA,,1                    
ESURF                
csys,0
allsel,all ! выделяем все!

! контактные пары отвечающие за внутренние контакты - между слоями и жесткими валами созданы

! Создание контактной пары для контакта двух слоев!
mat,5 ! задаем этот самый 17 материал Его тоже нет
ET,17,TARGE170 ! используем элемент типа деформируемая цель - мишень
type,17
real,17! реальные постоянные номер 17
r,17 ! реальные постоянные 17
csys,1 
esize,,1
asel,s,loc,X,R+DR
AMESH,ALL
allsel,all ! выделяем все!
et,18,conta173 ! 18 вид элемента - conta173
KEYOPT,18,4,2 ! L
KEYOPT,18,10,5 ! 
KEYOPT,18,2,3 ! 
type,18
real,17
local,11,1,0,dy,0
csys,11
asel,s,loc,x,r1+dr1
amesh,all
ESEL,S,REAL,,17 
ESURF,,REVERSE 
allsel,all
csys,0


/solu
nlgeom,on ! включить нелинейные геометрические величины - большие перемещения и вращения
nropt,unsym,,on ! Несимметричный решатель
lnsrch,on ! Включить line-search
pred,on ! Предсказывать
!CNVTOL,u,1,0.0001,2, ! определить сходимость по перемещениям, точность 0.01%, норма сходимости L2 
deltim,0.1,0.1,0.1
!deltim,0.001,0.0001,0.01 ! шаг решения 0.1 - очень быстрое решение
time,1 !
!
!d,100000,all
!ddele,10000,uy
!d,1000000,uy,0.1*dr
!d,1200000,uy,0.1*dr
!d,1000000,ux
!d,1200000,ux
 ! задать узлу 100000 перемещения по y вниз на 0.1*dr - верхний цилиндр
!d,1000000,ux ! закрепить центральный узел нижнего цилиндра по x
!d,1000000,uy,0.0 ! закрепить центральный узел нижнего цилиндра по y
!d,120000,all
!d,100000,all
!

d,all,rotx,0
d,all,roty,0
d,all,rotz,0
!solve ! решаем статическую задачу - вращения нет
d,120000,all
d,100000,all
d,1000000,uy,0.1*dr
d,1000000,ux,0
d,1000000,uz,0
d,1200000,uy,0.1*dr
d,1200000,ux,0
d,1200000,uz,0
Честно говоря вид этой проги вызывает ужос,Но - два цилиндра - вначале два блока, а потом последовательно 3 контактные пары, потом блок решения и всё
Думаю что эта задача достаточно сложна, как говориться дорогу осилит идущий, не так ли?
Всем спасибо!

Последний раз редактировалось Цветочек, 05.09.2010 в 21:07.
Цветочек вне форума  
 
Непрочитано 05.09.2010, 21:04
#30
Кулик Алексей aka kpblc
Moderator

LISP, C# (ACAD 200[9,12,13,14])
 
Регистрация: 25.08.2003
С.-Петербург
Сообщений: 36,861


Цветочек, про тэг code не забывай
__________________

---
Обращение ко мне - на "ты".
Все, что сказано - личное мнение.
Кулик Алексей aka kpblc вне форума  
 
Автор темы   Непрочитано 05.09.2010, 21:05
#31
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Простите меня! Я просто не знала.
Цветочек вне форума  
 
Непрочитано 05.09.2010, 21:38
#32
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


а в чем вопрос? задача решается, все хорошо!
derik вне форума  
 
Непрочитано 05.09.2010, 21:41
#33
aka raduntsev-nias

tester
 
Регистрация: 23.08.2008
Сообщений: 1,006


25 пост, дама хочет уйти от пилотных узлов
учебник в тему во вложении Александрова и Чебакова
учебник только что нашел в сети) может кому-то еще будет интересен
У Басова похожую задачу тоже наверное видели(SOLID95). Решается без пилотов.
вот еще

Последний раз редактировалось aka raduntsev-nias, 05.09.2010 в 22:41. Причина: орфография
aka raduntsev-nias вне форума  
 
Непрочитано 05.09.2010, 21:47
#34
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


ухты...не земетил
нужно попробывать, решить в 2Д, а там до трехмерки 1 шаг
будет время макрос напишу
derik вне форума  
 
Непрочитано 05.09.2010, 21:50
#35
aka raduntsev-nias

tester
 
Регистрация: 23.08.2008
Сообщений: 1,006


Offtop: ты уже вижу их штампуешь. переведи всю книжку в макросы)

Последний раз редактировалось aka raduntsev-nias, 05.09.2010 в 22:13.
aka raduntsev-nias вне форума  
 
Непрочитано 05.09.2010, 22:03
#36
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


Offtop:
Девушка, а у Вас есть гайд по контакту от кадфем?
derik вне форума  
 
Непрочитано 05.09.2010, 22:46
#37
aka raduntsev-nias

tester
 
Регистрация: 23.08.2008
Сообщений: 1,006


Брачо, попробуй дать похожие закрепления как в примере. У меня нессиметричный контакт решается комп висит
Точечные закрепления убрать из кода и все
все идеально просто

в эти минуты жалеешь. что плохо понимаешь в apdl
суть не понятна
что на что действует чтобы решить в wb
скорей всего и не только в apdl
эх. ладно. поработать и спать)
Вложения
Тип файла: pdf 123.pdf (349.0 Кб, 174 просмотров)

Последний раз редактировалось aka raduntsev-nias, 06.09.2010 в 15:16. Причина: узловые конечно. ) запарился с anys/ точки поверхности. так и говорю уже. исправил лексику)
aka raduntsev-nias вне форума  
 
Автор темы   Непрочитано 05.09.2010, 23:02 Вообще то двухмерная моделька у меня уже есть - если хотите я её выложу!
#38
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


1. Скажу честно Guide от CadFem это тупой перевод помощи Ансис
2. Все книги Александрова я хорошо знаю
3. Не точечные - а узловые.
4. У Басова видели, у него всё очень просто и потому грустно - у меня-то не так!
Цветочек вне форума  
 
Непрочитано 05.09.2010, 23:19
#39
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


через терми к звездам я тоже когда взялся за контакт - ужоснулся, а теперь все понятно, нужно только больше задач решать
а можно двумерный вариант Вашей задачи
будем грызть гранит контакта все вместе, смотри и найдем решение Вашей задачки
все завтра, сегодня спать. а завтра начну смотреть и прбывать решить задачку.
derik вне форума  
 
Непрочитано 06.09.2010, 00:29
#40
aka raduntsev-nias

tester
 
Регистрация: 23.08.2008
Сообщений: 1,006


код в студию. будем изучать apdl
workbench освобождает на это время

Последний раз редактировалось aka raduntsev-nias, 06.09.2010 в 00:59.
aka raduntsev-nias вне форума  
 
Автор темы   Непрочитано 06.09.2010, 16:24
#41
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Простите что задерживаю - были важные дела.
Оставляю все комментарии - ибо раз хотите изучить apdl - примеры самое то, пусть и неверные

Код:
[Выделить все]
/prep7
ex,1,1 ! модуль юнга 1 МПа
nuxy,1,0.3 ! коэффициент пуассона 0.3
et,1,82 ! элемент код 82
r=0.1 ! внутренний радиус верхнего цилиндра
dr=0.02 ! толщина - ?
k,1 ! 1 точка = координаты 0,0,0
k,2,r ! 2 точка = r,0,0
k,3,r+dr ! 3 точка r+dr,0,0
k,4,0,r ! 4 точка 0,r,0
k,5,0,r+dr ! 5 точка 0,r+dr,0
k,6,-r !  6 точка -r,0,0
k,7,-r-dr ! 7 точка -r-dr,0,0 ! здесь -r-dr - наружный диаметр 
k,8,0,-r ! 8 точка 0,-r,0
k,9,0,-r-dr! 9 точка 0,-r-dr
LARC,2,4,1,r, !1 кривая по 3 точкам и радиусу
LARC,4,6,1,r, 
LARC,6,8,1,r, 
LARC,8,2,1,r, 
LARC,3,5,1,r+dr, !5
LARC,5,7,1,r+dr, 
LARC,7,9,1,r+dr, 
LARC,9,3,1,r+dr, 
lstr,2,3 !9 ! прямая линия в глобальной системе координат - линия 9
lstr,4,5
lstr,6,7
lstr,8,9
al,1,10,5,9 ! площадь - четверть окружности малого вала 1 площадь
LESIZE,9,,,3,,,,,0 ! разбиваем линии с 9 по 12 на три участка - число ! элементов по толщине
LESIZE,10,,,3,,,,,0 
LESIZE,11,,,3,,,,,0 
LESIZE,12,,,3,,,,,0 
al,2,11,6,10 ! 2 площадь
al,3,12,7,11 ! 3 - - 
al,4,9,8,12 ! 4 - -
type,1 ! применяем элемент 82
real,1 ! реальные константы номер 1
mat,1 ! материал 1
MSHAPE,0,2D ! сетка из 4-угольников!
MSHKEY,1 ! mapped meshing
esize,0.01 ! характерный размер 1 элемента - 0.01
AMAP,1,2,3,5,4 ! mapped mesh площади 1 по угловым точкам 2,3,5,4
AMAP,2,5,4,7,6 !
AMAP,3,7,6,9,8 !
AMAP,4,9,8,3,2 !

ex,2,1! материал номер 2
nuxy,2,0.3 ! коэффициент пуассона номер 2
et,2,82 ! элемент 82 номер 2
r1=0.3 ! внешний диаметр нижнего цилиндра
dr1=0.02 ! толщина цилиндра
dy=-r-dr-r1-dr1 ! величина dy - межосевое расстояние между !верхним и нижним цилиндрами
k,11,0,dy ! центр нижнего цил коорд 0,dy,0
k,12,r1,dy ! далее и ниже прорисовка нижнего цилиндра
k,13,r1+dr1,dy
k,14,0,r1+dy
k,15,0,r1+dr1+dy
k,16,-r1,dy
k,17,-r1-dr1,dy
k,18,0,-r1+dy
k,19,0,-r1-dr1+dy
LARC,12,14,11,r1, !13 дуги окружности нижнего цилиндра
LARC,14,16,11,r1, 
LARC,16,18,11,r1, 
LARC,18,12,11,r1, 
LARC,13,15,11,r1+dr1, !17
LARC,15,17,11,r1+dr1, 
LARC,17,19,11,r1+dr1, 
LARC,19,13,11,r1+dr1, 
lstr,12,13 !21 прямые линии с 21 по 24 для указания количества слоев элементов по толщине
lstr,14,15
lstr,16,17
lstr,18,19
LESIZE,21,,,3,,,,,0 ! разбивка вышеперечисленных линий на 3 подлинии
LESIZE,22,,,3,,,,,0 
LESIZE,23,,,3,,,,,0 
LESIZE,24,,,3,,,,,0 

num=12 ! количество линий в верхнем цилиндре
al,num+1,num+10,num+5,num+9 ! создание 4 подобластей для слоя нижнего цилиндра 
al,num+2,num+11,num+6,num+10
al,num+3,num+12,num+7,num+11
al,num+4,num+9,num+8,num+12
type,2 ! тип элементов теперь 2 - реальные константы 2 материал 2 
real,2
mat,2
MSHAPE,0,2D  ! сетка 4-угольников
MSHKEY,1 ! mapped meshing
esize,0.01 ! характерный размер элемента 0.01
AMAP,5,12,13,15,14 ! mapped meshing всех 4-подобластей нижнего цилиндра
AMAP,6,15,14,17,16 
AMAP,7,17,16,19,18 
AMAP,8,19,18,13,12 
!!!!!!!!!!!!! внеконтактная геометрия, сетка и элементы с материалами !созданы
!!!!!!! создание первой контактной пары - верхний цилиндр - между жестким валом и покрытием
mat,3 ! материал 3 не создан но мы все равно его используем что отвлеч ансис
ET,3,TARGE169 ! элемент типа недеформируемая цель
KEYOPT,3,2,1 ! граничные условия для этого элемента будут задаваться пользователем
type,3
R,3,r,0, ! радиус цели r
real,3 
tshap,circ  ! определяем форму поверхности цели
n,100000, ! узел с номером 100000 имеет координаты 0,0,0
en,100000,100000 ! задаем элемент circ номера 100000 вида цель с узлом 100000 центре верхнего
TSHAP,PILO ! создаем мастер узел
En,100001,100000 ! элемент 100001 pilot создаем с узлом в центре верхнего 
et,4,CONTA172 ! декларируем элемент вида контакт 172
KEYOPT,4,12,5 ! он всегда будет always bonded
type,4
real,3! используем  реальные константы номер 3
lsel,s,,,1,4 ! выбираем линии с 1 по 4 
nsll,s,1! выделяем там все узлы
esurf  ! покрываем все выделенные  узлы контактными элементами
allsel,all ! выделяем все!
! создание второй контактной пары -нижний цилиндр - между жестким валом и покрытием
mat,5 ! материал номер 5
ET,5,TARGE169 ! элемент 5 - недеформируемая цель
KEYOPT,5,2,1 ! граничные условия задает пользователь
type,5
R,5,r1,0, ! радиус поверхности цели - мишени
real,5
tshap,circ ! задаем форму поверхности цели
n,100010,0,dy ! создать узел номером 100010 с координатами 0,dy,0
en,100010,100010! создать элемент типа цель номером 100010
TSHAP,PILO  ! создаем мастер-узел
En,100011,100010 ! создание элемента 100011 с мастер-узлом
et,6,CONTA172 ! элемент вида conta172
KEYOPT,6,12,5  ! этот контактный элемент будет always bonded
type,6 ! создаем теперь контактные элементы
real,5 ! реальные константы номер 5 
lsel,s,,,num+1,num+4! выделяем линии с 13 по 17
nsll,s,1 ! выделяем все узлы на выделенных линиях
esurf ! покрываем эти узлы контактными элементами
allsel,all ! выделяем все!
! контактные пары отвечающие за внутренние контакты - между слоями и жесткими валами созданы
! Создание контактной пары для контакта двух слоев!
MU,7,0.95 ! создаем седьмой материал к коэффициентом трения 0.8
mat,7 ! задаем этот самый 7 материал
ET,7,TARGE169 ! используем элемент типа деформируемая цель - мишень
type,7
real,7! реальные постоянные номер 7
r,7 ! реальные постоянные 7
RMODIF,7,13,0.0002 !меняем множество реальных постоянных 7, а именно 13 постоянную - cohe = 0.0002 
lsel,s,,,5,8! выделяем  кривые с 5-8 - внешний круг верхнего цилиндра
nsll,s,1! выделяем все узлы
esurf  ! покрываем элементами target169
et,8,CONTA172 ! 8 вид элемента - conta172
KEYOPT,8,4,2 ! Location of contact detection point : On nodal point - normal to target surface
KEYOPT,8,10,5 ! Contact stiffness update : Each iteration based on current mean stress of underlying elements ! (individual element based).
KEYOPT,8,2,3 ! Contact algorithm : Lagrange multiplier on contact normal and penalty on tangent
type,8
real,7
lsel,s,,,num+5,num+8 ! выделяем линии с 17 по 20 -  внешние линии нижнего цилиндра
nsll,s,1 ! выделяем все узлы на выделенных кривых
esurf ! покрываем их все контактными элементами
allsel,all ! выделяем все!
! блок решения
/solu
CNVTOL,U,1,0.0001,2,  ! определить сходимость по перемещениям, точность 0.01%, норма сходимости L2 
deltim,0.1,0.1,0.1 ! шаг решения 0.1 - очень быстрое решение
time,1 ! время идет до 1 
nlgeom,on ! включить нелинейные геометрические величины - большие перемещения и вращения
d,100000,ux ! запретить узлу 100000 перемещения по x
d,100000,uy,-0.1*dr ! задать узлу 100000 перемещения по y вниз на !0.1*dr - верхний цилиндр
d,100000,rotz,0 ! вращение узла 100000 невозможно
d,100010,ux ! закрепить центральный узел нижнего цилиндра по x
d,100010,uy,0.0 ! закрепить центральный узел нижнего цилиндра по y
d,100010,rotz,0 ! нижний цилиндр не вращается
solve ! решаем статическую задачу - вращения нет
Цветочек вне форума  
 
Автор темы   Непрочитано 07.09.2010, 18:04 Уф
#42
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Бра40 - Вы рано расстраиваетесь - Слава Богу! Здесь нету никаких сил кориолиса и так далее - у меня эти самые цилиндры не вращаются, это просто задача Герца в чистом виде! Просто она большая и всё
Цветочек вне форума  
 
Непрочитано 07.09.2010, 18:11
#43
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


да не расстраиваюсь я если задача Герца тада я в теме, а если добавлять вращение...тут нада хелпа почитать :-)
Вы же написали в макросе: что решение есть, а вот вращения нет!
derik вне форума  
 
Автор темы   Непрочитано 07.09.2010, 18:13
#44
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Я написала для себя что запрещаю вращение по rotz - как факт чтобы не было наклонов. ТАМА НЕТУ ВРАЩЕНИЯ! Я ж писала чтобы себя успокоить!
Цветочек вне форума  
 
Непрочитано 07.09.2010, 18:23
#45
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


писали для себя а не понял я хD
derik вне форума  
 
Автор темы   Непрочитано 07.09.2010, 18:30 Как многого я хотела!
#46
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Тут вот в чём дело! Я изначально задумывала и вращение делать, но только когда смогу решить задачу Герца в статитке, но поскольку у меня даже статика обламилась, то о какой динамике думать?
Цветочек вне форума  
 
Непрочитано 07.09.2010, 18:58
#47
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


так пойдет?
(эт набросал на скрорую руку)
Код:
[Выделить все]
fini
/clear,nostart
/outp,outfile,txt,C:\ansys\output
/cwd,'C:\ansys\out'

t=.05 ! поставте значение которое нужно
t1=.05 ! поставте значение которое нужно
r=.3 ! поставте значение которое нужно
r1=.3 ! поставте значение которое нужно
a=r+r1 ! поставте значение которое нужно
p=5e2 ! поставте значение которое нужно

/prep7

et,1,183

mptemp,,,,,,,
mptemp,1,0
mpdata,ex,1,,2.06e8
mpdata,prxy,1,,.3

pcirc,r,r-t,270,450,
pcirc,r1,r1-t1,270,450,
agen,,2,,,,-a,,,,1

mshkey,1
mshape,2,2d
esize,t/4
amesh,all

kref,6,,,1,2,,
kref,1,,,1,2,,

et,2,169
et,3,172
keyopt,3,2,1
keyopt,3,5,1
keyopt,3,9,3
keyopt,3,10,5
keyopt,3,12,5
mp,mu,3,.3

mat,3
real,3

type,2
lsel,s,,,5
nsll,s,1
esln
esurf
type,3
lsel,s,,,1
nsll,s,1
esln
esurf
!cncheck,auto

lsel,s,,,3,7,4
dl,all,,all
lsel,s,,,2,8,2
dl,all,,symm
allsel,all
fini

/sol

/gst,1
antype,0
nlgeom,1
nsubst,50,1000,20
outres,erase
outres,all,all
time,1

solve
fini
/post1
set,first
/expand,2,rect,half,.00001

Последний раз редактировалось derik, 07.09.2010 в 21:21.
derik вне форума  
 
Автор темы   Непрочитано 08.09.2010, 01:35
#48
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Спасибо за поддержку, Бра4о! Я посмотрю ваш код
Цветочек вне форума  
 
Непрочитано 08.09.2010, 14:16
#49
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


Код:
[Выделить все]
fini
/clear,nostart
/outp,outfile,txt,C:\ansys\output
/cwd,'C:\ansys\out'

r=.03 ! поставте значение которое нужно
r1=.09 ! поставте значение которое нужно

/prep7

et,1,183

mptemp,,,,,,,
mptemp,1,0
mpdata,ex,1,,7e8
mpdata,prxy,1,,.3

cyl4,,r,r,270,,450,
cyl4,,-r1,r1,270,,450

mshkey,0
mshape,2,2d
esize,r/7
amesh,all

kref,5,,,2,3,,
kref,1,,,2,3,,

et,2,169
et,3,172
keyopt,3,2,1
keyopt,3,5,1
keyopt,3,10,5
mp,mu,3,.3
r,3,0,0,11,0,0,40

mat,3
real,3
type,2
lsel,s,,,4
nsll,s,1
esln
esurf
type,3
lsel,s,,,1
nsll,s,1
esln
esurf
!cncheck,auto

ksel,s,,,3,6,3
dk,all,,,,,,all,
lsel,s,,,2,3
lsel,a,,,5,6
dl,all,,symm
allsel,all
fini

/sol

/gst,1
antype,0
nlgeom,1
nldiag,nrre,on
nropt,unsym,,on
nsubst,50,5000,10
deltim,0.1,0.1,0.1
outres,erase
outres,all,all
time,1

solve
fini
/post1
set,first
/expand,2,rect,half,.00001
а вот если два цилиндра
derik вне форума  
 
Автор темы   Непрочитано 08.09.2010, 22:31 Благодарствую за помощь!
#50
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Спасибо Вам бра4о большое! К сожалению то, что вы написали лишний раз подтверждает что свои ошибки каждый должен исправлять сам. К сожалению, я еще свои не исправила.
Всё же придется мне искать ошибки в переходе от 2-d примера в 3-d ситуацию - где колёса почему-то кривятся.
Цветочек вне форума  
 
Непрочитано 08.09.2010, 23:00
#51
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


:-) контакт решен же...а по поводу кручения - команда omega и cnomega...большим помочь не могу :-(
derik вне форума  
 
Непрочитано 10.09.2010, 15:03
#52
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


Цветочек, как там дела у Вас? что нибудь помогло?
derik вне форума  
 
Автор темы   Непрочитано 10.09.2010, 23:36 Приветик бра4о
#53
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


У меня к сожалению начался рабочий год с 1 сентября, поэтому не могу полностью отдать себя решению этой проблемы. Нет, практически ничего не помогло
Цветочек вне форума  
 
Непрочитано 19.09.2010, 21:39
#54
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


Цветочек, а Вы не пробывали добавить плотность материалу и приложить команду омега?
derik вне форума  
 
Автор темы   Непрочитано 19.09.2010, 22:13 А зачем?
#55
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Нет ли тут мании по поводу вращения? Уже устала уверять что вращения нету - просто сложный контакт - конечно можно добавить нулевое вращение и плотность, и ?
Вы наверное думаете что раз я так хочу пилотные узлы значит хочу вращать? Нет, вращать не хочу. Хочу задавать контакт через перемещения колёс
Цветочек вне форума  
 
Непрочитано 19.09.2010, 23:22
#56
derik

Конструякер
 
Регистрация: 27.07.2009
Подмосковье
Сообщений: 583
Отправить сообщение для derik с помощью Skype™


чтобы получить результат нужно смоделировать вращение валов и получим напряжения в точке соприкосновения.
в покое правильного результата не будет...цилиндры, даже в двумерке должны крутиться.
вращение - запрещаете перемещения по y, раздвигаете колеса и по x задаете перемещения друг к другу. либо одно колесо жестко закрепляете и приближаете второе, опять по x:
asel,s,,,nA
da,nA,ux,1(-1)
derik вне форума  
 
Автор темы   Непрочитано 19.09.2010, 23:41 Уф
#57
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


У меня и в статике не работает эта задача - в 2-d всё крутиться , но только всё плохо крутиться нельзя в ансис смоделировать качение - то есть процессы трения при качении и соответственно нельзя получить верное НДС в месте контакта
Поэтому забудьте про качение - я его сделала в 2-d и всё неверное.
Давайте просто оставим качение, меня сейчас это уже не трогает - я сделала это другим методом. Но вот расчётная схема про пилоты и два колеса всё еще нужна - правда без вращения. Поверьте мне Бра4o. Если вы озаботитесь кодом на 3 странице наших разговоров и поможете мне понять почему пилоты неверно работают я правда буду счастлива .
А если вам просто интересно как можно задавать вращение, могу помочь - d,pilot node, rotz,1 радиан

Последний раз редактировалось Цветочек, 19.09.2010 в 23:47.
Цветочек вне форума  
 
Автор темы   Непрочитано 03.10.2010, 15:38 Определение длины кривой линии контакта
#58
Цветочек


 
Регистрация: 29.03.2009
Сообщений: 38


Кое что написала - может и неплохо - в любом случае поправите если надо
Эти строки определяют ширину площадки контакта - работает с элементами 171, 172. С 175 не работает.
Надеюсь всем пригодиться! как и мне
Код:
[Выделить все]
/post1
allsel,all
lengs=0
ereal=2
*get,nodmax,elem,,num,max
*do,i,1,nodmax,1
*GET,elemstype,ELEM,i,ATTR,ENAM
  *if,elemstype,eq,172,then
    elemstype=0
    *GET,realelem,ELEM,i,ATTR,REAL
      *if,realelem,eq,ereal,then
           realelem=0     
        *GET,flag1,NODE,nelem(i,1),CONT,STAT
        *GET,flag2,NODE,nelem(i,2),CONT,STAT
           *if,flag1+flag2,ge,4,then 
             flag1=0
             flag2=0      
             delta1=0
             *GET,delta1,ELEM,i,LENG 
              *status,i
              lengs=lengs+delta1
          *endif
       *endif
   *endif
*enddo
 *status,lengs

Последний раз редактировалось Цветочек, 11.10.2010 в 14:26.
Цветочек вне форума  
Ответ
Вернуться   Форум DWG.RU > Программное обеспечение > Расчетные программы > ANSYS > Пара вопросов по контактным задачам Ansys

Размещение рекламы
Опции темы Поиск в этой теме
Поиск в этой теме:

Расширенный поиск


Похожие темы
Тема Автор Раздел Ответов Последнее сообщение
несколько вопросов по пострпоцессору ANSYS Mechanical autocader ANSYS 17 22.06.2010 21:37
К проектировщикам по водоотводу, водопроводу, канализации есть пара вопросов. FRAER Водоснабжение и водоотведение 20 04.02.2010 15:15