[metalirk]

В схеме нелинейный бетон (65), нелинейная арматура (8), линейный композит (46) и нелинейные связи между ними (39). Без композита и связей решается, солюшн дон, как говорится. Добавляю их - никак. Подскажите какие параметры решения выбрать и чем еще можно "вылечить" такую систему. Я не мудрствуя лукаво как-то так делал:

Код:

[Выделить все]

CNVTOL,F,,0.5 !Контроль по F
TIME,1   !Время
NSUBST,100,,,1 !подшаги
AUTOTS,ON !таймспэйс автоматом
LNSRCH,1 !поиск линейный
NEQIT,20 !итераций 20
PRED,ON   !прогноз вкл
NLGEOM,ON !большие перемещения вкл
OUTPR,ALL,ALL 
OUTRES,ALL,ALL 
ALLS   
SOLVE

Потом перечитав форум еще так пробовал:

Код:

[Выделить все]

ANTYPE,STATIC			! тип анализа – статический
AUTOTS,ON				! Авто таймстеппинг
OUTRES,ALL,all
NROPT,unsym,,on!	Ньютон-Рафсон несимм решатель	 с прогноз-коррекцией
LNSRCH,ON!		линейный поиск
cnvtol,f,,.50!невязка контролируется только для сил и приближенно
NLGEOM, OFF		
nldiag,nrre,on
cutcontrol,noshape,1!		отказ от контроля искажения формы
cutcontrol,plslimit,1.0!
nsubst,50,1000000,50
NSUBST,20,,	!		шагов побольше
NEQIT,20		! число итераций на шаге поменьше
	TIME,100!		время в тоннах
	SOLVE

[СергейД]

узнаю свой почерк...
только отчего отключили большие перемещения
и поставили nsubst,20 что отключило предшествующее число шагов и
главное, возможность их сгущать.
рисуйте невязки. увидите
не видя задачи подсказывать невозможно.+ мне крайне некогда.
вывесьте фрагмент оутпут-файла. может быть посоветую.
там наверняка есть намеки.попробуйте разобраться.

[Graf Kim]

Скажите, а команда cnvtol,f,,.50 какой смысл в себе несёт? Мы загрубляем контроль по силовому критерию до 50%? Я надеюсь, что ошибаюсь, но по умолчанию там стоит контроль SRSS. Если мне мой маразм не изменяет - это среднеквадритичная величина. Если я правильно понимаю, то получается такая картина: средний квадрат ошибки по всем элементам составляет 50%. Я не прав?

ps Прошу прощения за ещё один дурацкий вопрос, но какой смысл несёт в себе поле value той же команды? Это typical reference value. Как простому пользователю оценить это typical значение? Этим полем пользуются?

[Фролов Дмитрий]

50% здесь значит, что при проверке невязки по силе, внутренние силы могут отличаться от внешних на 50%. т.е. решатель будет считать это равновесием. По умолчанию стоит 0.5%
Value - это значение в явном виде, в Ньютонах

[metalirk]

Экспериментировал с шагами и итерациями - не помогло, по результатам аутпута разобраться пока тоже не получается. Конечный результат постарался гармонизировать, так сказать, с теми примерами, что тут уже обсуждались. Предупреждения выдает по поводу а) Контроля формы элементов с толщиной 0,167мм б) После объединения узлов (балки и опор) остались узлы, которые не принадлежат линиям. Думаю на результате это не сказывается, исправлю в будущем, когда основные проблемы решу. Вот аутпут и кривые решения. Буду благодарен за любой совет:

Код:

[Выделить все]

/clear,start
/COM,GASU
/PREP7
/TITLE, beamCFRP
ANTYPE,STATIC! тип анализа – статический
/UNITS,SI
/OUTPUT,beamCFRP,out

l=2.3				! Длина 
h=0.22				! Высота 
b=0.12				! Ширина 
c=0.575			! Проекция накл. трещины
sh_f_v=h+0.04			! Высота балки+толщина пластины
a_s1=0.03			! Толщина защитного слоя снизу/сверху
a_sb=0.03			! Толщина защитного слоя сбоку
A_s=1.539E-4			! Площадь нижней рабочей арматуры в м2
A_s_str=0.785E-4		! Площадь верхней арматуры в м2
A_sw=0.2827E-4		! Площадь поперечной арматуры в м2


ET,1,SOLID65			! тип элемента – солид65(бетон)
R,1                 			

