[S_M]

Здравствуйте!
Моя задача состояла в том, чтобы в нелинейной постановке рассчитать железобетонную балку. Балку делал из Link8 и Solid65 (линками моделировал арматуру).
Теперь, по окончании расчета, хочу построить график зависимости напряжений в наиболее напряженном элементе арматуры (ННЭА)от нугрузки.
Для элемента Link8 делаю следующее:
etable,fi,smisc,1
etable,fj,smisc,1
pretab,fi,fj
Но в результате я получаю таблицу для последнего substep, а мне бы хотелось вывести на экран таблицу или список со значениями усилий для ННЭА для каждого substep`а.
Знаю, что можно менять substep`ы и смотреть для них значения:
set,sbstep,2 (для второго например)
etable,fi,smisc,1
etable,fj,smisc,1
pretab,fi,fj
Но у меня 50 substep`ов и так вот для каждого смотреть неудобно.
Уважаемые Гуру, помогите студенту!!!! )))

[ETCartman]

А если мне память не изменяет - надо считать нужные результаты
PostPro - Read Results
по номеру степа или по тайму (в долях 1, если у вас это первая и единственная прогонка)

[Евгений, Екатеринбург]

Сообщение от S_M Но в результате я получаю таблицу для последнего substep, а мне бы хотелось вывести на экран таблицу или список со значениями усилий для ННЭА для каждого substep`а

таблица не может быть для каждого подшага - таблица это "снимок", т.е. снапшот в конкретный момент времени.
Если не ошибаюсь, Вы сегодня подходили с этим вопросом? Вот мой код

Код:

[Выделить все]

/FILNAME, filename
/TITLE, titlename
/UNITS,SI
/Prep7
A=0.3
B=0.4

BLC5,0,0,A,B,0
L=2
ndiv=8
Rb=17E6
Ec2=0.002
Ec3=0.0035

K,5,0,0,0
K,6,0.10,0.15,0
K,7,-0.10,0.15,0
K,8,-0.10,-0.15,0
K,9,0.10,-0.15,0
K,18,-0.10,0.10,0
K,19,0.10,0.10,0

ET,1,MESH200,6
ET,2,SOLID65,
ET,3,LINK8
ET,4,SHELL63

KEYOPT,2,7,1

R,1,
R,2,0.001
R,3,0.000314

MP,ex,1,Rb*(1-(1-0.1)**2)/(0.1*Ec2)
MP,nuxy,1,0.2

TB,CONCR,1
TBDATA,1,1,1,1.2E6,!1.7E7
TB,MISO,1,1,11
TBTEMP,0
TBPT,,0,0   
TBPT,,0.1*Ec2,Rb*(1-(1-0.1)**2)
TBPT,,0.2*Ec2,Rb*(1-(1-0.2)**2)
TBPT,,0.3*Ec2,Rb*(1-(1-0.3)**2)
TBPT,,0.4*Ec2,Rb*(1-(1-0.4)**2)
TBPT,,0.5*Ec2,Rb*(1-(1-0.5)**2)
TBPT,,0.6*Ec2,Rb*(1-(1-0.6)**2)
TBPT,,0.7*Ec2,Rb*(1-(1-0.7)**2)
TBPT,,0.8*Ec2,Rb*(1-(1-0.8)**2)
TBPT,,0.9*Ec2,Rb*(1-(1-0.9)**2)
TBPT,,0.95*Ec2,Rb*(1-(1-0.95)**2)
!TBPT,,Ec2,Rb
!TBPT,,0.9*Ec3,Rb
!TBPT,,Ec3,0.2*Rb

mp,ex,2,2E11
TB,BISO,2,1,
TBDATA,1,3.55E8,2E9

TYPE,1
esize,0.05
MSHAPE,0,2D
MSHKEY,2
amesh,all,

nsel,s,loc,z,0 
esln,,1 
local,11,0 
emodif,all,esys,11

MAT,1
REAL,1
EXTOPT,esize,ndiv
EXTOPT,aclear,1
EXTOPT,ATTR,0,0,1

