[german-nk]

Дилетантский вопрос. Перерыл интернет и справочники.

Вот цитата из справочника: "You can use some other properties of a TextStyle object to set the way text appears: Height, Width, ObliqueAngle, and TextGenerationFlag". Все работает, но Width не работает.

Пример модуля из справки VBA, немного отредактировано.

Код:

[Выделить все]

Option Explicit
Sub Example_TextStyle()
   ' This example creates an aligned dimension in model space and
   ' creates a new system text style.  The new text style is then assigned to
   ' the new dimension

    Dim dimObj As AcadDimAligned
    Dim newText As AcadTextStyle
    Dim point1(0 To 2) As Double, point2(0 To 2) As Double
    Dim location(0 To 2) As Double
    
    ' Define the dimension
    point1(0) = 5: point1(1) = 5: point1(2) = 0
    point2(0) = 5.5: point2(1) = 5: point2(2) = 0
    location(0) = 5: location(1) = 7: location(2) = 0
    
    ' Create an aligned dimension object in model space
    Set dimObj = ThisDrawing.ModelSpace.AddDimAligned(point1, point2, location)
    
    ' Create new text style
    Set newText = ThisDrawing.TextStyles.Add("MYSTYLE")
    newText.Height = 10    ' Just set the height of the new style so we can differentiate. Это работает
    
    Dim Widht As Double
    newText.Widht = 0.8     'Вот это не работает
    
    Dim ObliqueAngle As Double
    newText.ObliqueAngle = 0.1 'Это работает
    ThisDrawing.Application.ZoomAll
    
    ' Read and display the current text style for this dimension
    MsgBox "The text style is currently set to: " & dimObj.TextStyle
    
    ' Change the text style to use the new style we created
    dimObj.TextStyle = "MYSTYLE"
    ThisDrawing.Regen acAllViewports
    
    ' Read and display the current text style for this dimension
    MsgBox "The text style is now set to: " & dimObj.TextStyle

End Sub

Сам не могу сообразить и ответ найти не могу. Нужно отредактировать готовый модуль, а программист уволился и уехал в Россию.

[trir]

newText.Width

[Олег (jr.)]

Попробуй сначала изменить шрифт, затем ширину,
в 2009 работает

Код:

[Выделить все]

Option Explicit

Sub Example_TextStyle()
   ' This example creates an aligned dimension in model space and
   ' creates a new system text style.  The new text style is then assigned to
   ' the new dimension

    Dim dimObj As AcadDimAligned
    Dim newTextStyle As AcadTextStyle
    Dim point1(0 To 2) As Double, point2(0 To 2) As Double
    Dim location(0 To 2) As Double
    
      Dim typeFace As String
    Dim Bold As Boolean
    Dim Italic As Boolean
    Dim charSet As Long
    Dim PitchandFamily As Long
    
    ThisDrawing.ActiveTextStyle.GetFont typeFace, Bold, Italic, charSet, PitchandFamily
 
    On Error Resume Next
    Set newTextStyle = ThisDrawing.TextStyles.Item("MYSTYLE")
    If Err Then
    Err.Clear
    On Error GoTo 0
    End If
    
   ' Create new text style
   Set newTextStyle = ThisDrawing.TextStyles.Add("MYSTYLE")
   ' Set font name
   typeFace = "arial"
   
   newTextStyle.SetFont typeFace, Bold, Italic, charSet, PitchandFamily
   
    newTextStyle.Height = 10    ' Just set the height of the new style so we can differentiate. Это работает
    
    Dim Widht As Double
    newTextStyle.Width = 0.8     'Вот это A2009 работает
    
    Dim ObliqueAngle As Double
    newTextStyle.ObliqueAngle = 0.1 'Это работает
    
    ThisDrawing.Application.ZoomAll
    
  
    
    ' Define the dimension
    point1(0) = 5: point1(1) = 5: point1(2) = 0
    point2(0) = 5.5: point2(1) = 5: point2(2) = 0
    location(0) = 5: location(1) = 7: location(2) = 0
    
    ' Create an aligned dimension object in model space
    Set dimObj = ThisDrawing.ModelSpace.AddDimAligned(point1, point2, location)
    
  ' Change the text style to use the new style we created
    dimObj.TextStyle = "MYSTYLE"
    ThisDrawing.Regen acAllViewports
    
    ' Read and display the current text style for this dimension
    MsgBox "The text style is now set to: " & dimObj.TextStyle

End Sub

[Кулик Алексей aka kpblc]

german-nk, для справки: ширина текста - это одно, а коэффициент сжатия для текстового стиля - совсем другое.