[diesel-generator]

Подскажите пожалуйста как выполнять расчеты на устойчивость стальных конструкций в программе Ansys.

[ETCartman]

Материалы по Ansys
Расчет по деформированной схеме (тестовый пример)
Расчет по деформированной схеме - это способ точно смоделировать потерю устойчивости в постановке СНиП, формулы и коэффициенты которого выведены аналитическим путем (в Ansys могут быть воспроизведены)
Эйлерова устойчивость:
пример
еще
еще раз
вот тут немного
и тут

(искал запросом на слово pstres,1 - именно этой командой активируется опция необходимая для последующего расчета на эйлерову устойчивость - вслед за статикой)

[diesel-generator]

Спасибо! Сейчас попробую посчитать и посмотреть что получиться. Я уже выполнял тестовые расчеты центрально сжатых стальных стоек по деформированной схеме и результаты расчетов у меня не совпали с результатами расчето выполненых в ручную по СНиПу т. е. критическая сила полученная в ансисе намного больше была чем полученная по нормам.

[ETCartman]

Центрально сжатые никогда и не теряют устойчивость, не бывает стержней без начальных выгибов и эксцентриситетов. А вот если задавать стержням начальный эксцентриситет, как в "Пособии по проектированию..." к СНиП, то сходимость Ansys/СниП получается на уровне 3-5% для прямоугольных стержней, а для стержней произвольного сечения отслеживается влияние формы сечения на устойчивость (то чего нет в СНиП но сделана попытка в СП)
Коэффициенты формы сечения, коэффициенты фи_е для решетчатых и сплошных, коэффициенты при расчете с учетом пластических деформаций - все это, если решать задачу в СНиПовской постановке, со СНиП естественно сходится.

[diesel-generator]

А как в Ансисе задавать начальный эксцентриситет и чему он будет равен? Я в расчетах начальный эксцентриситет задавал в качестве горизонтальной силы(перемещения), но от величины этой силы(перемещения) зависило значение критиической силы которое как раз и не совпадало со СНиПом.

[ETCartman]

А в "Пособии" прописано i/20+L/750 если мне память не изменяет, там и схемка есть. От горизонтальной силы ясен пень будет зависить критическая, но это уже не центральное сжатие в понимании СНиП.
Такого рода задачи (деформированная схема) требуют определенных знаний и навыков, но в принципе все это решабельно вполне

[diesel-generator]

Большое спасибо!!! Тогда получается что при расчете на устойчивость все потенциально сжатым элементам необходимо задавать начальные эксцентриситеты и затем решать физически и геометрически нелинейную задачу???

[ETCartman]

Есть два способа: решать линейную задачу, определять расчетные длины методом Эйлера и далее считать по формулам СНиП (которые выведены для простого шарнирного стержня, а эйлеров расчет именно и приводит вашу конструкцию к такому стержню - для частного случая когда напряжения при потере устойчивости не превышают предела пропорциональности). Это приближенный подход который иногда дает результаты в большой запас прочности.
Расчет по деформированной схеме, если есть как N так и моменты (с усл. эксцентриситетом m>0.1) производится на заданную комбинацию - никаких выгибов задавать не надо, доп моменты от них будут малы по сравнению с моментами от внешних сил.
Если говорить за ansys - нужно построить модель , выбрать тип элемента (стержневого) который учитывает пластику, задать диаграмму деформирования, включить нелинейные опции и считать до расходимости. Потом в time history postproсessor построить и исследовать кривую нагрузка-перемещение. Если доля нагрузки (time) при которой конструкция уже не несет меньше 1 то конструкция неустойчива.
Если в частности речь идет о гибкой конструкции, которая теряет устойчивость до предела пропорциональности, то пластика влять на результат не будет, только геометрическая нелиненость. И в общем случае величина time будет совпадать с эйлеровым коэффициентом запаса устойчивости.

[Португалец]

А как решить общую задачу - сжато-изогнутая балка? В СНиП об этом ничего не говорится. Рассматривается либо отдельно крутильная форма потери устойчивости (устойчивость плоской формы изгиба, так называемое "фи балочное"), либо устойчивость при внецентренном сжатии, там уже другое "фи". Или крутильная форма всегда будет первая, поэтому совместно их не рассматривают?