ET,2,LINK8                  		! тип элемента – линк8 (арматура)
R,2,A_s                     		! площадь арматуры продольной нижней
R,3,A_s_str			! площадь арматуры продольной верхней
R,4,A_sw			! площадь арматуры поперечной

ET,3,SOLID45			  ! тип элемента – солид45(ОПОРЫ)
R,5

ET,4,SOLID46
ET,5,COMBIN39
Keyopt,5,1,0
Keyopt,5,2,0
Keyopt,5,4,3 
Keyopt,5,6,0 ! (1) 0-разгрузка вдоль той же кривой, (2) 0 – сжатие определяется кривой сжатия, (4) 1 – 2d элемент со степенями свободы ху, (6) выводить кривые load-defl для каждого элемента
R,7,0.0,0.0,1.0,600E+8,.1, 20.4E+8,.2, 43.2 E+8
RMORE,.3, 70.8 E+8,.4,105.6 E+8,.5,150 E+8
RMORE,.6,206.4 E+8,.7,277.2 E+8,.8,364.8 E+8
RMORE,.9,471.6 E+8

E_x_s=1.87E11			! Модуль упругости стали продольной арматуры
E_x_sw=2.1E11			! Модуль упругости стали поперчной арматуры
E_x_f=2.31E11 			! МУ пленки по х
E_y_f=0.0038E11			! МУ пленки по y
E_z_f=0.0038E11			! МУ пленки по z

MP,EX,1,3.3E10
MP,PRXY,1,0.3
TB,CONCR,1 
TBTEMP,0
TBDATA,,0.9,1,3.46E6,-1
!Продольная арматура:
MP,EX,2,E_x_s              	! материал, линейный, 2(сталь), модуль упругости
MP,NUXY,2,0.3	     	!коэф пуассона
TB,kinh,2,1,3
tbpt,defi,0.0031/2,29E7
tbpt,defi,0.0031,58E7
tbpt,defi,0.02,58E7
! Свойства поперечной арматуры
MP,EX,3,E_x_s                 	
MP,NUXY,2,0.3
TB,BISO,3
TBDATA,1,2.5E08
TBDATA,2,1.45E09

MP,EX,4,E_x_s                 	! Пластины (опоры, приложение нагрузки)
MP,NUXY,4,0.3
		!пленка
MP,EX,6, 62E+09
MP,EY,6, 4.8E+09
MP,EZ,6, 4.8E+09
MP,NUXY,6,0.017032
MP,NUXZ,6, 0.017032
MP,NUYZ,6,0.3
MP,GXY,6, 1.31E+09
MP,GXZ,6, 1.97E+09
MP,GYZ,6,1.85E+09
Keyopt,4,1,0
Keyopt,4,2,0
Keyopt,4,3,0
Keyopt,4,5,1 ! Использовать напряжения как
Keyopt,4,6,0 !критерий прочности
Keyopt,4,9,1 ! Напряжения  и деформации с поверхностей слоя
!RC пленки
R,6,1,1,1,1,, 
RMORE,0,,,,, 
RMORE,6,0,0.000167 
! Создание модели
! Продольная арматура
		!Нижняя
*GET,num,kp,,NUM,MAX
TYPE,2				! Тип элемента
MAT,2				! Материал
REAL,2			! Выбор р.к.
K,num+1,0,a_s1,a_sb		!Кейпойнты
K, num+2,l, a_s1,a_sb
L, num+1, num+2
K, num+3,0,a_s1,b-a_sb		!Кейпойнты
K, num+4,l, a_s1,b-a_sb
L, num+3, num+4
		        ! Верхняя
*GET,num,kp,,NUM,MAX
REAL,3			! Выбор р.к.
K, num+1,0,h-a_s1,a_sb
K, num+2,l,h-a_s1,a_sb
L, num+1, num+2
K, num+3,0,h-a_s1,b-a_sb
K, num+4,l,h-a_s1,b-a_sb
L, num+3, num+4
allsel
		 ! Мешинг продольной арматуры
MSHKEY,1
MOPT,QMESH,MAIN
LSEL,S,LINE,,1,4,1,1		! Выбор линий для применения параметров мешинга
LESIZE,ALL,0.03,,,,,,1		! Задание шага для мешинга
REAL,2			! Выбор р.к.
LMESH,1,2,1			! Мешинг нижней арматуры
REAL,3			! Переход к 3й р.к.
LMESH,3,4,1			! Мешинг верхней арматуры



