[lobaskov]

Добрый день!
Делаю команды в экселе для последующей вставки в командную строку Автокад чтобы отрисовывал нужное. К примеру команда "Плиния 0,0 0,15 ", отрисовывает ее. Потом много таких значений в ячейках экселя копрую - вставляю в автокад и все ок. только вот с текстом немного сложнее. Помогите написать ни Лиспе либо просто с помощью команды Мтекст

[trir]

(command "_mtext" '(0 0) '(1 1) "test" "")

[Кулик Алексей aka kpblc]

ИМХО проще на лиспе сделать отдельную функцию по созданию многострочника со всеми настройками и ее вызывать по мере надобности.

[trir]

такой способ позваляет за пару кликов перекинуть большой объём данных из Excel'я в AutoCAD
а настроек обычно в Excel'е нет

[Сергей812]

Если акад не LT, то можно и через COM напрямую из экселя вставлять без промежуточных телодвижений - не обязательно лисп использовать)

[lobaskov]

Спасибо! Вот такая команда из экселя работает нормально в новом чистом листе:
(command "_TEXT" "_MC" '(0 0) 2.5 "90" "ПК1")\P
(command "_TEXT" "_MC" '(10 0) 2.5 "90" "ПК2")\P
А вот в этом файле почему то нет!
https://cloud.mail.ru/public/Eygp/kWday2bSg
Кто сможет помочь?

[Сергей812]

Если используете Excel, так используйте его нормально:

Область данных на листе экселя:

Текст | X | Y | Z | Height | Angle
Текст 1 | 10 | 20 | 0 | 2 | 0
Текст 2 | 10 | 40 | 0 | 2,1 | 45
Текст 3 | 10 | 60 | 0 | 2,2 | 90


и

Код:

[Выделить все]

' Вставка множества текстов из области данных листа Excel
Public Sub InsertText()
  On Error Resume Next
  ' Подключаемся к акаду
  Dim lAcadApp As Object
  Set lAcadApp = GetObject(, "AutoCAD.Application")
  If Err Then Exit Sub
  ' Получаем текущий документ
  Dim lAcadDoc As Object
  Set lAcadDoc = lAcadApp.ActiveDocument
  ' Получаем пространство моделей
  Dim lAcadMS As Object
  Set lAcadMS = lAcadDoc.ModelSpace
  ' Получаем массив данных с экселевского листа
  ' lInputSheet из именованного диапазона Data
  Dim lInputData As Variant
  lInputData = InputSheet.Range("Data")
  ' В цикле вставляем текст в акад
  Dim I1 As Long
  For I1 = 1 To UBound(lInputData, 1)
    ' Собираем координаты
    Dim lCoorD(2) As Double, lCoorV As Variant
    lCoorD(0) = lInputData(I1, 2)
    lCoorD(1) = lInputData(I1, 3)
    lCoorD(2) = lInputData(I1, 4)
    lCoorV = lCoorD
    ' Вставляем текст
    Dim lAcadText As Object
    Set lAcadText = lAcadMS.AddText(CStr(lInputData(I1, 1)), lCoorV, CDbl(lInputData(I1, 5)))
    ' Задаем угол поворота (преобразуем в радианы)
    lAcadText.Rotation = CDbl(lInputData(I1, 6)) * WorksheetFunction.Pi / 180
  Next I1
  ' Освобождаем объекты
  Set lAcadMS = Nothing
  Set lAcadDoc = Nothing
  Set lAcadApp = Nothing
End Sub

А с командными методами развлекайтесь сами, мне не интересно то - что вообще никак нельзя контролировать)