[ETCartman]

Про теорию расчета есть немного в Гореве (1т), про устойчивость балок - в Белене даже есть. Элементы 188-189 позволяют определить изгибно-крутильные формы при расчете в эйлеровой постановке. При расчете изгиба с кручением с учетом пластических деформаций - результаты выдаются, если сравнивать с оболочечными моделями - вполне приемлемые на начальной стадии развития пластических деформаций, но в справке есть рекомендация использовать результаты с осторожностью (поскольку тут сама теория может давать сбои).
Деформационные расчеты - хороший инструмент для дополнительных проверок, это уже моделирование - настоящее, хотя едва ли можно будет когда-нибудь полностью на них полагаться.
Для плоских систем все проще, надежность результатов выше.

[diesel-generator]

Правильно ли я понял???

Первый метод расчета на общую устойчивость. Идея метода заключается в том, что выполняется "linear buckling analyses" в результате этого расчета мы определяем расчетные длины стержневых элементов и продольные сжимающие силы, а затем выполняем проверку на устойчивость в ручную по СНиПу.

Второй метод расчета на общую устойчивость. Мы решаем геометрически и физически нелинейную задачу, где значение нагрузки до ее расчетной величины будет прикладываться последовательно. Если решение такой задачи сойдется, то устойчивость обеспечена если нет то можно будет посмотреть значение нагрузки при которой произошла потеря устойчивости.

Третий метод расчета на общую устойчивость. Выполняются расчеты определяются максимальные сжимающие усилия и моменты а потом по СНиПу с наибольшей расчетной длиной выполняем проверку на устойчивость.

[ETCartman]

не понял, как вы поняли. Чем третий тогда от второго отличается. хотите действительно понять - прорешайте всеми методами задачи с известными решениями, получите самостоятельно сниповские коэффициенты, а потом приступайте к более менее реальным задачам

[diesel-generator]

третий отличается от второго тем, что там выполняется линейные расчеты и в результате комбинаций расчетов определяются наибольшие сжимающие силы и изгибающие моменты а потом они используются для проверки на устойчивость элементов по СНиПу.

2 ETCartman большое Вам спасибо!!! я действительно сейчас займусь расчетами, что бы не задавть глупые вопросы.

[Португалец]

Сообщение от ETCartman Для плоских систем все проще, надежность результатов выше.

Но в то-же время корректность плоских систем реальной конструкции меньше.

[ETCartman]

Для реальной конструкции столько всего оказывает влияние, что пространственность схемы идет через запятую среди десятка факторов, о которых вы может быть и не задумываетесь.
Основа расчета и конструирования - плоская схема, максимально упрощенная. На пространственной с большей вероятностью можно сделать ошибку, сами программы на сложных схемах могут давать ошибки, а ваша "добавка" в усилия может быть запросто перебита податливостью узлов, наличием дефектов, влиянием основания или перераспределением нагрузки, иным чем это может быть по вашей схеме.

[diesel-generator]

Здравствуйте!

Решается следующая задача в Ansys: определить критическую силу центрально сжатого стержня.
Тип анализа Buckling analysis. Тип элемента beam4.
Стержень имеет шарнирное закрепление по концам. Длина стержня l=10м. Квадратное поперечное сечение с размером а=0,1м. Момент инерции I=8,33e-6м4. Площадь сечения А=10e-3м2. Материал упругий E=2,06e11Па.
Значение критической силы вычесленное по формуле Эйлера Pcr=169188Н.
Значение критическо силы полученное в результате расчетов по программе Ansys Pcr=169363Н

Почему первая форма потери устойчивости происходит относительно не главной оси инерции???

Хотя если решать аналогичную задачу и использовать элемент beam189, то первая форма потери устойчивости происходит отнсительно главной оси инерции.

На рисунках показана первая форма потери устойчивости при использовании элемента beam4. Вид вдоль оси X и вдоль оси Z.

[ETCartman]

