[cnapta4ok]

Доброе время суток. У меня такая проблемка:
у меня около 200.000 точек в автокаде, которые имеют свои реальные координаты X,Y и высотное значение Z (одним словом значения глубин в морском порту). Как сделать, что бы вместо самих точек показывало только значения Z?

Извиняюсь, если это повтор. Просто в автокаде я новичок и еще толком ничего не умею.

[Disney]

1) Создать блок с полем, которое будет отображать Z координату этого блока
2) Воспользовавшись программой LISP. Замена набора примитивов на выбранный примитив заменить все точки на блок
3) Обновить поля _updatefield или выполнить регенерацию _regenall

[AlexV]

Ну, уже многое выкладывалось на эту тему... Если "на коленке", то вот:

Код:

[Выделить все]

Option Explicit
Public Const tpv = "" ' "Выбрать объекты"
Public Const heighttxt = 100
Sub main()
Dim pnt As Object
Dim acSelSet As AcadSelectionSet
Dim textObj As AcadText
Dim textString As String
Dim insertionPoint
Dim height As Double
height = heighttxt
Set acSelSet = SelectOnlyOnScreen(tpv)
If acSelSet.Count = 0 Then Exit Sub
For Each pnt In acSelSet
 insertionPoint = pnt.Coordinates
 textString = insertionPoint(2)
 Set textObj = ThisDrawing.ModelSpace.AddText(textString, insertionPoint, height)
Next
End Sub
Private Function SelectOnlyOnScreen(str) As AcadSelectionSet
Dim objSelSet As AcadSelectionSet
Dim objSelCol As AcadSelectionSets
Dim intType(0) As Integer
Dim varData(0) As Variant
Set objSelCol = ThisDrawing.SelectionSets
For Each objSelSet In objSelCol
 If objSelSet.Name = "Blck" Then
  objSelSet.Delete
  Exit For
 End If
Next
Set objSelSet = ThisDrawing.SelectionSets.Add("Blck")
intType(0) = 0
varData(0) = "Point"
If str = "Выбрать объекты" Then
  objSelSet.SelectOnScreen intType, varData
Else
  objSelSet.Select acSelectionSetAll, , , intType, varData
End If
Set SelectOnlyOnScreen = objSelSet
End Function

Макрос VBA ищет все точки и вставляет текст с z координатой точки. Константа heighttxt определяет высоту текста (можно подставить другое допустимое значение.). Если вместо Public Const tpv = "" вставить Public Const tpv = "Выбрать объекты", то обрабатываться будут точки по выбору рамкой..

[cnapta4ok]

большое вам спасибо