VOFFST,1,L, ,
/VIEW,1,1,2,3   
/ANG,1  
/REP,FAST   
EPLOT

KSEL,S,KP,,6,9,1
KSEL,A,KP,,18,19,1   
KGEN,2,all, , , , ,L, ,0

allsel,all
LSTR,       6,      14  
LSTR,       7,      15  
LSTR,       8,      16  
LSTR,       9,      17
LSTR,       18,     20  
LSTR,       19,     21

allsel,all
KSEL,S,KP,,6,9,1
KSEL,A,KP,,18,19,1
LSLK,S,0

TYPE,3   
MAT,2
REAL,3   
LESIZE,ALL, , ,ndiv, ,1, , ,1, 
LMESH,all

NUMMRG,NODE,,,,

allsel,all

NSEL,S,LOC,Z,0   
D,ALL, , , , , ,UZ, , , , , 
NSEL,R,LOC,Y,-B/2
D,ALL, , , , , ,UY, , , , ,

NSEL,S,LOC,Z,0
NSEL,R,LOC,X,-A/2
NSEL,R,LOC,Y,0
D,ALL, , , , , ,UX, , , , ,

NSEL,S,LOC,X,0
NSEL,R,LOC,Y,0
NSEL,R,LOC,Z,L

*GET,nodenum,node,0,num,min,,

NSEL,S,LOC,Z,0
NSEL,R,LOC,X,0.10
NSEL,R,LOC,Y,0.15
ESLN,S,0,ALL
ESEL,R,ENAME,,8,8,,
*GET,elemnum1,ELEM,0,num,min,,
NSLE,S,all,
*GET,nodenum1,node,0,num,max,,

NSEL,S,LOC,Z,0
NSEL,R,LOC,X,0.10
NSEL,R,LOC,Y,0.10
ESLN,S,0,ALL
ESEL,R,ENAME,,8,8,,
*GET,elemnum2,ELEM,0,num,min,,
NSLE,S,all,
*GET,nodenum2,node,0,num,max,,

NSEL,S,LOC,Z,0
NSEL,R,LOC,X,0.10
NSEL,R,LOC,Y,-0.15
ESLN,S,0,ALL
ESEL,R,ENAME,,8,8,,
*GET,elemnum3,ELEM,0,num,min,,
NSLE,S,all,
*GET,nodenum3,node,0,num,max,,


FINISH
/SOLU
eqslv,pcg,1e-4
nropt,unsym,,on
nldiag,nrre,on
lnsrch,on
KBC,0
AUTOTS,1
OUTRES,ERASE
OUTRES,ALL,1

allsel,all
SFA,5,1,PRES,220000

TIME,220*0.3
DELTIME,0.3,0,0.3,0
CNVTOL,F, ,0.04,2,1,   
CNVTOL,U, ,0.05,2,5,
SOLVE

allsel,all
SFA,5,1,PRES,240000

TIME,238*0.3
DELTIME,0.2,0,0.2,0
CNVTOL,F, ,0.04,2,1,   
CNVTOL,U, ,0.05,2,5,
SOLVE

FINISH  
/POST26 
FILE,'filename','rst','.'   
/UI,COLL,1  
NUMVAR,200  
SOLU,191,NCMIT  
STORE,MERGE 
FILLDATA,191,,,,1,1 
REALVAR,191,191 
!*  
NSOL,2,nodenum,U,Y, UY_2
STORE,MERGE 
XVAR,1  
PLVAR,2,

!***********************************************
!Выводим изображение в файл
!***********************************************
/SHOW,TIFF,,0
/GFILE,1600,
/REPLOT
/SHOW,CLOSE !Вывод изображения в файл окончен
!***********************************************

ESOL,3,elemnum1,nodenum1,SMISC,1,S_1
STORE,MERGE 
XVAR,1  
PLVAR,3,

!***********************************************
!Выводим изображение в файл
!***********************************************
/SHOW,TIFF,,0
/GFILE,1600,
/REPLOT
/SHOW,CLOSE !Вывод изображения в файл окончен
!***********************************************