Стержень квадратный - потеря устойчивости в двух плоскостях равноверояна. Тут вопрос из области "по какому правилу отобразить сразу две формы, если можно отобразить только одну, но нужно именно две", возможно, решается по разному для разных типов. Это вопрос отображения результата, однозначного решения не имеет - сам результат верный (0,1%), уточняется в зависимости от степени разбивки для данного эл-та

[СергейД]

подобное происходит при расчете частот и является особенностью математики, т.н.проблемы кратных собственных значений.
с тзр программы если моменты равны (ей что круг, что квадрат и куда главные оси ей неинтересно= главное, что формы получаются ортогональны)

если значения моментов инерции будут неравны, например отличаться на 0.0001%
то формы колебаний будут ориентированы строго по главным осям.
можешь проверить.
для 188 и 189 при задании сечений, два момента могут чуть (в каком-нибудь 7м знаке) и отличаться, возможно их специально "разводят".

для устойчивости используется по сути примерно тот же алгоритм и эффекты могут быть аналогичны. проверь= задай чуть разные моменты инерции.

[diesel-generator]

Спасибо!!!

Действительно если моменты инерции отличаются на 0.0001%, то формы потери устойчивости ориентированы по главным осям.

[diesel-generator]

Здравствуйте!

Решается следующая задача в программе Ansys: к стержню прикладывается продольная сила со значением P=4000 кН,
с эксцентриситетом e=0.0036575м, относительно оси с наибольшим моментом инерции.

Цель задачи: определить предельное значение сжимающей силы P.

Исходные данные: длина стержня L=0.5775, прямоугольное поперечное сечение 0.2*0.1м.

Физические и механические характеристики: E=2.06e11Па, v=0,3, R=200e6Па, Et=2,06e8.

Расчетная модель: для моделирования стержня применяется расчетный элемент beam189.
Используется упруго-пластический материал (диаграмма Прандтля).

Расчет. Решается физически и геометрически нелинейная задача. Нагрузка на стержень возрастает постепенно.

Вопросы:
1. Почему пластические деформации имеют столь странный вид (картинка.doc)?
2. Как посмотреть зависимость напряжений, деформаций от времени в узлах сечения?
3. В таблице Table 189.2 BEAM 189 Item and Sequence Numbers есть EPTO, EPTH, EPPL, EPCR как их можно посмотреть.
4. Как считать на устойчивость систему с центрально сжатыми стержнями (стержни теряют устойчивость с появлением пластических деформаций)?
Задавать прогибы, создавать расчетную схему со случайными эксцентриситетами, прикладывать сосредоточенные моменты или как то по другому?

[Евгений, Екатеринбург]

1. Диаграмму надо задавать в истинных напряжениях, диаграмма Прандтля задается в инженерных, что в истинных получается с ниспадающей ветвью. Ansys использует истинные.
2. Разбивка по-моему не подходящая, надо мельче бить, но я со 18х не работал кроме 186, не знаю.
3. Согласно пособию к СНиП задается стрелка прогиба i/20+L/750. Согласно еврокод можно задавать стрелку прогиба, поперечную силу таким образом чтобы она давала наибольший момент, отклонение от вертикали.
4. alle выкладывал чудный пример именно с устойчивостью центрально-сжатого стержня (со стрелкой прогиба), вроде бы 23-ми моделировал если не ошибаюсь, расхождение со СНиП 1% было, поищите.

[diesel-generator]

Спасибо за ответ!

Меня конечно больше всего интересует:

1. Почему пластические деформации имеют такой вид распределения (на мой взгляд при потери устойчивости (при искривлении стержня)
часть его сечения, находящаяся со стороны растянутых волокон от изгиба, будет разгружаться по упругому закону т. е. будет находиться в
упругом состоянии. Другая часть будет находиться в пластическом состояии. Т. е. должен быть какой-то равномерный переход от
пластических деформаций к упругим, что как раз на картинке и не наблюдается)?

2. Как посмотреть зависимость перемещений, напряжений от временя для балочных элементов в узлах поперечного сечения?

Стержень теряет устойчивость при нагрузке Pcr=0.955*4000кН.
Изгибается относительно оси Y.
Ниже приведина картинка с изополями интенсивности пластических деформаций для всего стержня в момент потери устойчивости.

