[swell{d}]

Вопрос в теме

Код:

[Выделить все]

for i=0 to ThisDrawing.ModelSpace.count-1
	set line = ThisDrawing.ModelSpace.Item(i)
	if (line.ObjectName = "AcDbFace") then
		ThisDrawing.Utility.Prompt ???
	end if
next

[Кулик Алексей aka kpblc]

Свойство Coordinates у 3DFACE есть?

[swell{d}]

http://entercad.ru/acadauto.en/idh_coordinates.htm

ещё бы кусочек кода

Offtop: яжнепрограммист

[trir]

Код:

[Выделить все]

Public Sub FindMyEntry(ByVal TableName, ObjName As String)
'Ищем в чертеже нужные графические примитивы и загружаем их
'координаты, в указаную таблицу БД
'Вход : Имя таблицы (TableName), Название примитива (ObjName)
'Выход: В таблицу БД

'Коментарий: Коодинаты примитивов хранятся в свойстве .Coordinates
'за исключением линии - у них два свойства .StartPoint и .EndPoint
'поэтому для линии координаты загружаем по особому
Dim MyRS As ADODB.Recordset 'Рабочий набор данных
Dim MyCoord() As Double 'Массив для хранения координат
Dim i, MyUp As Integer
 Set MyRS = OpenMyTable(TableName, 1) 'Открываем таблицу
 For Each Entry In ThisDrawing.ModelSpace
 'Перебираем все примитивы AutoCAD'а в текущем чертеже,
 'в пространстве модели
  If Entry.ObjectName = ObjName Then
  'Если текущий примитив нужный
   If ObjName = "AcDbLine" Then
   'Если нужный примитив линии
    Dim MyCoord1() As Double
    MyCoord = Entry.StartPoint ' Начальная точка
    MyCoord1 = Entry.EndPoint ' Конечная точка
    MyRS.AddNew 'Добавляем запись и записываем координаты
    For i = LBound(MyCoord) To UBound(MyCoord)
     MyRS.Fields(i + 1) = MyCoord(i)
     MyRS.Fields(i + 4) = MyCoord1(i)
    Next i
    MyRS.Update
   Else
    MyCoord = Entry.Coordinates ' Получаем координаты примитива
    MyRS.AddNew 'Добавляем запись и записываем координаты
    If ObjName = "AcDbFace" Then MyUp = 8 Else MyUp = UBound(MyCoord)
    For i = LBound(MyCoord) To MyUp
     MyRS.Fields(i + 1) = MyCoord(i)
    Next i
    MyRS.Update
   'MsgBox "Good"
   End If ' ObjName = "AcDbLine"
  End If ' Entry.ObjectName = ObjName
 Next   ' Entry In ThisDrawing.ModelSpace
 MyRS.Close
End Sub ' FindMyEntry

[swell{d}]

разобрался, спасибо!