ESOL,4,elemnum2,nodenum2,SMISC,1,S_2
STORE,MERGE 
XVAR,1  
PLVAR,4,

!***********************************************
!Выводим изображение в файл
!***********************************************
/SHOW,TIFF,,0
/GFILE,1600,
/REPLOT
/SHOW,CLOSE !Вывод изображения в файл окончен
!***********************************************

ESOL,5,elemnum3,nodenum3,SMISC,1,S_3
STORE,MERGE 
XVAR,1
PLVAR,5,

!***********************************************
!Выводим изображение в файл
!***********************************************
/SHOW,TIFF,,0
/GFILE,1600,
/REPLOT
/SHOW,CLOSE !Вывод изображения в файл окончен
!***********************************************

PLVAR,s_1,s_2,, , , , , , , ,
!***********************************************
!Выводим изображение в файл
!***********************************************
/SHOW,TIFF,,0
/GFILE,1600,
/REPLOT
/SHOW,CLOSE !Вывод изображения в файл окончен
!***********************************************

PLVAR,s_1,s_2,s_3, , , , , , , ,
!***********************************************
!Выводим изображение в файл
!***********************************************
/SHOW,TIFF,,0
/GFILE,1600,
/REPLOT
/SHOW,CLOSE !Вывод изображения в файл окончен
!***********************************************

/DEVICE,VECTOR,0
!*  
FINISH  
/POST1  
SET,LAST
PLDISP,1
/SHOW,TIFF,,0   
/GFILE,1600,
!*  
/REPLOT 
/SHOW,CLOSE 
/DEVICE,VECTOR,0
!*  
/VIEW,1,1   
/ANG,1  
/REP,FAST   
/SHOW,TIFF,,0   
/GFILE,1600,
!*  
/REPLOT 
/SHOW,CLOSE 
/DEVICE,VECTOR,0
!*  
/VIEW,1,1,2,3   
/ANG,1  
/REP,FAST   
ESEL,S,ENAME,,8 
!*  
PLESOL, SMISC,1, 0,1.0  
/SHOW,TIFF,,0   
/GFILE,1600,
!*  
/REPLOT 
/SHOW,CLOSE 
/DEVICE,VECTOR,0

Вам нужно конкретно вот это место

Код:

[Выделить все]

/POST26 
FILE,'filename','rst','.'   
/UI,COLL,1  
NUMVAR,200  
SOLU,191,NCMIT  
STORE,MERGE 
FILLDATA,191,,,,1,1 
REALVAR,191,191 
!*  
NSOL,2,nodenum,U,Y, UY_2
STORE,MERGE 
XVAR,1  
PLVAR,2,

!***********************************************
!Выводим изображение в файл
!***********************************************
/SHOW,TIFF,,0
/GFILE,1600,
/REPLOT
/SHOW,CLOSE !Вывод изображения в файл окончен
!***********************************************

ESOL,3,elemnum1,nodenum1,SMISC,1,S_1
STORE,MERGE 
XVAR,1  
PLVAR,3,

[S_M]

Большое спасибо! Буду пробывать. Обязательно сообщу о результате.

[СергейД]

промежуточные результаты записывать нужно (OUTRES,all,all)
сделали? по умолчанию этого нет.
в Result summary сколько шагов?
если есть данные, то
можно рисовать графики и для SMISC и для всего.

если хотите еtab для промежуточных, то
/post1
set,last
*do, i,1,50! если записано столько
set,next
etab,ss%i%,smisc,1
....
*enddo

тогда в ss1 ss2 ss3.. будут etab для промежут шагов

[tyro41]

Можно также в цикле считывать нужные результаты *GET-ом в созданный массив. Потом выводить распечатку в файл, а дальше -экспортировать и строить графики в Эксель или ОпенОфис-орг.

[S_M]

ОГРОМНОЕ СПАСИБО, Сергей Д, Евгений!!!!!!! Оба варианта получились, и в Ansys графики построил и в EXEL, Ура!!!!!! :-D