[Ifclissium]

Здравствуйте !

Есть ли способ создания связи между ячейками таблицы и выносками/текстом на чертеже , без СПДС? При этом нужно сохранить связь таблицы в Autocad с таблицей в Exel.
Возникла потребность "автоматизации" перебивания определенной информации на чертеже , без ручного переписывания 215 выносок, а лишь меняя таблицу в exel/autocad.

Как можно это сделать ?
Заранее спасибо!

[krok64]

Недавно решал такую же проблему. Я сделал так. Пусть у нас в экселе хранится спецификация, эта спецификация связывается с таблицей в автокаде. Правее от спецификации (в экселе) заводим столбец и называем его например TAG. В автокаде создаем динамический блок в виде выноски с 2 атрибутами: первый атрибут (NUM) это номер позиции как у обычной выноски, а второй атрибут пихаем на невидимый слой и называем его TAG. Проставляем эти новые выноски по всему чертежу, прописывая только TAG. В экселе также заполняем колонку TAG. Теперь пишем прогу которая будет читать экселевский файл и проставлять атрибут NUM в соответствии с атрибутом TAG.

[Ifclissium]

Сообщение от krok64 Недавно решал такую же проблему. Я сделал так. Пусть у нас в экселе хранится спецификация, эта спецификация связывается с таблицей в автокаде. Правее от спецификации (в экселе) заводим столбец и называем его например TAG. В автокаде создаем динамический блок в виде выноски с 2 атрибутами: первый атрибут (NUM) это номер позиции как у обычной выноски, а второй атрибут пихаем на невидимый слой и называем его TAG. Проставляем эти новые выноски по всему чертежу, прописывая только TAG. В экселе также заполняем колонку TAG. Теперь пишем прогу которая будет читать экселевский файл и проставлять атрибут NUM в соответствии с атрибутом TAG.

Есть туториал , как писать прогу ? я в программирование дно чуть меньше чем совсем .

[trir]

всё гораздо проще

я в программирование дно чуть меньше чем совсем

поиграй

[krok64]

Сообщение от Ifclissium Есть туториал , как писать прогу ? я в программирование дно чуть меньше чем совсем .

Наверно есть.
Вот код моей программы для примера.

Код:

[Выделить все]

Public Sub GetBlkRefs(strBlkName As String, objSelSet As AcadSelectionSet)
'  Dim objBlk As AcadBlock
'  Dim colBlks As AcadBlocks  AddCircle
'  Dim objBlkRefs As AcadBlockReference
  Dim varData(0) As Variant
  Dim intData(0) As Integer
  varData(0) = strBlkName
  intData(0) = 2
  objSelSet.Select acSelectionSetAll, , , intData, varData
End Sub

Public Function vbdPowerSet(strName As String) As AcadSelectionSet
  Dim objSelSet As AcadSelectionSet
  Dim objSelCol As AcadSelectionSets
  
  Set objSelCol = ThisDrawing.SelectionSets
  For Each objSelSet In objSelCol
    If objSelSet.Name = strName Then
      ThisDrawing.SelectionSets.Item(strName).Delete
      Exit For
    End If
  Next
  Set objSelSet = ThisDrawing.SelectionSets.Add(strName)
  Set vbdPowerSet = objSelSet
End Function

 
Public Sub ImportLeadersFromExcel()
  Dim objSS As AcadSelectionSet
  Dim objblkRef As AcadBlockReference
  Dim objExcel As Excel.Application
  Dim list As New Scripting.Dictionary
  Dim i As Integer, j As Integer, numbers As Boolean, value As String, key As String
  Dim varAtts As Variant, intCnt As Integer, intCnt2 As Integer, found As Boolean
  
  Const MAXROW = 1000
  Const MAXCOL = 256
  
  On Error GoTo Err_Control
  'Excel MUST be running for this sample
  Set objExcel = GetObject(, "Excel.Application")

  With objExcel
    'Ищем строку с надписью Поз. в первой колонке
    For i = 1 To MAXROW
        If .Cells(i, 1) = "Поз." Then
            Exit For
        End If
    Next i
    If i >= MAXROW Then
        MsgBox ("Откройте документ эксель с надписью Поз. в первой колонке")
        Exit Sub
    End If
    
    'в найденной строке ищем ячейку со значением TAG
    For j = 1 To MAXCOL
        If .Cells(i, j) = "TAG" Then
            Exit For
        End If
    Next j
    If j >= MAXCOL Then
        MsgBox ("Не найдена надпись TAG в одной строке с Поз.")
        Exit Sub
    End If
    
    While i < MAXROW
        i = i + 1
        If .Cells(i, j).value <> "" Then
            value = .Cells(i, 1).value
            key = .Cells(i, j).value
            If list.Exists(key) Then
                MsgBox ("В строке " + str(i) + " найден повторяющийся TAG")
                Exit Sub
            End If
            list(key) = value
        End If
    Wend
  End With
  
'  MsgBox (str(list.Count))
  
  Set objSS = vbdPowerSet("mdv3")
  
  GetBlkRefs "mdv,`*U*", objSS
  
'  MsgBox ("Найдено " & str(objSS.Count) & " блоков")
  
  For Each objblkRef In objSS
   If objblkRef.HasAttributes And objblkRef.EffectiveName = "mdv" Then
      varAtts = objblkRef.GetAttributes
      For intCnt = LBound(varAtts) To UBound(varAtts)
        If varAtts(intCnt).TagString = "TAG" Then
            For intCnt2 = LBound(varAtts) To UBound(varAtts)
                If varAtts(intCnt2).TagString = "NUM" Then
                    If list.Exists(varAtts(intCnt).TextString) Then
                        varAtts(intCnt2).TextString = list(varAtts(intCnt).TextString)
                    Else
                        varAtts(intCnt2).TextString = "TAG не найден"
                    End If
                    Exit For
                End If
            Next intCnt2
        End If
      Next
   End If
  Next objblkRef
  
Exit_Here:
  Exit Sub
Err_Control:
  MsgBox err.Description
  Resume Exit_Here
  
End Sub

[Ifclissium]

Сообщение от krok64 Наверно есть. Вот код моей программы для примера. [/code]

Программа должна быть - лиспом ?

[Кулик Алексей aka kpblc]

Раздел - "AutoCAD", а не "Программирование". Так что ищем и предлагаем штатные варианты!

[trir]

Программа должна быть - лиспом ?

почему?

[Ifclissium]

Сообщение от trir почему?

Как я ранее писала , я не разбираюсь в программирование. Я предположила что программа должна быть лиспом , ибо до этого применяла их в связке с кадом.

Но хотелось бы найти решение без программирования чего-то , может команда/набор команд какой есть ? или комбинация программ-лиспов?