[sergtranes]

добрый всем день,
проблема со штриховкой замкнутой полилинии неправильной формы
грязно ругается на команду:

oHatch.AppendOuterLoop oPline
"Invalid object array!"

хотя PolyLine допустима для етой команды!

kak сделать штриховку неправильной формы ?
хотелось бы MultyLine , но ето не подходит!

спасибо

[Олег (jr.)]

Пробуй для замкнутых LWPOLINE:

Option Explicit


          Public Sub ApplyHatch(pline As AcadLWPolyline, ptype As Long, patt As String, scl As Double)
     
          Dim oEnt As AcadEntity
          Dim oSpace As AcadBlock
          Set oSpace = ThisDrawing.ActiveLayout.Block
          
          With oSpace
          Set oEnt = pline
          Dim varObj(0) As AcadEntity
          Set varObj(0) = pline
          Dim oHatch As AcadHatch
          


          Set oHatch = .AddHatch(ptype, patt, True)
          oHatch.SetPattern ptype, patt
          oHatch.PatternScale = scl

          oHatch.AppendOuterLoop varObj
          

          End With
          End Sub
          
          Public Sub demo()
            Dim pfs As AcadSelectionSet
              Dim oEnt As AcadEntity
              Dim varPt As Variant
              Dim ftype(0 To 1) As Integer
              Dim fdata(0 To 1) As Variant
              Dim dxfCode, dxfValue
              Dim n
          
              Dim oPline As AcadLWPolyline
              
          On Error GoTo Err_Conrtol
          
              ftype(0) = 0: ftype(1) = 70:
              
              fdata(0) = "LWPOLYLINE": fdata(1) = 1:
              
              dxfCode = ftype: dxfValue = fdata
              
              With ThisDrawing
              
          With .SelectionSets
               While .Count > 0
                    .Item(0).Delete
               Wend
          Set pfs = .Add("NewOne")
          End With
       
              pfs.SelectOnScreen dxfCode, dxfValue
          
              If pfs.Count = 0 Then Exit Sub
 
              For Each oEnt In pfs
          
                  Set oPline = oEnt
                  
          ApplyHatch oPline, 1, "ANSI37", 10#
          
              Next oEnt
              
.Regen acActiveViewport

              End With
              
Err_Conrtol:
          
          End Sub

[sergtranes]

спасибо Олег - помогло!

[Олег (jr.)]

Сообщение от sergtranes спасибо Олег - помогло!

Пожалуйста,
забыл добавить в справке:
после вызова метода AppendOuterLoop

Код:

[Выделить все]

oHatch.AppendOuterLoop varObj

нельзя производить никаких манипуляций со
штриховкой из-за непредсказуемости результата
(вольный перевод)

[sergtranes]

впечетляет!
еще раз спасибо