[Евгений, Екатеринбург]

1. Не могу так ничего посоветовать, можете выложить код? Для начала попробуйте Beam23, к сожалению код alle не могу найти.
2. Посмотреть зависимость любого параметра от времени TimeHist PostPro-> Add Data, далее выбрать интересующий параметр, построить график.

[diesel-generator]

Спасибо за ответы!


Я практически со всеми вопросами разобрался кроме одного.
Как посмотреть развитие относительных деформаций во времени (время условная величина) в угловых точках сечения?
Через TimeHist PostPro-> Add Data это сделать не получиться


Выкладываю код задачи.

[Евгений, Екатеринбург]

Вот код предложенный alle для устойчивости, все права сохраненны (с). Еще раз восхищаюсь его мастерством. :-)
В Вашем коде:
1. Надо эксцентриситет задавать моментом, а не доп. стержнем.
2. Пластичности нет потому что вы ее не задали, в ANSYS двухлинейная диаграмма это не пластичность, а упругая двухлинейная диаграмма, т.е. система консервативная - при разрузке он возвращается по тому же пути, что и при нагрузке. Полностью.

Код:

[Выделить все]

!Сопоставление результатов расчета на устойчивость по СНиП II-23-81* 
!с результатами упругопластического расчета в геометрически-нелинейной постановке 
!в ANSYS Program (для прямоугольного сечения и степенной диаграммы деформирования) 
!Смысл кода такой: вычисляем предельное усилие Рu по СНиП, моделируем в ANSYS ED 
!и получаем, что лишь немного его надо подкорректировать, для того чтобы момент 
!когда стержень гикнется совпал с теорией. 
! 
!ИСХОДНЫЕ ДАННЫЕ 
!Размеры сечения, м 
!Ширина, м 
b=0.10 
!Высота, м 
h=0.15 
!Длина (пролет) стержня, м 
L=3 
!Радиус инерции сечения, м 
i=h/sqrt(12) 
!Начальная погибь стержня, м (см ПОСОБИЕ по проектированию 
!стальных конструкций к СНиП II-23-81*) 
f=i/20+L/750 
!Характеристики стали (кПа) 
s02=345000                              !Условный предел текучести 
fs=490000                               !Предел прочности 
psi=63                                  !Относительное сужение при разрыве % 
E=2.06e8                                !Модуль Юнга    
m=0.75*log(fs*(1+1.4*(psi/100))/s02)/log(log(100/(100-psi))/((s02/E)+0.002)) 
!"Истинный" предел текучести 
ys=(s02/(E*0.002+s02)**m)**(1/(1-m)) 
!Напряжение, соответствующее предельной деформации    
sm=ys*(log(100/(100-psi))/(ys/E))**m    
!* 
!Определение предельного усилия по  по СНиП II-23-81* (формулы 7-10) 
!Гибкость стержня 
flex=L/i 
rflex=flex*sqrt(s02/E) 
*IF,rflex,LE,2.5,THEN 
phi=1-(0.073-5.53*s02/E)*rflex*sqrt(rflex) 
*ENDIF 
*IF,rflex,GT,2.5,AND,rflex,LE,4.5,THEN 
phi=1.47-13*s02/E-(0.371-27.3*s02/E)*rflex+(0.0275-5.53*s02/E)*rflex**2 
*ENDIF 
*IF,rflex,GT,4.5,THEN 
phi=332/(rflex**2*(51-rflex)) 
*ENDIF 
!Предельное теор. усилие, кН (уменьш. на 1%). 
Pu=0.99*b*h*s02*phi 
!Вход в препроцессор 
/PREP7 
!*  
ET,1,BEAM23  
!Действ. константа 
R,1,b*h,b*h**3/12,h, 
!Материал 
MP,EX,1,E 
MP,NUXY,1,0.3 
TB,MISO,1,1,20                !Закон упрочнения материала 
TBTEMP,0                      !Температура 
TBPT,,(ys/E),ys               !Начальная точка графика sigma =f(e) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(1/19))**(1/m),ys+(sm-ys)*(1/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(2/19))**(1/m),ys+(sm-ys)*(2/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(3/19))**(1/m),ys+(sm-ys)*(3/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(4/19))**(1/m),ys+(sm-ys)*(4/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(5/19))**(1/m),ys+(sm-ys)*(5/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(6/19))**(1/m),ys+(sm-ys)*(6/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(7/19))**(1/m),ys+(sm-ys)*(7/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(8/19))**(1/m),ys+(sm-ys)*(8/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(9/19))**(1/m),ys+(sm-ys)*(9/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(10/19))**(1/m),ys+(sm-ys)*(10/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(11/19))**(1/m),ys+(sm-ys)*(11/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(12/19))**(1/m),ys+(sm-ys)*(12/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(13/19))**(1/m),ys+(sm-ys)*(13/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(14/19))**(1/m),ys+(sm-ys)*(14/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(15/19))**(1/m),ys+(sm-ys)*(15/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(16/19))**(1/m),ys+(sm-ys)*(16/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(17/19))**(1/m),ys+(sm-ys)*(17/19) 
TBPT,,(ys/E)*(1+((sm/ys)-1)*(18/19))**(1/m),ys+(sm-ys)*(18/19) 
TBPT,, log(100/(100-psi)),sm   !Конечная точка графика sigma =f(e)    
!* 
!Ввод ключевых точек 
K,1,,,, 
K,2,L/2,f,, 
K,3,L,0,,  
!Сплайн  
BSPLIN,1,2,3 
!* 
LESIZE,ALL, , ,10, ,1, , ,1, 
LMESH,       1    
FINISH 
!Вход в решатель 
/SOL 
DK,1, , , ,0,UX,UY, , , , ,  
DK,3, , , ,0,UY, , , , , ,    
FK,3,FX,-Pu    
ANTYPE,0 
NLGEOM,1 
NSUBST,20,0,0    
OUTRES,ERASE 
OUTRES,ALL,ALL  
TIME,1 
solve    
FINISH  
/POST26 
NUMVAR,200  
!*  
NSOL,2,7,U,Y, UY_2  
STORE,MERGE 
XVAR,1  
PLVAR,2, 
/replot