! Создание бетонных блоков
*GET,num,kp,,NUM,MAX

TYPE,1				! Задание элемента, материала и констант
MAT,1
REAL,1

k,num+1,0,0,0			! Кейпойнты для поперечного сечения
k, num+2,0,h,0
k, num+3,0,0,b
k, num+4,0,h,b
a, num+1, num+3, num+4, num+2			! Плоскость для экструзии
allsel
asel,s,,,1			! Выбор плоскости для экструзии
vext,all,,,l			! Экструзия по выборке на 2.3м

MSHKEY,1				! Тип мешинга - mapped
MOPT,QMESH,MAIN			! Опции мешинга - четырехугольный
ESIZE,0.03				! Размер границы элемента для мешинга
	! Мешинг бетона
TYPE,1					! Параметры элементов и материалов
MAT,1
REAL,1
VMESH,1,1,1				! Мешинг бетона


! Поперечная арматура
TYPE,2
MAT,3				! Переход на сталь поперечной арматуры
REAL,4			! Переход к р.к.  поперечной арматуры
		! Создание линий поперечной арматуры
*GET,num,kp,,NUM,MAX
*DO,I,1,5
REAL,4
num=num+1
K,num,0.02+(i-1)*0.12,a_s1,b-a_sb
num=num+1
K,num,0.02+(i-1)*0.12,h-a_s1,b-a_sb
L,num-1,num
*ENDDO
*GET,num,kp,,NUM,MAX
*DO,I,1,5
REAL,4
num=num+1
K,num,0.02+(i-1)*0.12,a_s1, a_sb
num=num+1
K,num,0.02+(i-1)*0.12,h-a_s1, a_sb
L,num-1,num
*ENDDO
*GET,num,kp,,NUM,MAX
*DO,I,1,5
REAL,4
num=num+1
K,num,l-0.02-(i-1)*0.12,a_s1,b-a_sb
num=num+1
K,num,l-0.02-(i-1)*0.12,h-a_s1,b-a_sb
L,num-1,num
*ENDDO
*GET,num,kp,,NUM,MAX
*DO,I,1,5
REAL,4
num=num+1
K,num,l-0.02-(i-1)*0.12,a_s1, a_sb
num=num+1
K,num,l-0.02-(i-1)*0.12,h-a_s1, a_sb
L,num-1,num
*ENDDO


*GET,numl,line,,NUM,MAX
numm=numl-19
		! Мешинг поперечной арматуры
LSEL,S,LINE,,numm,numl,1,1		! Выбор линий для применения параметров мешинга
LESIZE,ALL,0.02,,,,,,1		! Задание шага для мешинга
LMESH,numm,numl,1			! Мешинг

LSEL,S,LINE,,ALL		! Выбор всех линий
NSEL,S,NODE,,ALL		! Выбор всех точек
NUMMRG,NODE
NUMMRG,KP


!Секция merge
allsel,all
esel,s,ename,,65
esel,a,ename,,8
nsle,s,all
cpintf,all,0.01
allsel,all
NUMMRG,NODE
NUMMRG,KP

! пленка
*GET,num,kp,,NUM,MAX

TYPE,4				! Задание элемента, материала и констант
MAT,6
REAL,6

k,num+1, 0.89610E-01,-0.01,0			! Кейпойнты для поперечного сечения
k, num+2, 0.89610E-01,-0.01,0.12
k, num+3, 0.89610E-01,-0.010167,0.12
k, num+4, 0.89610E-01,-0.010167,0

a, num+2, num+1, num+4, num+3			! Плоскость для экструзии

asel,s,,,7			! Выбор плоскости для экструзии
vext,all,,, 2.12079			! Экструзия по выборке на 2.16м

*GET,NMAX,NODE,,NUM,MAX
ALLSEL
n,nmax+1,1.15,0,0.06
n, nmax+2, 1.20,0,0.06
n, nmax+3, 1.15,0.05,0.06
n, nmax+4, 1.15,0,0.11

nc0=node(1.15,0,0.06)
ncx=node(1.20,0,0.06)
ncy=node(1.15,0.05,0.06)
ncz=node(1.15,0,0.11)
CS,11,0,nc0,ncx,ncy !перенос СК в середину балки
CSYS,11
CSYS,0
MSHKEY,1				! Тип мешинга - mapped
MOPT,QMESH,MAIN			! Опции мешинга - четырехугольный
ESIZE,0.03				! Размер границы элемента для мешинга
	! Мешинг пленки
