[swell{d}]

я г..кодер, поэтому не ругайтесь сразу =)

у меня есть такой г..код для создания блока, причём он может вызываться несколько раз, а выполниться должен только один раз:

Код:

[Выделить все]

Sub st1()
    Dim item As AcadBlock, block_name As String
    block_name = "bla-bla"
    For Each item In ThisDrawing.Blocks
        If item.Name = block_name Then
            Exit Sub
        End If
    Next

    Dim block As AcadBlock, pt0(2) As Double
    Set block = ThisDrawing.Blocks.Add(pt0, block_name)
    'здесь создаём начинку блока
End Sub

я заметил, что цикл ооочень сильно подтормаживает всю программку в целом. стал разбираться, оказывается он перебирает вообще все блоки чертежа.
т.е. если у меня один и тот же блок вставлен 100500 раз, то программа перебирает 100500 элементов.
а мне-то достаточно проверить есть блок с таким названием или нет. как быть?

п.с. чтобы понимать всю степень моей "трудности" уточню - я пишу в экселе (vba) под нанокад через COM. связка эксель-нано тормозит прилично, поэтому стараюсь сократить количество обращений...

[Кулик Алексей aka kpblc]

Учитывая, что я не пишу на VBA, прошу не ругать за кривой код:

Код:

[Выделить все]

Option Explicit 

Public Function GetOrCreateBlockDef(BlockName As String) As AcadBlock
Dim res As AcadBlock
On Error GoTo lCreateBlockDef
  Set res = ThisDrawing.Blocks.Item(BlockName)
  GoTo lExit
lCreateBlockDef:
  Dim ptBase(2) As Double
  ptBase(0) = 0#: ptBase(1) = 0#: ptBase(2) = 0#
  Set res = ThisDrawing.Blocks.Add(ptBase, BlockName)
lExit:
  Set GetOrCreateBlockDef = res
End Function
 
'Проверка
Sub test()
Dim obj As AcadBlock
  Set obj = GetOrCreateBlockDef("test")
  MsgBox obj.Name
End Sub

[Дима_]

Сообщение от swell{d} заметил, что цикл ооочень сильно подтормаживает всю программку в целом. стал разбираться, оказывается он перебирает вообще все блоки чертежа. т.е. если у меня один и тот же блок вставлен 100500 раз, то программа перебирает 100500 элементов.

Может и перебирает, но точно не этот фрагмент - если только 100500 разных вариантов 1-го динамического блока, у Вас он пробегается только по описаниям блоков. Снаружи действительно COM API автокада тормозят жутко (работают внутри достаточно быстро - а само каждое обращение - занимает приличное время) - посему - в Вашем случае используйте Item (как и предложенно Крысом) с проверкой ошибок (внутри он сделает все то-же самое, вряд-ли блоки у него проиндексированны, но количество обращений будет 1, а не по кол-ву блоков. Хотя тот-же пример "изнутри" предпочтительно реализовать как у Вас - т.к. выполнить с контролем ошибок это не есть хороший метод по многим причинам, а на метод проверки наличия блока в коллекции автокад не осилил видимо).

[hwd]

Сообщение от swell{d} если у меня один и тот же блок вставлен 100500 раз, то программа перебирает 100500 элементов.

Значит ты, скорее всего, перебираешь вхождения блоков, а нужно перебирать их определения.
Offtop:

Сообщение от Дима_ Снаружи действительно COM API автокада тормозят жутко (работают внутри достаточно быстро - а само каждое обращение - занимает приличное время)

Хм... Интересно, а вот если (в качестве теста) в AutoCAD подгрузить плагин (серверная часть), ожидающий (в параллельном потоке) запрос на перечисление имён определений блоков, а во внешнем приложении набросать для этого сервера клиента и обратиться к серверной части за обозначенной информацией, то какова будет разница по скорости? Передачу данных выполнять через сокеты по протоколу TCP\IP.

[swell{d}]

Сообщение от hwd Значит ты, скорее всего, перебираешь вхождения блоков, а нужно перебирать их определения.

дык, объектная модель содержит только коллекцию всех блоков чертежа.
если есть коллекция определений - подскажите, как до неё достучаться.

идею Алексея понял, сейчас попробую.
на тему скорости, вот пример видео

[Дима_]

Сообщение от swell{d} если есть коллекция определений - подскажите, как до неё достучаться.