[diesel-generator]

Спасибо большое за помощь!

[diesel-generator]

Всем здравствуйте!

Сегодня решал задачу на устойчивость и
у меня возник вопрос.

Код и результаты задачи приводятся ниже.

Почему если прикладывать различный внешний момент относительно
оси с минимальным моментом инерции то на значение первой
критической силы он не оказывает никакого влияния???

Ведь если это действительно так ( т. е. я нигде не ошибся при расчетах)
то получается что buckling analysis который есть в ансисе, лире, скаде,
настране нельзя использовать для расчетов на устойчивость потому что
этот тип анализа не позволяет корректно учитывать изгибающие моменты, которые характерны для рамных систем.

Код:

[Выделить все]

!ВЛИЯНИЕ ЭКСЦЕНТРИСИТЕТА НА ЗНАЧЕНИЕ ЭЙЛЕРОВОЙ КРИТИЧЕСКОЙ СИЛЫ
!ПРИ РАСЧЕТЕ ВНЕЦЕНТРЕННОГО СЖАТОГО СТЕРЖНЯ
 
!Постановка задачи. К свободному концу консольного стержня, длиной 5м и 
!с прямоугольным поперечным сеченим 0.1*0.05М, приложены следующие нагрузки:

!1. Сосредоточенная сжимающая сила n=1Н действующая вдоль продольной оси;

!2. Сосредоточенный момент mx(my)=n*e действующий относительно
!оси У или относительно оси X, где e=-эксцентриситет приложения внешней силы.
!e=0.1; 1,0; 5,0; 10м. Значение момента меняется в зависимости от эксцентриситета.

!Цель. Изучить влияние эксцентриситета, который откладывается вдоль оси X или Y,
!на значение критической силы.

!Примечание. Программа Ansys. Для решения используется Buckling analysis.

/TITLE,buckling_analysis_of_eccentric_compressed_bar 

!*ИСХОДНЫЕ ДАННЫЕ