*GET,VMAX,VOLU,,NUM,MAX
TYPE,4					! Параметры элементов и материалов
MAT,6
REAL,6
VMESH,vmax,vmax,1				! Мешинг пленки
ALLSEL

!Связь пленки и бетона

TYPE,5
				! Задание элемента, материала и констант


allsel,all
esel,s,ename,,65
esel,a,ename,,46
nsle,s,all
EINTF,0.015  !


!Пластины

	!Опора
*GET,num,kp,,NUM,MAX
K,num+1,0,0,0			! Кейпойнты
K, num+2,0,0,b
K, num+3,0,-0.04,0
K, num+4,0,-0.04,b
A, num+1, num+3, num+4, num+2			! Плоскость для экструзии

	! Сила
*GET,num,kp,,NUM,MAX

K, num+1, c-0.035,0+ sh_f_v,0		! Кейпойнты
K, num+2, c-0.035,0+ sh_f_v,b
K, num+3, c-0.035,-0.04+ sh_f_v,0
K, num+4,c-0.035,-0.04+ sh_f_v,b
A, num+1, num+3, num+4, num+2				! Плоскость для экструзии


ALLSEL
*GET,anum,area,,NUM,MAX

ASEL,s,,,anum-1,anum				! Выбор плоскости для экструзии
VEXT,anum-1,anum,1,0.07			! Экструзия по выборке на 7см

! Мешинг массивов
MSHKEY,1				! Тип мешинга - mapped
MOPT,QMESH,MAIN			! Опции мешинга - четырехугольный
ESIZE,0.01				! Размер границы элемента для мешинга
TYPE,3					! Параметры элементов и материалов
MAT,4
REAL,5
*GET,vnum,volu,,NUM,MAX
VMESH,vnum-1,vnum,1
ALLSEL
!отразить
CSYS,11
Numstr,node
VSYMM,X, vnum-1, vnum,1,0,,0,0
CSYS,0

!опора средняя

ALLSEL



!Опоры

*get,nmax,node,,num,max
*do,n,1,nmax
*get,a,node,n,loc,x
*get,b,node,n,loc,y
*if,a,eq,0.03,and,b,eq,-0.04,then
D,n,UY,0
D,n,UZ,0
D,n,UX,0
*endif
*enddo


*do,n,1,nmax
*get,a,node,n,loc,x
*get,b,node,n,loc,y
*if,a,eq,2.27,and,b,eq,-0.04,then
D,n,UY,0
D,n,UZ,0
*endif
*enddo

!Секция merge
allsel,all
esel,s,ename,,65
esel,a,ename,,45
nsle,s,all
cpintf,all,0.005
allsel,all
NUMMRG,NODE
NUMMRG,KP

allsel
! Секция нагрузок 
Fd=80000/13             !80кН - нагрузка/13 точек

*get,nmax,node,,count
NN=ndnext(0)
*do,i,1,nmax
*get,a,node,NN,loc,x
*get,b,node,NN,loc,y
*if,a,eq,0.58,and,b,eq,0.26,then
F,NN,FY,-Fd

*endif
NN=ndnext(NN)
*enddo

*get,nmax,node,,count
NN=ndnext(0)
*do,i,1,nmax
*get,a,node,NN,loc,x
*get,b,node,NN,loc,y
*if,a,eq,1.73,and,b,eq,0.26,then
F,NN,FY,-Fd
*endif
NN=ndnext(NN)
*enddo


/pnum,mat,1
/num,1
eplot

/outp,,outp
/pbc,u,,2


/solu
ANTYPE,STATIC			! тип анализа – статический
AUTOTS,ON
OUTRES,ALL,all
OUTPR,ALL	

NROPT,unsym,,on!	Ньютон-Рафсон несимм решатель	 с прогноз-коррекцией
LNSRCH,ON!		линейный поиск


cnvtol,f,,.50!невязка контролируется только для сил и приближенно
NLGEOM, ON	
nldiag,nrre,on
cutcontrol,noshape,1!		отказ от контроля искажения формы
cutcontrol,plslimit,1.0!
nsubst,50,1000000,50!		шагов побольше
NEQIT,7		! число итераций на шаге поменьше
	TIME,100!		время в тоннах
	SOLVE
FINISH