В Вашем примере Вы именно в нее и стучитесь.

[hwd]

Сообщение от Дима_ В Вашем примере Вы именно в нее и стучитесь.

Да, похоже на то.

[swell{d}]

Сообщение от Дима_ В Вашем примере Вы именно в нее и стучитесь.

хм, странно. так, надо поразбираться...

добавлено:
эм. я нахожусь в некотором замешательстве. проблема вот в чём. при добавлении в чертёж одного повёрнутого размера в коллекцию блоков добавляются 2 новых объекта.
я не знаю бага это или фича, и относится ли она только к нанокаду, или в акаде так же, но суть, что количество записей в коллекции блоков значительно больше, чем их фактическое количество.
и что самое забавное, после удаления размеров, записи всё равно остаются, а "пурге" не помогает.

[Дима_]

Сообщение от hwd Хм... Интересно, а вот если (в качестве теста) в AutoCAD подгрузить плагин (серверная часть), ожидающий (в параллельном потоке) запрос на перечисление имён определений блоков, а во внешнем приложении набросать для этого сервера клиента и обратиться к серверной части за обозначенной информацией, то какова будет разница по скорости? Передачу данных выполнять через сокеты по протоколу TCP\IP.

Из паралельного потока обратится можно только к "свободному" автокаду, при достаточном количестве блоков разница будет существенной:
Внешние обращение F#:
> acad.ActiveDocument.Blocks.Count;; //получает количество через свойство Count
Real: 00:00:00.002, CPU: 00:00:00.000, GC gen0: 0, gen1: 0, gen2: 0
val it : int = 1005
> seq {for x in acad.ActiveDocument.Blocks->x}|>Seq.length;; //то же самое но пробежкой по коллекции снаружи
Real: 00:00:04.072, CPU: 00:00:01.747, GC gen0: 0, gen1: 0, gen2: 0
val it : int = 1005
> seq {for x in acad.ActiveDocument.Blocks->x.Name}|>Seq.length;; // + еще получает имена с этих-же объектов
Real: 00:00:05.818, CPU: 00:00:01.716, GC gen0: 0, gen1: 0, gen2: 0
val it : int = 1005

Этот же сеанс из самого автокада через тот же ActiveX - лиспом:

Команда: (defun coll->list (obj / ret) (vlax-for x obj (setq ret (cons x ret))) (reverse ret))
COLL->LIST

Команда: (length (coll->list (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))))
1005 // - это количество

Команда:
((lambda (cd)
(length (coll->list (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))))
(- (getvar "cdate") cd))
(getvar "cdate"))
3.72529e-009 // время в сутках (в F# в секундах) - то есть достаточно быстро с учетом что еще список переворачивали (что для данного действия не нужно) и это интерпритатор.
В общем за это время можно и по ком-порту успеть отослать.

[Boxa]

Я с vba давно не работал, там разве нет что то на подобии

Код:

[Выделить все]

Dim coll As New Collection
If coll.Contains("block_name") = True Then
End If

[Олег (jr.)]

Попробуй так, не будет быстрее?

Код:

[Выделить все]

'' by Dick Kusleika http://dailydoseofexcel.com/
Public Function BlockExists(blockName As String) As Boolean
Dim blkDef As AcadBlock
On Error Resume Next
Set blkDef = ThisDrawing.Blocks(blockName)
BlockExists = (Err.Number = 0)
End Function

[swell{d}]

ну примерно так и сделал:

Код:

[Выделить все]

Sub st1()
    On Error GoTo ErrorHandler
    Dim block_name As String
    block_name = "bla-bla"
    Dim tmp_block As IAcadBlock
    Set tmp_block = ThisDrawing.blocks.item(block_name)
Exit Sub
ErrorHandler:
    Select Case Err.Number
        Case -2145386470
            Dim block As IAcadBlock, pt0(2) As Double
            Set block = ThisDrawing.blocks.Add(pt0, block_name)

'здесь начинка блока

    End Select
End Sub

стало заметно бодрее отрисовываться

[Олег (jr.)]

Потому что выражение:
ThisDrawing.blocks.item(block_name)
сразу определяет наличие блока в таблице BlockTable

[p_sh]

нужно name добавить
b_string = ThisDrawing.Blocks.Item("blname").name

[swell{d}]

куда чего зачем добавить?