!*Геометрия стержня

l=5  !*расчетная длина стержня, м
e=0.1 !*Эксцентриситет
!*Сечение стержня, м

h=0.1 
b=0.05 

!*Механические характеристики
e1=2.06e11
v=0.3
d=7850

!*Нагрузка
n=1
m=n*e
!*ПОСТРОЕНИЕ РАСЧЕТНОЙ МОДЕЛИ

/prep7

k,1,
k,2,,,l
k,3,e,

l,1,2

ET,1,beam189

MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,2.06e11
MPDATA,PRXY,1,,0.3  

SECTYPE,   1, BEAM, RECT, , 0   
SECOFFSET, CENT 
SECDATA,b,h,0,0,0,0,0,0,0,0

lesize,all,l/10

latt,1,,beam189,,3,,1

lmesh,all

d,1,all

F,2,FZ,-n
F,2,MY,m
FINISH


/SOLU   

ANTYPE,0

NLGEOM,0
NROPT,AUTO, ,   
STAOPT,DEFA 
LUMPM,0 
EQSLV, , ,0,
PRECISION,0 
MSAVE,0 
PCGOPT,0, ,AUTO, , ,AUTO
PIVCHECK,1  
PSTRES,ON   
TOFFST,0,
SOLVE 
FINISH

/SOLU 

ANTYPE,1

BUCOPT,LANB,10,0,0  

MXPAND,10,0,0,0,0.001,  
/STATUS,SOLU
SOLVE   

!РЕЗУЛЬТАТЫ РАСЧЕТОВ

!№	      Pcr при N и My			
!	e=0.1	e=1,0	e=5,0	e=10,0
!1	21173	20754	15284	10274
!2	84693	84693	26238	13551
!3	187580	100190	71801	38671
!4	514910	246420	79923	40967
!5	760790	331050	84693	67046
!6	969570	508130	128170	69347
!7	1577800	601960	136500	84693
!8	2106600	760790	187390	96889
!9	2244100	791050	196490	99379
!10	3105400	896770	253630	130420

!%		Pcr при N и Mz			
!	e=0.1	e=1,0	e=5,0	e=10,0
!1	21177	21177	21177	21177
!2	84622	78587	41095	24006
!3	190520	190520	54197	27536
!4	529160	237390	154640	80536
!5	717530	529160	163820	82955
!6	1038500	603630	190520	137380
!7	1723800	742050	268060	139770
!8	1912200	1038500	277260	190520
!9	2597700	1150600	387300	197260
!10	3316400	1298600	397250	199840

!Примечание. #-номер формы потери устойчивости и критической силы.

!Выводы:
!1. Изгибающий момент оказывает влияние на значение критической силы;
!2. Первая форма потери устойчивости стержня происходит относительно оси с меньшим моментом инерции
!даже если момент приложен относительно оси с большим моментом инерции;
!3. Если прикладывать различный внешний момент относительно оси с минимальным моментом инерции то
! то на значение первой критической силы он не оказывает никакого влияния.

[СергейД]

эксцентриситет задают не так. не третьей точкой,
она направляющая для осей.
а
secoffs,user...
нарисуйте сечение -то ..
/eshap,1

но
наиболее адекватный расчет с учетом моментов будет
= прямой нелинейный расчет с начальными несовершенствами.

[diesel-generator]

Спасибо за Ваш ответ!

Третью точку я задавал для ориентации сечения, а
эксцентриситет задавал путем приложения
сосредоточенного изгибающего момента и продольной
силы. Хотя действительно эксцентриситет можно было задать через
secoffs.

Расчетная схема
http://www.flickr.com/photos/4484694...13309/sizes/o/

Если говорить о стальных стержневых конструкциях
то получается, что buckling analysis применим только для центрально сжатых гибких
стержневых систем?

[СергейД]

buckling- первичная оценка.
реальное поведение - суть нелинейно.
изучайте начальные несовершенства.

[Александр Бауск]

Подпишусь-ка я на тему (c).

[vittantonio]

Всем здравствуйте!

Цель: оценить устойчивость стальных конструкций
при расчетном землетрясении.