[Фролов Дмитрий]

подумайте над симметрией...тут как у Wolanski две плоскости

[Graf Kim]

Сообщение от Фролов Дмитрий 50% здесь значит, что при проверке невязки по силе, внутренние силы могут отличаться от внешних на 50%. т.е. решатель будет считать это равновесием. По умолчанию стоит 0.5% Value - это значение в явном виде, в Ньютонах

Ну вопрос сводится к следующему. Как я уже говорил, по умолчанию стоит контроль SRSS невязок. 50% среднего квадрата отклонения - это же очень много. Мне бы тут очень хотелось ошибится, но фактически это означает, что равновесия как такового в системе нет.
А что касается value - понятно, что не в герцах, вопрос по-другому звучал.

[metalirk]

Спасибо, подумаю. Когда начинал моделировать, читал что симметрия сокращает время счета и не более, а четверти балок моделировались на ПК 2000х годов, поэтому решил не заморачиваться...

[СергейД]

смотреть пока некогда. на работе свои задачи актуальны. а дома не до ансиса...

нарисуйте невязки. plnso,nrre
нарисуйте графики, анимацию, трещины. я так понял, вы этого не сделали.
может быть у вас правильно и вы достигли предельного состояния... (нирваны, так сказать)

разберитесь, где именно реализуется несходимость
без визуального анализа нельзя.
+если график обрывается будучи горизонтальным= надо смотреть невязки и ""облагораживать" (а не обязательно сгущать) сетку локально.
рисуйте анимацию трещин. разберитесь, где они возникают и почему.
если график перемещений резко пошел вверх (вниз),
если пластика в арматуре (рисовать ее нужно обязательно) появилась и растет,
если опоры окружены треснувшими элементами, значит > разрушение наступило.
к собственно расчету вопросов быть не должно. значит, такие уж х-ки и нагрузки заданы на входе.
не нравится результат= проверяйте их.

меня удивили большие невязки на первом шаге (2.0) уже при примерно 20% вашей предельной нагрузки (9.0). там уже нелинейность.
сколько вообще дает ручной счет или линейное решение?
вы должны были начинать c 5% или 10% от них. с тем чтобы минимум три шага были линейными и сходились бы за одну итерацию с минимальными невязками.
а у вас же критерий невязки 50% начинает учитываться уже на первой итерации. а не в процессе разрушения (где он нужен как своего рода подпорочка-мостик в сингулярностях)
в итоге уже первое решение- неточное. дальше ошибка накапливается.

вообще по поводу невязок. важно не сколько именно они, а где и на каком этапе нагружения.
srss накапливает основные значения в разрушившихся (треснутых) зонах.
и ставить критерием стандартным 0.05 на всех этапах непрактично. вы так не решите ни единой подобной задачи.

в общем> проверьте величину полной нагрузки или уменьшите начальный шаг раз в 10 минимум. программа сама его увеличит, если все пойдет гладко.

у вас в самом начале есть диагностика pivot . это значит, что появились локальные механизмы (например, разрушились элементы вокруг узла)
конечно, есть команда pivcheck,off
но применять ее лучше, лишь когда поймете, почему и где эти пивоты возникают.

симметрия позволяет достичь большей устойчивости численной процедуры и минимизирует паразитные эффекты при работе на пороге точности в практических задачах с неидеальной сеткой. + так проще назначать граничные условия.

ps
.
и я решил бы для начала = заменив тип46 (не применял никогда) на простой (45 однослой).
нужно убедиться, что не они причина. а уж потом двигаться дальше.
в 65 типе я ставлю опции 7и 8 (посмотрите в примере, что я выкладывал)= они помогают

в макросе упоминается тип 39, в output (где формирование матриц) его нет. ничего не потеряли?

ззы
у вас диагностик слишком много и они начали передаваться в *.err. что там, мне неизвестно.
установите в начале
/nerr,,1e6,1e6 (позиции по памяти) во избежание того.
исправьте все вышеуказанное и снова вывешивайте out.
или может быть разберетесь уже сами.

[Graf Kim]

Сергей, а под "облагораживать" подразумевается приведение элементов к хорошей форме?

[metalirk]

СергейД, большое спасибо! Применил, помогло. Проблема была в combin39 - нелинейной связи 46го и 65го, вылечилась упрощением его [39го] диаграммы. Плюс, пока моделировал четверть вместо полной балки, еще пару огрехов нашел.