Решение

Код:

[Выделить все]

!!!Формируется геометрия расчетной схемы

!!!Выбираем конечные элементы

!!!Создаем реальные константы

!!!Определяем модели материалов:

!Материал для стальных конструкций
MPTEMP,1,0  
MPDATA,DENS,1,,7850*1.05*0.9  
MPDATA,EX,1,,2.06e11
MPDATA,PRXY,1,,0.3  
TB,BISO,1,1,2,  
TBTEMP,0
TBDATA,,340e6,2.06e9,

!Материал для жб конструкций
MPTEMP,1,0  
MPDE,DENS,2 
MPDATA,DENS,2,,3000  
MPTEMP,1,0  
MPDE,EX,2   
MPDE,NUXY,2 
MPDE,PRXY,2 
MPDATA,EX,2,,3E+010 
MPDATA,PRXY,2,,0.2  

!!!Назначаем аттрибуты

!!!Наносим сетку конечных элементов

!!!Устанавливаем граничные условия (закрепления)

!!!Прикладываем нагрузку от собственного веса
ACEL,,,9.81

!!!Выполняем расчеты

ANTYPE,4
NLGEOM,1
DELTIM,0.2,0.1,0.2  
KBC,0.0 
TIME,1  
TIMINT,0

SOLVE

!!!В конструкции сформировалось ндс от
!!!собственного веса
!!!На это напряженное состояние конструкции
!!!задается воздействие от расчетного землетрясения
!!!в качестве акселлерограмм (нестационарное поле ускорений)

!Воздействие от расчетного землетрясения
ACEL,%A_X%,%A_Y%,%A_Z%,
   
DELTIM,0.01,0.005,0.01  
KBC,1.0 
TIME,31 
TIMINT,1

SOLVE

Если мы получем схождение задачи в каждый момент времени,
то можно считать, что устойчивость стальных конструкций
при землетрясении обеспечена.

Если не получаем схождение, то устойчивость не обеспечена.

Вопрос.

Можно ли такой подход к оценке устойчивости стальных
конструкций при сейсмическом воздействии считать верным?

[vs-tes]

Всем доброго...!
Какой физический смысл отрицательного коэфф-та FACT?




Я смотрю, что здесь пока не нахамишь, никто внимания не обращает...

[Graf Kim]

Сообщение от vs-tes Какой физический смысл отрицательного коэфф-та FACT?

Покажите схемку, пожалуйста. А то сейчас СергейД опять будет телепатов требовать.

Пока здравая логика подсказывает, что это может означать противоположное направление приложения нагрузки.

[СергейД]

если нахамишь , то внимания также потом обращать не станут... обычно у тех, кто знает ответ= своих дел хватает= не всем дежурить же на форуме.

конечно, это просто множитель= если нагрузку задать не в ту сторону= минус таки и получится.

[vs-tes]

Еще раз добрый день!

Сообщение от СергейД если нахамишь , то внимания также потом обращать не станут...

Да я, если честно, хамить и не собирался... Но, как видите, сама претензия на хамство немного оживляет форум. Поверьте, мне самому не хочется выглядеть наглецом.

Сообщение от СергейД обычно у тех, кто знает ответ= своих дел хватает= не всем дежурить же на форуме.

Понимаю, что проблемы таких "спецов", как я, мало кого колышут, НО!.. Ответы знать интересно...
Воспользовался вашим советом - получил результат при расчете линейной устойчивости -> далее UPCOORD, но приводить коэффициент данной команды думаю такой, который будет давать искажение, имеющее величину около 5-10мм (вы рекомендовали 0,001, что для меня кажется недостаточным для учета дефектов изготовления, плюс сюда же расчет по деформированной схеме).

Относительно того, что FACT - это множитель, сомнений нет. Для данного случая я мог предположить, что FACT может быть только больше нуля: берем совокупность силовых факторов, приложенных к схеме, умножаем на коэфф-т FACT, в следствии чего получаем критическую "совокупность факторов" (по Эйлеру). Но здесь появляется знак "минус" и все приобретает иной оттенок...

Итак, как я погляжу, история повторяется...